Modules/UseQt4.cmake

   1 # - Use Module for QT4
   2 # Sets up C and C++ to use Qt 4.  It is assumed that FindQt.cmake
   3 # has already been loaded.  See FindQt.cmake for information on
   4 # how to load Qt 4 into your CMake project.
   5
   6
   7 ADD_DEFINITIONS(${QT_DEFINITIONS})
   8 SET_PROPERTY(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_DEBUG QT_DEBUG)
   9 SET_PROPERTY(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG)
  10 SET_PROPERTY(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_RELWITHDEBINFO QT_NO_DEBUG)
  11 SET_PROPERTY(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS_MINSIZEREL QT_NO_DEBUG)
  12
  13 INCLUDE_DIRECTORIES(${QT_INCLUDE_DIR})
  14
  15 SET(QT_LIBRARIES "")
  16
  17 IF (QT_USE_QTMAIN)
  18   IF (WIN32)
  19     SET(QT_LIBRARIES ${QT_LIBRARIES} ${QT_QTMAIN_LIBRARY})
  20   ENDIF (WIN32)
  21 ENDIF (QT_USE_QTMAIN)
  22
  23 IF(QT_DONT_USE_QTGUI)
  24   SET(QT_USE_QTGUI 0)
  25 ELSE(QT_DONT_USE_QTGUI)
  26   SET(QT_USE_QTGUI 1)
  27 ENDIF(QT_DONT_USE_QTGUI)
  28
  29 IF(QT_DONT_USE_QTCORE)
  30   SET(QT_USE_QTCORE 0)
  31 ELSE(QT_DONT_USE_QTCORE)
  32   SET(QT_USE_QTCORE 1)
  33 ENDIF(QT_DONT_USE_QTCORE)
  34
  35 IF (QT_USE_QT3SUPPORT)
  36   ADD_DEFINITIONS(-DQT3_SUPPORT)
  37 ENDIF (QT_USE_QT3SUPPORT)
  38
  39 # list dependent modules, so dependent libraries are added
  40 SET(QT_QT3SUPPORT_MODULE_DEPENDS QTGUI QTSQL QTXML QTNETWORK QTCORE)
  41 SET(QT_QTSVG_MODULE_DEPENDS QTGUI QTXML QTCORE)
  42 SET(QT_QTUITOOLS_MODULE_DEPENDS QTGUI QTXML QTCORE)
  43 SET(QT_QTHELP_MODULE_DEPENDS QTGUI QTSQL QTXML QTCORE)
  44 SET(QT_PHONON_MODULE_DEPENDS QTGUI QTDBUS QTCORE)
  45 SET(QT_QTDBUS_MODULE_DEPENDS QTXML QTCORE)
  46 SET(QT_QTXMLPATTERNS_MODULE_DEPENDS QTNETWORK QTCORE)
  47
  48 # Qt modules  (in order of dependence)
  49 FOREACH(module QT3SUPPORT QTOPENGL QTASSISTANT QTDESIGNER QTMOTIF QTNSPLUGIN
  50                QTSCRIPT QTSVG QTUITOOLS QTHELP QTWEBKIT PHONON QTGUI QTTEST
  51                QTDBUS QTXML QTSQL QTXMLPATTERNS QTNETWORK QTCORE)
  52
  53   IF (QT_USE_${module} OR QT_USE_${module}_DEPENDS)
  54     IF (QT_${module}_FOUND)
  55       IF(QT_USE_${module})
  56         STRING(REPLACE "QT" "" qt_module_def "${module}")
  57         ADD_DEFINITIONS(-DQT_${qt_module_def}_LIB)
  58         INCLUDE_DIRECTORIES(${QT_${module}_INCLUDE_DIR})
  59       ENDIF(QT_USE_${module})
  60       SET(QT_LIBRARIES ${QT_LIBRARIES} ${QT_${module}_LIBRARY} ${QT_${module}_LIB_DEPENDENCIES})
  61       FOREACH(depend_module ${QT_${module}_MODULE_DEPENDS})
  62         SET(QT_USE_${depend_module}_DEPENDS 1)
  63       ENDFOREACH(depend_module ${QT_${module}_MODULE_DEPENDS})
  64     ELSE (QT_${module}_FOUND)
  65       MESSAGE("Qt ${module} library not found.")
  66     ENDIF (QT_${module}_FOUND)
  67   ENDIF (QT_USE_${module} OR QT_USE_${module}_DEPENDS)
  68
  69 ENDFOREACH(module)
  70