Source/cmCommandArgumentParser.y

   1 %{
   2 /*=========================================================================
   3
   4   Program:   CMake - Cross-Platform Makefile Generator
   5   Module:    $RCSfile: cmCommandArgumentParser.y,v $
   6   Language:  C++
   7   Date:      $Date: 2008-12-18 14:58:01 $
   8   Version:   $Revision: 1.12 $
   9
  10   Copyright (c) 2002 Kitware, Inc., Insight Consortium.  All rights reserved.
  11   See Copyright.txt or http://www.cmake.org/HTML/Copyright.html for details.
  12
  13      This software is distributed WITHOUT ANY WARRANTY; without even
  14      the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15      PURPOSE.  See the above copyright notices for more information.
  16
  17 =========================================================================*/
  18 /*
  19
  20 This file must be translated to C and modified to build everywhere.
  21
  22 Run bison like this:
  23
  24   bison --yacc --name-prefix=cmCommandArgument_yy --defines=cmCommandArgumentParserTokens.h -ocmCommandArgumentParser.cxx cmCommandArgumentParser.y
  25
  26 Modify cmCommandArgumentParser.cxx:
  27   - remove TABs
  28   - put header block at top of file
  29
  30 */
  31
  32 #include "cmStandardIncludes.h"
  33
  34 /* Configure the parser to use a lexer object.  */
  35 #define YYPARSE_PARAM yyscanner
  36 #define YYLEX_PARAM yyscanner
  37 #define YYERROR_VERBOSE 1
  38 #define cmCommandArgument_yyerror(x) \
  39         cmCommandArgumentError(yyscanner, x)
  40 #define yyGetParser (cmCommandArgument_yyget_extra(yyscanner))
  41
  42 /* Make sure malloc and free are available on QNX.  */
  43 #ifdef __QNX__
  44 # include <malloc.h>
  45 #endif
  46
  47 /* Make sure the parser uses standard memory allocation.  The default
  48    generated parser malloc/free declarations do not work on all
  49    platforms.  */
  50 #include <stdlib.h>
  51 #define YYMALLOC malloc
  52 #define YYFREE free
  53
  54 /*-------------------------------------------------------------------------*/
  55 #include "cmCommandArgumentParserHelper.h" /* Interface to parser object.  */
  56 #include "cmCommandArgumentLexer.h"  /* Interface to lexer object.  */
  57 #include "cmCommandArgumentParserTokens.h" /* Need YYSTYPE for YY_DECL.  */
  58
  59 /* Forward declare the lexer entry point.  */
  60 YY_DECL;
  61
  62 /* Internal utility functions.  */
  63 static void cmCommandArgumentError(yyscan_t yyscanner, const char* message);
  64
  65 #define YYDEBUG 1
  66 /* Configure the parser to support large input.  */
  67 #define YYMAXDEPTH 100000
  68 #define YYINITDEPTH 10000
  69
  70 /* Disable some warnings in the generated code.  */
  71 #ifdef __BORLANDC__
  72 # pragma warn -8004 /* Variable assigned a value that is not used.  */
  73 # pragma warn -8008 /* condition always returns true */
  74 # pragma warn -8060 /* possibly incorrect assignment */
  75 # pragma warn -8066 /* unreachable code */
  76 #endif
  77 #ifdef _MSC_VER
  78 # pragma warning (disable: 4102) /* Unused goto label.  */
  79 # pragma warning (disable: 4065) /* Switch statement contains default but no
  80                                     case. */
  81 # pragma warning (disable: 4244) /* loss of precision */
  82 # pragma warning (disable: 4702) /* unreachable code */
  83 #endif
  84 %}
  85
  86 /* Generate a reentrant parser object.  */
  87 %pure_parser
  88
  89 /*
  90 %union {
  91   char* string;
  92 }
  93 */
  94
  95 /*-------------------------------------------------------------------------*/
  96 /* Tokens */
  97 %token cal_ENVCURLY
  98 %token cal_NCURLY
  99 %token cal_DCURLY
 100 %token cal_DOLLAR "$"
 101 %token cal_LCURLY "{"
 102 %token cal_RCURLY "}"
 103 %token cal_NAME
 104 %token cal_BSLASH "\\"
 105 %token cal_SYMBOL
 106 %token cal_AT     "@"
 107 %token cal_ERROR
 108 %token cal_ATNAME
 109
 110 /*-------------------------------------------------------------------------*/
 111 /* grammar */
 112 %%
 113
 114
 115 Start:
 116 GoalWithOptionalBackSlash
 117 {
 118   $<str>$ = 0;
 119   yyGetParser->SetResult($<str>1);
 120 }
 121
 122 GoalWithOptionalBackSlash:
 123 Goal
 124 {
 125   $<str>$ = $<str>1;
 126 }
 127 |
 128 Goal cal_BSLASH
 129 {
 130   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 131 }
 132
 133 Goal:
 134 {
 135   $<str>$ = 0;
 136 }
 137 |
 138 String Goal
 139 {
 140   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 141 }
 142
 143 String:
 144 OuterText
 145 {
 146   $<str>$ = $<str>1;
 147 }
 148 |
 149 Variable
 150 {
 151   $<str>$ = $<str>1;
 152 }
 153
 154 OuterText:
 155 cal_NAME
 156 {
 157   $<str>$ = $<str>1;
 158 }
 159 |
 160 cal_AT
 161 {
 162   $<str>$ = $<str>1;
 163 }
 164 |
 165 cal_DOLLAR
 166 {
 167   $<str>$ = $<str>1;
 168 }
 169 |
 170 cal_LCURLY
 171 {
 172   $<str>$ = $<str>1;
 173 }
 174 |
 175 cal_RCURLY
 176 {
 177   $<str>$ = $<str>1;
 178 }
 179 |
 180 cal_SYMBOL
 181 {
 182   $<str>$ = $<str>1;
 183 }
 184
 185 Variable:
 186 cal_ENVCURLY EnvVarName cal_RCURLY
 187 {
 188   $<str>$ = yyGetParser->ExpandSpecialVariable($<str>1,$<str>2);
 189   //std::cerr << __LINE__ << " here: [" << $<str>1 << "] [" << $<str>2 << "] [" << $<str>3 << "]" << std::endl;
 190 }
 191 |
 192 cal_NCURLY MultipleIds cal_RCURLY
 193 {
 194   $<str>$ = yyGetParser->ExpandSpecialVariable($<str>1,$<str>2);
 195   //std::cerr << __LINE__ << " here: [" << $<str>1 << "] [" << $<str>2 << "] [" << $<str>3 << "]" << std::endl;
 196 }
 197 |
 198 cal_DCURLY MultipleIds cal_RCURLY
 199 {
 200   $<str>$ = yyGetParser->ExpandVariable($<str>2);
 201   //std::cerr << __LINE__ << " here: [" << $<str>1 << "] [" << $<str>2 << "] [" << $<str>3 << "]" << std::endl;
 202 }
 203 |
 204 cal_ATNAME
 205 {
 206   $<str>$ = yyGetParser->ExpandVariableForAt($<str>1);
 207 }
 208
 209 EnvVarName:
 210 MultipleIds
 211 {
 212   $<str>$ = $<str>1;
 213 }
 214 |
 215 cal_SYMBOL EnvVarName
 216 {
 217   $<str>$ = $<str>1;
 218 }
 219
 220 MultipleIds:
 221 {
 222   $<str>$ = 0;
 223 }
 224 |
 225 ID MultipleIds
 226 {
 227   $<str>$ = yyGetParser->CombineUnions($<str>1, $<str>2);
 228 }
 229
 230 ID:
 231 cal_NAME
 232 {
 233   $<str>$ = $<str>1;
 234 }
 235 |
 236 Variable
 237 {
 238   $<str>$ = $<str>1;
 239 }
 240
 241
 242 %%
 243 /* End of grammar */
 244
 245 /*--------------------------------------------------------------------------*/
 246 void cmCommandArgumentError(yyscan_t yyscanner, const char* message)
 247 {
 248   yyGetParser->Error(message);
 249 }
 250