Modules/FindSDL.cmake

   1 # Locate SDL library
   2 # This module defines
   3 # SDL_LIBRARY, the name of the library to link against
   4 # SDL_FOUND, if false, do not try to link to SDL
   5 # SDL_INCLUDE_DIR, where to find SDL.h
   6 #
   7 # This module responds to the the flag:
   8 # SDL_BUILDING_LIBRARY
   9 # If this is defined, then no SDL_main will be linked in because
  10 # only applications need main().
  11 # Otherwise, it is assumed you are building an application and this
  12 # module will attempt to locate and set the the proper link flags
  13 # as part of the returned SDL_LIBRARY variable.
  14 #
  15 # Don't forget to include SDLmain.h and SDLmain.m your project for the
  16 # OS X framework based version. (Other versions link to -lSDLmain which
  17 # this module will try to find on your behalf.) Also for OS X, this
  18 # module will automatically add the -framework Cocoa on your behalf.
  19 #
  20 #
  21 # Additional Note: If you see an empty SDL_LIBRARY_TEMP in your configuration
  22 # and no SDL_LIBRARY, it means CMake did not find your SDL library
  23 # (SDL.dll, libsdl.so, SDL.framework, etc).
  24 # Set SDL_LIBRARY_TEMP to point to your SDL library, and configure again.
  25 # Similarly, if you see an empty SDLMAIN_LIBRARY, you should set this value
  26 # as appropriate. These values are used to generate the final SDL_LIBRARY
  27 # variable, but when these values are unset, SDL_LIBRARY does not get created.
  28 #
  29 #
  30 # $SDLDIR is an environment variable that would
  31 # correspond to the ./configure --prefix=$SDLDIR
  32 # used in building SDL.
  33 # l.e.galup  9-20-02
  34 #
  35 # Modified by Eric Wing.
  36 # Added code to assist with automated building by using environmental variables
  37 # and providing a more controlled/consistent search behavior.
  38 # Added new modifications to recognize OS X frameworks and
  39 # additional Unix paths (FreeBSD, etc).
  40 # Also corrected the header search path to follow "proper" SDL guidelines.
  41 # Added a search for SDLmain which is needed by some platforms.
  42 # Added a search for threads which is needed by some platforms.
  43 # Added needed compile switches for MinGW.
  44 #
  45 # On OSX, this will prefer the Framework version (if found) over others.
  46 # People will have to manually change the cache values of
  47 # SDL_LIBRARY to override this selection or set the CMake environment
  48 # CMAKE_INCLUDE_PATH to modify the search paths.
  49 #
  50 # Note that the header path has changed from SDL/SDL.h to just SDL.h
  51 # This needed to change because "proper" SDL convention
  52 # is #include "SDL.h", not <SDL/SDL.h>. This is done for portability
  53 # reasons because not all systems place things in SDL/ (see FreeBSD).
  54
  55 FIND_PATH(SDL_INCLUDE_DIR SDL.h
  56   HINTS
  57   $ENV{SDLDIR}
  58   PATH_SUFFIXES include
  59   PATHS
  60   ~/Library/Frameworks
  61   /Library/Frameworks
  62   /usr/local/include/SDL
  63   /usr/include/SDL
  64   /usr/local/include/SDL12
  65   /usr/local/include/SDL11 # FreeBSD ports
  66   /usr/include/SDL12
  67   /usr/include/SDL11
  68   /usr/local/include
  69   /usr/include
  70   /sw/include/SDL # Fink
  71   /sw/include
  72   /opt/local/include/SDL # DarwinPorts
  73   /opt/local/include
  74   /opt/csw/include/SDL # Blastwave
  75   /opt/csw/include
  76   /opt/include/SDL
  77   /opt/include
  78 )
  79 #MESSAGE("SDL_INCLUDE_DIR is ${SDL_INCLUDE_DIR}")
  80
  81 # SDL-1.1 is the name used by FreeBSD ports...
  82 # don't confuse it for the version number.
  83 FIND_LIBRARY(SDL_LIBRARY_TEMP
  84   NAMES SDL SDL-1.1
  85   HINTS
  86   $ENV{SDLDIR}
  87   PATH_SUFFIXES lib64 lib
  88   PATHS
  89   /usr/local
  90   /usr
  91   /sw
  92   /opt/local
  93   /opt/csw
  94   /opt
  95 )
  96
  97 #MESSAGE("SDL_LIBRARY_TEMP is ${SDL_LIBRARY_TEMP}")
  98
  99 IF(NOT SDL_BUILDING_LIBRARY)
 100   IF(NOT ${SDL_INCLUDE_DIR} MATCHES ".framework")
 101     # Non-OS X framework versions expect you to also dynamically link to
 102     # SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms
 103     # seem to provide SDLmain for compatibility even though they don't
 104     # necessarily need it.
 105     FIND_LIBRARY(SDLMAIN_LIBRARY
 106       NAMES SDLmain SDLmain-1.1
 107       HINTS
 108       $ENV{SDLDIR}
 109       PATH_SUFFIXES lib64 lib
 110       PATHS
 111       /usr/local
 112       /usr
 113       /sw
 114       /opt/local
 115       /opt/csw
 116       /opt
 117     )
 118   ENDIF(NOT ${SDL_INCLUDE_DIR} MATCHES ".framework")
 119 ENDIF(NOT SDL_BUILDING_LIBRARY)
 120
 121 # SDL may require threads on your system.
 122 # The Apple build may not need an explicit flag because one of the
 123 # frameworks may already provide it.
 124 # But for non-OSX systems, I will use the CMake Threads package.
 125 IF(NOT APPLE)
 126   FIND_PACKAGE(Threads)
 127 ENDIF(NOT APPLE)
 128
 129 # MinGW needs an additional library, mwindows
 130 # It's total link flags should look like -lmingw32 -lSDLmain -lSDL -lmwindows
 131 # (Actually on second look, I think it only needs one of the m* libraries.)
 132 IF(MINGW)
 133   SET(MINGW32_LIBRARY mingw32 CACHE STRING "mwindows for MinGW")
 134 ENDIF(MINGW)
 135
 136 SET(SDL_FOUND "NO")
 137 IF(SDL_LIBRARY_TEMP)
 138   # For SDLmain
 139   IF(NOT SDL_BUILDING_LIBRARY)
 140     IF(SDLMAIN_LIBRARY)
 141       SET(SDL_LIBRARY_TEMP ${SDLMAIN_LIBRARY} ${SDL_LIBRARY_TEMP})
 142     ENDIF(SDLMAIN_LIBRARY)
 143   ENDIF(NOT SDL_BUILDING_LIBRARY)
 144
 145   # For OS X, SDL uses Cocoa as a backend so it must link to Cocoa.
 146   # CMake doesn't display the -framework Cocoa string in the UI even
 147   # though it actually is there if I modify a pre-used variable.
 148   # I think it has something to do with the CACHE STRING.
 149   # So I use a temporary variable until the end so I can set the
 150   # "real" variable in one-shot.
 151   IF(APPLE)
 152     SET(SDL_LIBRARY_TEMP ${SDL_LIBRARY_TEMP} "-framework Cocoa")
 153   ENDIF(APPLE)
 154
 155   # For threads, as mentioned Apple doesn't need this.
 156   # In fact, there seems to be a problem if I used the Threads package
 157   # and try using this line, so I'm just skipping it entirely for OS X.
 158   IF(NOT APPLE)
 159     SET(SDL_LIBRARY_TEMP ${SDL_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
 160   ENDIF(NOT APPLE)
 161
 162   # For MinGW library
 163   IF(MINGW)
 164     SET(SDL_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL_LIBRARY_TEMP})
 165   ENDIF(MINGW)
 166
 167   # Set the final string here so the GUI reflects the final state.
 168   SET(SDL_LIBRARY ${SDL_LIBRARY_TEMP} CACHE STRING "Where the SDL Library can be found")
 169   # Set the temp variable to INTERNAL so it is not seen in the CMake GUI
 170   SET(SDL_LIBRARY_TEMP "${SDL_LIBRARY_TEMP}" CACHE INTERNAL "")
 171
 172   SET(SDL_FOUND "YES")
 173 ENDIF(SDL_LIBRARY_TEMP)
 174
 175 #MESSAGE("SDL_LIBRARY is ${SDL_LIBRARY}")
 176