Modules/CMakeTestCXXCompiler.cmake

   1 # This file is used by EnableLanguage in cmGlobalGenerator to
   2 # determine that that selected C++ compiler can actually compile
   3 # and link the most basic of programs.   If not, a fatal error
   4 # is set and cmake stops processing commands and will not generate
   5 # any makefiles or projects.
   6 IF(NOT CMAKE_CXX_COMPILER_WORKS)
   7   MESSAGE(STATUS "Check for working CXX compiler: ${CMAKE_CXX_COMPILER}")
   8   FILE(WRITE ${CMAKE_BINARY_DIR}/CMakeTmp/testCXXCompiler.cxx
   9     "#ifndef __cplusplus\n"
  10     "# error \"The CMAKE_CXX_COMPILER is set to a C compiler\"\n"
  11     "#endif\n"
  12     "int main(){return 0;}\n")
  13   TRY_COMPILE(CMAKE_CXX_COMPILER_WORKS ${CMAKE_BINARY_DIR}
  14     ${CMAKE_BINARY_DIR}/CMakeTmp/testCXXCompiler.cxx
  15     OUTPUT_VARIABLE OUTPUT)
  16   SET(CXX_TEST_WAS_RUN 1)
  17 ENDIF(NOT CMAKE_CXX_COMPILER_WORKS)
  18
  19 IF(NOT CMAKE_CXX_COMPILER_WORKS)
  20   MESSAGE(STATUS "Check for working CXX compiler: ${CMAKE_CXX_COMPILER} -- broken")
  21   FILE(APPEND ${CMAKE_BINARY_DIR}/CMakeError.log
  22     "Determining if the CXX compiler works failed with "
  23     "the following output:\n${OUTPUT}\n\n")
  24   MESSAGE(FATAL_ERROR "The C++ compiler \"${CMAKE_CXX_COMPILER}\" "
  25     "is not able to compile a simple test program.\nIt fails "
  26     "with the following output:\n ${OUTPUT}\n\n"
  27     "CMake will not be able to correctly generate this project.")
  28 ELSE(NOT CMAKE_CXX_COMPILER_WORKS)
  29   IF(CXX_TEST_WAS_RUN)
  30     MESSAGE(STATUS "Check for working CXX compiler: ${CMAKE_CXX_COMPILER} -- works")
  31     FILE(APPEND ${CMAKE_BINARY_DIR}/CMakeOutput.log
  32       "Determining if the CXX compiler works passed with "
  33       "the following output:\n${OUTPUT}\n\n")
  34   ENDIF(CXX_TEST_WAS_RUN)
  35   SET(CMAKE_CXX_COMPILER_WORKS 1 CACHE INTERNAL "")
  36 ENDIF(NOT CMAKE_CXX_COMPILER_WORKS)