Source/cmCommandArgumentParser.y

   1 %{
   2 /*=========================================================================
   3
   4   Program:   CMake - Cross-Platform Makefile Generator
   5   Module:    $RCSfile: cmCommandArgumentParser.y,v $
   6   Language:  C++
   7   Date:      $Date: 2006-10-04 18:37:41 $
   8   Version:   $Revision: 1.10 $
   9
  10   Copyright (c) 2002 Kitware, Inc., Insight Consortium.  All rights reserved.
  11   See Copyright.txt or http://www.cmake.org/HTML/Copyright.html for details.
  12
  13      This software is distributed WITHOUT ANY WARRANTY; without even
  14      the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15      PURPOSE.  See the above copyright notices for more information.
  16
  17 =========================================================================*/
  18 /*
  19
  20 This file must be translated to C and modified to build everywhere.
  21
  22 Run bison like this:
  23
  24   bison --yacc --name-prefix=cmCommandArgument_yy --defines=cmCommandArgumentParserTokens.h -ocmCommandArgumentParser.cxx cmCommandArgumentParser.y
  25
  26 Modify cmCommandArgumentParser.cxx:
  27   - remove TABs
  28
  29 */
  30
  31 #include "cmStandardIncludes.h"
  32
  33 /* Configure the parser to use a lexer object.  */
  34 #define YYPARSE_PARAM yyscanner
  35 #define YYLEX_PARAM yyscanner
  36 #define YYERROR_VERBOSE 1
  37 #define cmCommandArgument_yyerror(x) \
  38         cmCommandArgumentError(yyscanner, x)
  39 #define yyGetParser (cmCommandArgument_yyget_extra(yyscanner))
  40
  41 /* Make sure malloc and free are available on QNX.  */
  42 #ifdef __QNX__
  43 # include <malloc.h>
  44 #endif
  45
  46 /* Make sure the parser uses standard memory allocation.  The default
  47    generated parser malloc/free declarations do not work on all
  48    platforms.  */
  49 #include <stdlib.h>
  50 #define YYMALLOC malloc
  51 #define YYFREE free
  52
  53 /*-------------------------------------------------------------------------*/
  54 #include "cmCommandArgumentParserHelper.h" /* Interface to parser object.  */
  55 #include "cmCommandArgumentLexer.h"  /* Interface to lexer object.  */
  56 #include "cmCommandArgumentParserTokens.h" /* Need YYSTYPE for YY_DECL.  */
  57
  58 /* Forward declare the lexer entry point.  */
  59 YY_DECL;
  60
  61 /* Internal utility functions.  */
  62 static void cmCommandArgumentError(yyscan_t yyscanner, const char* message);
  63
  64 #define YYDEBUG 1
  65 //#define YYMAXDEPTH 100000
  66 //#define YYINITDEPTH 10000
  67
  68
  69 /* Disable some warnings in the generated code.  */
  70 #ifdef __BORLANDC__
  71 # pragma warn -8004 /* Variable assigned a value that is not used.  */
  72 # pragma warn -8008 /* condition always returns true */
  73 # pragma warn -8060 /* possibly incorrect assignment */
  74 # pragma warn -8066 /* unreachable code */
  75 #endif
  76 #ifdef _MSC_VER
  77 # pragma warning (disable: 4102) /* Unused goto label.  */
  78 # pragma warning (disable: 4065) /* Switch statement contains default but no
  79                                     case. */
  80 #endif
  81 %}
  82
  83 /* Generate a reentrant parser object.  */
  84 %pure_parser
  85
  86 /*
  87 %union {
  88   char* string;
  89 }
  90 */
  91
  92 /*-------------------------------------------------------------------------*/
  93 /* Tokens */
  94 %token cal_NCURLY
  95 %token cal_DCURLY
  96 %token cal_DOLLAR "$"
  97 %token cal_LCURLY "{"
  98 %token cal_RCURLY "}"
  99 %token cal_NAME
 100 %token cal_BSLASH "\\"
 101 %token cal_SYMBOL
 102 %token cal_AT     "@"
 103 %token cal_ERROR
 104 %token cal_ATNAME
 105
 106 /*-------------------------------------------------------------------------*/
 107 /* grammar */
 108 %%
 109
 110
 111 Start:
 112 GoalWithOptionalBackSlash
 113 {
 114   $<str>$ = 0;
 115   yyGetParser->SetResult($<str>1);
 116 }
 117
 118 GoalWithOptionalBackSlash:
 119 Goal
 120 {
 121   $<str>$ = $<str>1;
 122 }
 123 |
 124 Goal cal_BSLASH
 125 {
 126   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 127 }
 128
 129 Goal:
 130 {
 131   $<str>$ = 0;
 132 }
 133 |
 134 String Goal
 135 {
 136   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 137 }
 138
 139 String:
 140 OuterText
 141 {
 142   $<str>$ = $<str>1;
 143 }
 144 |
 145 Variable
 146 {
 147   $<str>$ = $<str>1;
 148 }
 149
 150 OuterText:
 151 cal_NAME
 152 {
 153   $<str>$ = $<str>1;
 154 }
 155 |
 156 cal_AT
 157 {
 158   $<str>$ = $<str>1;
 159 }
 160 |
 161 cal_DOLLAR
 162 {
 163   $<str>$ = $<str>1;
 164 }
 165 |
 166 cal_LCURLY
 167 {
 168   $<str>$ = $<str>1;
 169 }
 170 |
 171 cal_RCURLY
 172 {
 173   $<str>$ = $<str>1;
 174 }
 175 |
 176 cal_SYMBOL
 177 {
 178   $<str>$ = $<str>1;
 179 }
 180
 181 Variable:
 182 cal_NCURLY MultipleIds cal_RCURLY
 183 {
 184   $<str>$ = yyGetParser->ExpandSpecialVariable($<str>1,$<str>2);
 185   //std::cerr << __LINE__ << " here: [" << $<str>1 << "] [" << $<str>2 << "] [" << $<str>3 << "]" << std::endl;
 186 }
 187 |
 188 cal_DCURLY MultipleIds cal_RCURLY
 189 {
 190   $<str>$ = yyGetParser->ExpandVariable($<str>2);
 191   //std::cerr << __LINE__ << " here: [" << $<str>1 << "] [" << $<str>2 << "] [" << $<str>3 << "]" << std::endl;
 192 }
 193 |
 194 cal_ATNAME
 195 {
 196   $<str>$ = yyGetParser->ExpandVariableForAt($<str>1);
 197 }
 198
 199 MultipleIds:
 200 {
 201   $<str>$ = 0;
 202 }
 203 |
 204 ID MultipleIds
 205 {
 206   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 207 }
 208
 209 ID:
 210 cal_NAME
 211 {
 212   $<str>$ = $<str>1;
 213 }
 214 |
 215 Variable
 216 {
 217   $<str>$ = $<str>1;
 218 }
 219
 220
 221 %%
 222 /* End of grammar */
 223
 224 /*--------------------------------------------------------------------------*/
 225 void cmCommandArgumentError(yyscan_t yyscanner, const char* message)
 226 {
 227   yyGetParser->Error(message);
 228 }
 229