m4/link-follow.m4

   1 #serial 1
   2 dnl Run a program to determine whether whether link(2) follows symlinks.
   3 dnl Set LINK_FOLLOWS_SYMLINKS accordingly.
   4
   5 AC_DEFUN(jm_AC_FUNC_LINK_FOLLOWS_SYMLINK,
   6 [dnl
   7   AC_CACHE_CHECK([whether link(2) follows symlinks],
   8                  jm_ac_cv_func_link_follows_symlink,
   9   [
  10     dnl poor-man's AC_REQUIRE: FIXME: repair this once autoconf-3 provides
  11     dnl the appropriate framework.
  12     test -z "$ac_cv_header_unistd_h" \
  13       && AC_CHECK_HEADERS(unistd.h)
  14
  15     # Create a regular file.
  16     echo > conftest.file
  17     AC_TRY_RUN(
  18       [
  19 #       include <sys/types.h>
  20 #       include <sys/stat.h>
  21 #       ifdef HAVE_UNISTD_H
  22 #        include <unistd.h>
  23 #       endif
  24
  25 #       define SAME_INODE(Stat_buf_1, Stat_buf_2) \
  26           ((Stat_buf_1).st_ino == (Stat_buf_2).st_ino \
  27            && (Stat_buf_1).st_dev == (Stat_buf_2).st_dev)
  28
  29         int
  30         main ()
  31         {
  32           const char *file = "conftest.file";
  33           const char *sym = "conftest.sym";
  34           const char *hard = "conftest.hard";
  35           struct stat sb_file, sb_hard;
  36
  37           /* Create a symlink to the regular file. */
  38           if (symlink (file, sym))
  39             abort ();
  40
  41           /* Create a hard link to that symlink.  */
  42           if (link (sym, hard))
  43             abort ();
  44
  45           if (lstat (hard, &sb_hard))
  46             abort ();
  47           if (lstat (file, &sb_file))
  48             abort ();
  49
  50           /* If the dev/inode of hard and file are the same, then
  51              the link call followed the symlink.  */
  52           return SAME_INODE (sb_hard, sb_file) ? 0 : 1;
  53         }
  54       ],
  55       jm_ac_cv_func_link_follows_symlink=yes,
  56       jm_ac_cv_func_link_follows_symlink=no,
  57       jm_ac_cv_func_link_follows_symlink=yes dnl We're cross compiling.
  58     )
  59   ])
  60   if test $jm_ac_cv_func_link_follows_symlink = yes; then
  61     AC_DEFINE(LINK_FOLLOWS_SYMLINKS, 1,
  62       [Define if `link(2)' dereferences symbolic links.])
  63   fi
  64 ])