arch/arm/lib/clear_user.S

   1 /*
   2  *  linux/arch/arm/lib/clear_user.S
   3  *
   4  *  Copyright (C) 1995, 1996,1997,1998 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/linkage.h>
  11 #include <asm/assembler.h>
  12
  13                 .text
  14
  15 /* Prototype: int __clear_user(void *addr, size_t sz)
  16  * Purpose  : clear some user memory
  17  * Params   : addr - user memory address to clear
  18  *          : sz   - number of bytes to clear
  19  * Returns  : number of bytes NOT cleared
  20  */
  21 ENTRY(__clear_user_std)
  22 WEAK(__clear_user)
  23                 stmfd   sp!, {r1, lr}
  24                 mov     r2, #0
  25                 cmp     r1, #4
  26                 blt     2f
  27                 ands    ip, r0, #3
  28                 beq     1f
  29                 cmp     ip, #2
  30 USER(           strbt   r2, [r0], #1)
  31 USER(           strlebt r2, [r0], #1)
  32 USER(           strltbt r2, [r0], #1)
  33                 rsb     ip, ip, #4
  34                 sub     r1, r1, ip              @  7  6  5  4  3  2  1
  35 1:              subs    r1, r1, #8              @ -1 -2 -3 -4 -5 -6 -7
  36 USER(           strplt  r2, [r0], #4)
  37 USER(           strplt  r2, [r0], #4)
  38                 bpl     1b
  39                 adds    r1, r1, #4              @  3  2  1  0 -1 -2 -3
  40 USER(           strplt  r2, [r0], #4)
  41 2:              tst     r1, #2                  @ 1x 1x 0x 0x 1x 1x 0x
  42 USER(           strnebt r2, [r0], #1)
  43 USER(           strnebt r2, [r0], #1)
  44                 tst     r1, #1                  @ x1 x0 x1 x0 x1 x0 x1
  45 USER(           strnebt r2, [r0])
  46                 mov     r0, #0
  47                 ldmfd   sp!, {r1, pc}
  48 ENDPROC(__clear_user)
  49
  50                 .section .fixup,"ax"
  51                 .align  0
  52 9001:           ldmfd   sp!, {r0, pc}
  53                 .previous
  54