Modules/UseEcos.cmake

   1 # - This module defines variables and macros required to build eCos application.
   2 # This file contains the following macros:
   3 # ECOS_ADD_INCLUDE_DIRECTORIES() - add the eCos include dirs
   4 # ECOS_ADD_EXECUTABLE(name source1 ... sourceN ) - create an eCos executable
   5 # ECOS_ADJUST_DIRECTORY(VAR source1 ... sourceN ) - adjusts the path of the source files and puts the result into VAR
   6 #
   7 # Macros for selecting the toolchain:
   8 # ECOS_USE_ARM_ELF_TOOLS()       - enable the ARM ELF toolchain for the directory where it is called
   9 # ECOS_USE_I386_ELF_TOOLS()      - enable the i386 ELF toolchain for the directory where it is called
  10 # ECOS_USE_PPC_EABI_TOOLS()      - enable the PowerPC toolchain for the directory where it is called
  11 #
  12 # It contains the following variables:
  13 # ECOS_DEFINITIONS
  14 # ECOSCONFIG_EXECUTABLE
  15 # ECOS_CONFIG_FILE               - defaults to ecos.ecc, if your eCos configuration file has a different name, adjust this variable
  16 # for internal use only:
  17 #  ECOS_ADD_TARGET_LIB
  18
  19 # first check that ecosconfig is available
  20 FIND_PROGRAM(ECOSCONFIG_EXECUTABLE NAMES ecosconfig)
  21 IF(NOT ECOSCONFIG_EXECUTABLE)
  22    MESSAGE(SEND_ERROR "ecosconfig was not found. Either include it in the system path or set it manually using ccmake.")
  23 ELSE(NOT ECOSCONFIG_EXECUTABLE)
  24    MESSAGE(STATUS "Found ecosconfig: ${ECOSCONFIG_EXECUTABLE}")
  25 ENDIF(NOT ECOSCONFIG_EXECUTABLE)
  26
  27 # check that ECOS_REPOSITORY is set correctly
  28 IF (NOT EXISTS $ENV{ECOS_REPOSITORY}/ecos.db)
  29    MESSAGE(SEND_ERROR "The environment variable ECOS_REPOSITORY is not set correctly. Set it to the directory which contains the file ecos.db")
  30 ELSE (NOT EXISTS $ENV{ECOS_REPOSITORY}/ecos.db)
  31    MESSAGE(STATUS "ECOS_REPOSITORY is set to $ENV{ECOS_REPOSITORY}")
  32 ENDIF (NOT EXISTS $ENV{ECOS_REPOSITORY}/ecos.db)
  33
  34 # check that tclsh (coming with TCL) is available, otherwise ecosconfig doesn't work
  35 FIND_PACKAGE(Tclsh)
  36 IF (NOT TCL_TCLSH)
  37    MESSAGE(SEND_ERROR "The TCL tclsh was not found. Please install TCL, it is required for building eCos applications.")
  38 ELSE (NOT TCL_TCLSH)
  39    MESSAGE(STATUS "tlcsh found: ${TCL_TCLSH}")
  40 ENDIF (NOT TCL_TCLSH)
  41
  42 #add the globale include-diretories
  43 #usage: ECOS_ADD_INCLUDE_DIRECTORIES()
  44 MACRO(ECOS_ADD_INCLUDE_DIRECTORIES)
  45 #check for ProjectSources.txt one level higher
  46    IF (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../ProjectSources.txt)
  47       INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/../)
  48    ELSE (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../ProjectSources.txt)
  49       INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/)
  50    ENDIF (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../ProjectSources.txt)
  51
  52 #the ecos include directory
  53    INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/ecos/install/include/)
  54
  55 ENDMACRO(ECOS_ADD_INCLUDE_DIRECTORIES)
  56
  57
  58 #we want to compile for the xscale processor, in this case the following macro has to be called
  59 #usage: ECOS_USE_ARM_ELF_TOOLS()
  60 MACRO (ECOS_USE_ARM_ELF_TOOLS)
  61    SET(CMAKE_CXX_COMPILER "arm-elf-c++")
  62    SET(CMAKE_COMPILER_IS_GNUCXX 1)
  63    SET(CMAKE_C_COMPILER "arm-elf-gcc")
  64    SET(CMAKE_AR "arm-elf-ar")
  65    SET(CMAKE_RANLIB "arm-elf-ranlib")
  66 #for linking
  67    SET(ECOS_LD_MCPU "-mcpu=xscale")
  68 #for compiling
  69    ADD_DEFINITIONS(-mcpu=xscale -mapcs-frame)
  70 #for the obj-tools
  71    SET(ECOS_ARCH_PREFIX "arm-elf-")
  72 ENDMACRO (ECOS_USE_ARM_ELF_TOOLS)
  73
  74 #usage: ECOS_USE_PPC_EABI_TOOLS()
  75 MACRO (ECOS_USE_PPC_EABI_TOOLS)
  76    SET(CMAKE_CXX_COMPILER "powerpc-eabi-c++")
  77    SET(CMAKE_COMPILER_IS_GNUCXX 1)
  78    SET(CMAKE_C_COMPILER "powerpc-eabi-gcc")
  79    SET(CMAKE_AR "powerpc-eabi-ar")
  80    SET(CMAKE_RANLIB "powerpc-eabi-ranlib")
  81 #for linking
  82    SET(ECOS_LD_MCPU "")
  83 #for compiling
  84    ADD_DEFINITIONS()
  85 #for the obj-tools
  86    SET(ECOS_ARCH_PREFIX "powerpc-eabi-")
  87 ENDMACRO (ECOS_USE_PPC_EABI_TOOLS)
  88
  89 #usage: ECOS_USE_I386_ELF_TOOLS()
  90 MACRO (ECOS_USE_I386_ELF_TOOLS)
  91    SET(CMAKE_CXX_COMPILER "i386-elf-c++")
  92    SET(CMAKE_COMPILER_IS_GNUCXX 1)
  93    SET(CMAKE_C_COMPILER "i386-elf-gcc")
  94    SET(CMAKE_AR "i386-elf-ar")
  95    SET(CMAKE_RANLIB "i386-elf-ranlib")
  96 #for linking
  97    SET(ECOS_LD_MCPU "")
  98 #for compiling
  99    ADD_DEFINITIONS()
 100 #for the obj-tools
 101    SET(ECOS_ARCH_PREFIX "i386-elf-")
 102 ENDMACRO (ECOS_USE_I386_ELF_TOOLS)
 103
 104
 105 #since the actual sources are located one level upwards
 106 #a "../" has to be prepended in front of every source file
 107 #call the following macro to achieve this, the first parameter
 108 #is the name of the new list of source files with adjusted paths,
 109 #followed by all source files
 110 #usage: ECOS_ADJUST_DIRECTORY(adjusted_SRCS ${my_srcs})
 111 MACRO(ECOS_ADJUST_DIRECTORY _target_FILES )
 112    FOREACH (_current_FILE ${ARGN})
 113       GET_FILENAME_COMPONENT(_abs_FILE ${_current_FILE} ABSOLUTE)
 114       IF (NOT ${_abs_FILE} STREQUAL ${_current_FILE})
 115          GET_FILENAME_COMPONENT(_abs_FILE ${CMAKE_CURRENT_SOURCE_DIR}/../${_current_FILE} ABSOLUTE)
 116       ENDIF (NOT ${_abs_FILE} STREQUAL ${_current_FILE})
 117       LIST(APPEND ${_target_FILES} ${_abs_FILE})
 118    ENDFOREACH (_current_FILE)
 119 ENDMACRO(ECOS_ADJUST_DIRECTORY)
 120
 121 # the default ecos config file name
 122 # maybe in the future also out-of-source builds may be possible
 123 SET(ECOS_CONFIG_FILE ecos.ecc)
 124
 125 #creates the dependancy from all source files on the ecos target.ld,
 126 #adds the command for compiling ecos
 127 MACRO(ECOS_ADD_TARGET_LIB)
 128 # when building out-of-source, create the ecos/ subdir
 129     IF(NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/ecos)
 130         FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/ecos)
 131     ENDIF(NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/ecos)
 132
 133 #sources depend on target.ld
 134    SET_SOURCE_FILES_PROPERTIES(
 135       ${ARGN}
 136       PROPERTIES
 137       OBJECT_DEPENDS
 138       ${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib/target.ld
 139    )
 140
 141    ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib/target.ld
 142       COMMAND sh -c \"make -C ${CMAKE_CURRENT_BINARY_DIR}/ecos || exit -1\; if [ -e ${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib/target.ld ] \; then touch ${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib/target.ld\; fi\"
 143       DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/ecos/makefile
 144    )
 145
 146    ADD_CUSTOM_COMMAND(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/ecos/makefile
 147       COMMAND sh -c \" cd ${CMAKE_CURRENT_BINARY_DIR}/ecos\; ${ECOSCONFIG_EXECUTABLE} --config=${CMAKE_CURRENT_SOURCE_DIR}/ecos/${ECOS_CONFIG_FILE} tree || exit -1\;\"
 148       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/ecos/${ECOS_CONFIG_FILE}
 149    )
 150
 151    ADD_CUSTOM_TARGET( ecos make -C ${CMAKE_CURRENT_BINARY_DIR}/ecos/ DEPENDS  ${CMAKE_CURRENT_BINARY_DIR}/ecos/makefile )
 152 ENDMACRO(ECOS_ADD_TARGET_LIB)
 153
 154 # get the directory of the current file, used later on in the file
 155 GET_FILENAME_COMPONENT( ECOS_CMAKE_MODULE_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
 156
 157 #macro for creating an executable ecos application
 158 #the first parameter is the name of the executable,
 159 #the second is the list of all source files (where the path
 160 #has been adjusted beforehand by calling ECOS_ADJUST_DIRECTORY()
 161 #usage: ECOS_ADD_EXECUTABLE(my_app ${adjusted_SRCS})
 162 MACRO(ECOS_ADD_EXECUTABLE _exe_NAME )
 163    #definitions, valid for all ecos projects
 164    #the optimization and "-g" for debugging has to be enabled
 165    #in the project-specific CMakeLists.txt
 166    ADD_DEFINITIONS(-D__ECOS__=1 -D__ECOS=1)
 167    SET(ECOS_DEFINITIONS -Wall -Wno-long-long -pipe -fno-builtin)
 168
 169 #the executable depends on ecos target.ld
 170    ECOS_ADD_TARGET_LIB(${ARGN})
 171
 172 # when using nmake makefiles, the custom buildtype supresses the default cl.exe flags
 173 # and the rules for creating objects are adjusted for gcc
 174    SET(CMAKE_BUILD_TYPE CUSTOM_ECOS_BUILD)
 175    SET(CMAKE_C_COMPILE_OBJECT     "<CMAKE_C_COMPILER>   <FLAGS> -o <OBJECT> -c <SOURCE>")
 176    SET(CMAKE_CXX_COMPILE_OBJECT   "<CMAKE_CXX_COMPILER> <FLAGS> -o <OBJECT> -c <SOURCE>")
 177 # special link commands for ecos-executables
 178    SET(CMAKE_CXX_LINK_EXECUTABLE  "<CMAKE_CXX_COMPILER> <CMAKE_CXX_LINK_FLAGS> <OBJECTS>  -o <TARGET> ${_ecos_EXTRA_LIBS} -nostdlib  -nostartfiles -L${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib -Ttarget.ld ${ECOS_LD_MCPU}")
 179    SET(CMAKE_C_LINK_EXECUTABLE    "<CMAKE_C_COMPILER>   <CMAKE_C_LINK_FLAGS>   <OBJECTS>  -o <TARGET> ${_ecos_EXTRA_LIBS} -nostdlib  -nostartfiles -L${CMAKE_CURRENT_BINARY_DIR}/ecos/install/lib -Ttarget.ld ${ECOS_LD_MCPU}")
 180 # some strict compiler flags
 181    SET (CMAKE_C_FLAGS "-Wstrict-prototypes")
 182    SET (CMAKE_CXX_FLAGS "-Woverloaded-virtual -fno-rtti -Wctor-dtor-privacy -fno-strict-aliasing -fno-exceptions")
 183
 184    ADD_EXECUTABLE(${_exe_NAME} ${ARGN})
 185    SET_TARGET_PROPERTIES(${_exe_NAME} PROPERTIES SUFFIX ".elf")
 186
 187 #create a binary file
 188    ADD_CUSTOM_COMMAND(
 189       TARGET ${_exe_NAME}
 190       POST_BUILD
 191       COMMAND ${ECOS_ARCH_PREFIX}objcopy
 192       ARGS -O binary ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.elf ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.bin
 193    )
 194
 195 #and an srec file
 196    ADD_CUSTOM_COMMAND(
 197       TARGET ${_exe_NAME}
 198       POST_BUILD
 199       COMMAND ${ECOS_ARCH_PREFIX}objcopy
 200       ARGS -O srec ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.elf ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.srec
 201    )
 202
 203 #add the created files to the clean-files
 204    SET_DIRECTORY_PROPERTIES(
 205       PROPERTIES
 206        ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.bin;${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.srec;${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst;"
 207    )
 208
 209    ADD_CUSTOM_TARGET(ecosclean ${CMAKE_COMMAND} -DECOS_DIR=${CMAKE_CURRENT_BINARY_DIR}/ecos/ -P ${ECOS_CMAKE_MODULE_DIR}/ecos_clean.cmake  )
 210    ADD_CUSTOM_TARGET(normalclean ${CMAKE_MAKE_PROGRAM} clean WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 211    ADD_DEPENDENCIES (ecosclean normalclean)
 212
 213
 214    ADD_CUSTOM_TARGET( listing
 215       COMMAND echo -e   \"\\n--- Symbols sorted by address ---\\n\" > ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst
 216       COMMAND ${ECOS_ARCH_PREFIX}nm -S -C -n ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.elf >> ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst
 217       COMMAND echo -e \"\\n--- Symbols sorted by size ---\\n\" >> ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst
 218       COMMAND ${ECOS_ARCH_PREFIX}nm -S -C -r --size-sort ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.elf >> ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst
 219       COMMAND echo -e \"\\n--- Full assembly listing ---\\n\" >> ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst
 220       COMMAND ${ECOS_ARCH_PREFIX}objdump -S -x -d -C ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.elf >> ${CMAKE_CURRENT_BINARY_DIR}/${_exe_NAME}.lst )
 221
 222 ENDMACRO(ECOS_ADD_EXECUTABLE)
 223