Source/cmDependsFortranLexer.in.l

   1 %{
   2 /*=========================================================================
   3
   4   Program:   CMake - Cross-Platform Makefile Generator
   5   Module:    $RCSfile: cmDependsFortranLexer.in.l,v $
   6   Language:  C++
   7   Date:      $Date: 2008-04-24 03:53:20 $
   8   Version:   $Revision: 1.13 $
   9
  10   Copyright (c) 2002 Kitware, Inc., Insight Consortium.  All rights reserved.
  11   See Copyright.txt or http://www.cmake.org/HTML/Copyright.html for details.
  12
  13      This software is distributed WITHOUT ANY WARRANTY; without even
  14      the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15      PURPOSE.  See the above copyright notices for more information.
  16
  17 =========================================================================*/
  18 /*-------------------------------------------------------------------------
  19   Portions of this source have been derived from makedepf90 version 2.8.8,
  20
  21    Copyright (C) 2000--2006 Erik Edelmann <erik.edelmann@iki.fi>
  22
  23   The code was originally distributed under the GPL but permission
  24   from the copyright holder has been obtained to distribute this
  25   derived work under the CMake license.
  26 -------------------------------------------------------------------------*/
  27
  28 /*
  29
  30 This file must be translated to C and modified to build everywhere.
  31
  32 Run flex like this:
  33
  34   flex -i --prefix=cmDependsFortran_yy --header-file=cmDependsFortranLexer.h -ocmDependsFortranLexer.cxx cmDependsFortranLexer.in.l
  35
  36 Modify cmDependsFortranLexer.cxx:
  37   - remove TABs
  38   - remove "yyscanner" argument from these methods:
  39       yy_fatal_error, cmDependsFortran_yyalloc, cmDependsFortran_yyrealloc, cmDependsFortran_yyfree
  40   - remove all YY_BREAK lines occurring right after return statements
  41   - change while ( 1 ) to for(;;)
  42
  43 Modify cmDependsFortranLexer.h:
  44   - remove TABs
  45   - remove the yy_init_globals function
  46   - remove the block that includes unistd.h
  47   - remove #line directives (avoids bogus warning on old Sun)
  48
  49 */
  50
  51 #include "cmStandardLexer.h"
  52
  53 #define cmDependsFortranLexer_cxx
  54 #include "cmDependsFortranParser.h" /* Interface to parser object.  */
  55
  56 /* Replace the lexer input function.  */
  57 #undef YY_INPUT
  58 #define YY_INPUT(buf, result, max_size) \
  59   { result = cmDependsFortranParser_Input(yyextra, buf, max_size); }
  60
  61 /* Include the set of tokens from the parser.  */
  62 #include "cmDependsFortranParserTokens.h"
  63
  64 /*--------------------------------------------------------------------------*/
  65 %}
  66
  67
  68 %option reentrant
  69 %option noyywrap
  70 %pointer
  71
  72 %s free_fmt fixed_fmt
  73 %x str_sq str_dq
  74
  75 %%
  76
  77 \"              {
  78   cmDependsFortranParser_StringStart(yyextra);
  79   cmDependsFortranParser_SetOldStartcond(yyextra, YY_START);
  80   BEGIN(str_dq);
  81 }
  82
  83 '               {
  84   cmDependsFortranParser_StringStart(yyextra);
  85   cmDependsFortranParser_SetOldStartcond(yyextra, YY_START);
  86   BEGIN(str_sq);
  87 }
  88
  89 <str_dq>\" |
  90 <str_sq>'  {
  91   BEGIN(cmDependsFortranParser_GetOldStartcond(yyextra) );
  92   yylvalp->string = strdup(cmDependsFortranParser_StringEnd(yyextra));
  93   return STRING;
  94 }
  95
  96 <str_dq,str_sq>&[ \t]*\n |
  97 <str_dq,str_sq>&[ \t]*\n[ \t]*&  /* Ignore (continued strings, free fmt) */
  98
  99 <fixed_fmt,str_dq,str_sq>\n[ ]{5}[^ \t\n] {
 100   if (cmDependsFortranParser_GetOldStartcond(yyextra) == fixed_fmt)
 101     ; /* Ignore (cont. strings, fixed fmt) */
 102   else
 103     {
 104     unput(yytext[strlen(yytext)-1]);
 105     }
 106 }
 107
 108
 109 <str_dq,str_sq>\n {
 110   unput ('\n');
 111   BEGIN(INITIAL);
 112   return UNTERMINATED_STRING;
 113 }
 114
 115 <str_sq,str_dq>. {
 116   cmDependsFortranParser_StringAppend(yyextra, yytext[0]);
 117 }
 118
 119 !.*\n                   { return EOSTMT; } /* Treat comments like */
 120 <fixed_fmt>^[cC*dD].*\n { return EOSTMT; } /* empty lines */
 121
 122 ^[ \t]*#[ \t]*include  { return CPP_INCLUDE; }
 123 \$[ \t]*include { return F90PPR_INCLUDE; }
 124 \?\?[ \t]*include { return COCO_INCLUDE; }
 125
 126 ^[ \t]*#[ \t]*define   { return CPP_DEFINE; }
 127 \$[ \t]*DEFINE   { return F90PPR_DEFINE; }
 128
 129 ^[ \t]*#[ \t]*undef    { return CPP_UNDEF; }
 130 \$[ \t]*UNDEF   { return F90PPR_UNDEF; }
 131
 132 ^[ \t]*#[ \t]*ifdef    { return CPP_IFDEF; }
 133 ^[ \t]*#[ \t]*ifndef   { return CPP_IFNDEF; }
 134 ^[ \t]*#[ \t]*if       { return CPP_IF; }
 135 ^[ \t]*#[ \t]*elif     { return CPP_ELIF; }
 136 ^[ \t]*#[ \t]*else     { return CPP_ELSE; }
 137 ^[ \t]*#[ \t]*endif    { return CPP_ENDIF; }
 138
 139 $[ \t]*ifdef    { return F90PPR_IFDEF; }
 140 $[ \t]*ifndef   { return F90PPR_IFNDEF; }
 141 $[ \t]*if       { return F90PPR_IF; }
 142 $[ \t]*elif     { return F90PPR_ELIF; }
 143 $[ \t]*else     { return F90PPR_ELSE; }
 144 $[ \t]*endif    { return F90PPR_ENDIF; }
 145
 146  /* Line continuations, possible involving comments.  */
 147 &([ \t\n]*|!.*)*
 148 &([ \t\n]*|!.*)*&
 149
 150 , { return COMMA; }
 151
 152 :: { return DCOLON; }
 153
 154 <fixed_fmt>\n[ ]{5}[^ ]  { return GARBAGE; }
 155
 156 =|=>                     { return ASSIGNMENT_OP; }
 157
 158 [a-zA-Z_][a-zA-Z_0-9]* {
 159   yylvalp->string = strdup(yytext);
 160   return WORD;
 161 }
 162
 163 [^ \t\n\r;,!'"a-zA-Z=&]+ { return GARBAGE; }
 164
 165 ;|\n { return EOSTMT; }
 166
 167
 168 [ \t\r,]         /* Ignore */
 169 \\[ \t]*\n       /* Ignore line-endings preceeded by \ */
 170
 171 . { return *yytext; }
 172
 173 <<EOF>> {
 174   if(!cmDependsFortranParser_FilePop(yyextra) )
 175     {
 176     return YY_NULL;
 177     }
 178 }
 179
 180 %%
 181
 182 /*--------------------------------------------------------------------------*/
 183 YY_BUFFER_STATE cmDependsFortranLexer_GetCurrentBuffer(yyscan_t yyscanner)
 184 {
 185   /* Hack into the internal flex-generated scanner to get the buffer.  */
 186   struct yyguts_t * yyg = (struct yyguts_t*)yyscanner;
 187   return YY_CURRENT_BUFFER;
 188 }