Modules/FindSDL.cmake

   1 # Locate SDL library
   2 # This module defines
   3 # SDL_LIBRARY, the name of the library to link against
   4 # SDL_FOUND, if false, do not try to link to SDL
   5 # SDL_INCLUDE_DIR, where to find SDL.h
   6 #
   7 # This module responds to the the flag:
   8 # SDL_BUILDING_LIBRARY
   9 # If this is defined, then no SDL_main will be linked in because
  10 # only applications need main().
  11 # Otherwise, it is assumed you are building an application and this
  12 # module will attempt to locate and set the the proper link flags
  13 # as part of the returned SDL_LIBRARY variable.
  14 #
  15 # Don't forget to include SDLmain.h and SDLmain.m your project for the
  16 # OS X framework based version. (Other versions link to -lSDLmain which
  17 # this module will try to find on your behalf.) Also for OS X, this
  18 # module will automatically add the -framework Cocoa on your behalf.
  19 #
  20 #
  21 # Additional Note: If you see an empty SDL_LIBRARY_TEMP in your configuration
  22 # and no SDL_LIBRARY, it means CMake did not find your SDL library
  23 # (SDL.dll, libsdl.so, SDL.framework, etc).
  24 # Set SDL_LIBRARY_TEMP to point to your SDL library, and configure again.
  25 # Similarly, if you see an empty SDLMAIN_LIBRARY, you should set this value
  26 # as appropriate. These values are used to generate the final SDL_LIBRARY
  27 # variable, but when these values are unset, SDL_LIBRARY does not get created.
  28 #
  29 #
  30 # $SDLDIR is an environment variable that would
  31 # correspond to the ./configure --prefix=$SDLDIR
  32 # used in building SDL.
  33 # l.e.galup  9-20-02
  34 #
  35 # Modified by Eric Wing.
  36 # Added code to assist with automated building by using environmental variables
  37 # and providing a more controlled/consistent search behavior.
  38 # Added new modifications to recognize OS X frameworks and
  39 # additional Unix paths (FreeBSD, etc).
  40 # Also corrected the header search path to follow "proper" SDL guidelines.
  41 # Added a search for SDLmain which is needed by some platforms.
  42 # Added a search for threads which is needed by some platforms.
  43 # Added needed compile switches for MinGW.
  44 #
  45 # On OSX, this will prefer the Framework version (if found) over others.
  46 # People will have to manually change the cache values of
  47 # SDL_LIBRARY to override this selection or set the CMake environment
  48 # CMAKE_INCLUDE_PATH to modify the search paths.
  49 #
  50 # Note that the header path has changed from SDL/SDL.h to just SDL.h
  51 # This needed to change because "proper" SDL convention
  52 # is #include "SDL.h", not <SDL/SDL.h>. This is done for portability
  53 # reasons because not all systems place things in SDL/ (see FreeBSD).
  54
  55 FIND_PATH(SDL_INCLUDE_DIR SDL.h
  56   HINTS
  57   $ENV{SDLDIR}
  58   PATH_SUFFIXES include/SDL include
  59   PATHS
  60   ~/Library/Frameworks
  61   /Library/Frameworks
  62   /usr/local/include/SDL12
  63   /usr/local/include/SDL11 # FreeBSD ports
  64   /usr/include/SDL12
  65   /usr/include/SDL11
  66   /sw # Fink
  67   /opt/local # DarwinPorts
  68   /opt/csw # Blastwave
  69   /opt
  70 )
  71 #MESSAGE("SDL_INCLUDE_DIR is ${SDL_INCLUDE_DIR}")
  72
  73 # SDL-1.1 is the name used by FreeBSD ports...
  74 # don't confuse it for the version number.
  75 FIND_LIBRARY(SDL_LIBRARY_TEMP
  76   NAMES SDL SDL-1.1
  77   HINTS
  78   $ENV{SDLDIR}
  79   PATH_SUFFIXES lib64 lib
  80   PATHS
  81   /sw
  82   /opt/local
  83   /opt/csw
  84   /opt
  85 )
  86
  87 #MESSAGE("SDL_LIBRARY_TEMP is ${SDL_LIBRARY_TEMP}")
  88
  89 IF(NOT SDL_BUILDING_LIBRARY)
  90   IF(NOT ${SDL_INCLUDE_DIR} MATCHES ".framework")
  91     # Non-OS X framework versions expect you to also dynamically link to
  92     # SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms
  93     # seem to provide SDLmain for compatibility even though they don't
  94     # necessarily need it.
  95     FIND_LIBRARY(SDLMAIN_LIBRARY
  96       NAMES SDLmain SDLmain-1.1
  97       HINTS
  98       $ENV{SDLDIR}
  99       PATH_SUFFIXES lib64 lib
 100       PATHS
 101       /sw
 102       /opt/local
 103       /opt/csw
 104       /opt
 105     )
 106   ENDIF(NOT ${SDL_INCLUDE_DIR} MATCHES ".framework")
 107 ENDIF(NOT SDL_BUILDING_LIBRARY)
 108
 109 # SDL may require threads on your system.
 110 # The Apple build may not need an explicit flag because one of the
 111 # frameworks may already provide it.
 112 # But for non-OSX systems, I will use the CMake Threads package.
 113 IF(NOT APPLE)
 114   FIND_PACKAGE(Threads)
 115 ENDIF(NOT APPLE)
 116
 117 # MinGW needs an additional library, mwindows
 118 # It's total link flags should look like -lmingw32 -lSDLmain -lSDL -lmwindows
 119 # (Actually on second look, I think it only needs one of the m* libraries.)
 120 IF(MINGW)
 121   SET(MINGW32_LIBRARY mingw32 CACHE STRING "mwindows for MinGW")
 122 ENDIF(MINGW)
 123
 124 SET(SDL_FOUND "NO")
 125 IF(SDL_LIBRARY_TEMP)
 126   # For SDLmain
 127   IF(NOT SDL_BUILDING_LIBRARY)
 128     IF(SDLMAIN_LIBRARY)
 129       SET(SDL_LIBRARY_TEMP ${SDLMAIN_LIBRARY} ${SDL_LIBRARY_TEMP})
 130     ENDIF(SDLMAIN_LIBRARY)
 131   ENDIF(NOT SDL_BUILDING_LIBRARY)
 132
 133   # For OS X, SDL uses Cocoa as a backend so it must link to Cocoa.
 134   # CMake doesn't display the -framework Cocoa string in the UI even
 135   # though it actually is there if I modify a pre-used variable.
 136   # I think it has something to do with the CACHE STRING.
 137   # So I use a temporary variable until the end so I can set the
 138   # "real" variable in one-shot.
 139   IF(APPLE)
 140     SET(SDL_LIBRARY_TEMP ${SDL_LIBRARY_TEMP} "-framework Cocoa")
 141   ENDIF(APPLE)
 142
 143   # For threads, as mentioned Apple doesn't need this.
 144   # In fact, there seems to be a problem if I used the Threads package
 145   # and try using this line, so I'm just skipping it entirely for OS X.
 146   IF(NOT APPLE)
 147     SET(SDL_LIBRARY_TEMP ${SDL_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
 148   ENDIF(NOT APPLE)
 149
 150   # For MinGW library
 151   IF(MINGW)
 152     SET(SDL_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL_LIBRARY_TEMP})
 153   ENDIF(MINGW)
 154
 155   # Set the final string here so the GUI reflects the final state.
 156   SET(SDL_LIBRARY ${SDL_LIBRARY_TEMP} CACHE STRING "Where the SDL Library can be found")
 157   # Set the temp variable to INTERNAL so it is not seen in the CMake GUI
 158   SET(SDL_LIBRARY_TEMP "${SDL_LIBRARY_TEMP}" CACHE INTERNAL "")
 159
 160   SET(SDL_FOUND "YES")
 161 ENDIF(SDL_LIBRARY_TEMP)
 162
 163 #MESSAGE("SDL_LIBRARY is ${SDL_LIBRARY}")
 164