configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991, 1993-2011 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.62])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.1 dist-xz color-tests parallel-tests])
  36 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  37
  38 AC_PROG_CC_STDC
  39 AM_PROG_CC_C_O
  40 AC_PROG_CPP
  41 AC_PROG_GCC_TRADITIONAL
  42 AC_PROG_RANLIB
  43 AC_PROG_LN_S
  44 gl_EARLY
  45 gl_INIT
  46 coreutils_MACROS
  47
  48 AC_ARG_ENABLE([gcc-warnings],
  49   [AS_HELP_STRING([--enable-gcc-warnings],
  50                   [turn on lots of GCC warnings (for developers)])],
  51   [case $enableval in
  52      yes|no) ;;
  53      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  54    esac
  55    gl_gcc_warnings=$enableval],
  56   [gl_gcc_warnings=no]
  57 )
  58
  59 if test "$gl_gcc_warnings" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62
  63   nw=
  64   # This, $nw, is the list of warnings we disable.
  65   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  66   nw="$nw -Waggregate-return"       # anachronistic
  67   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  68   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  69   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  70   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  71   nw="$nw -Wcast-qual"              # Too many warnings for now
  72   nw="$nw -Wconversion"             # Too many warnings for now
  73   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  74   nw="$nw -Wsign-conversion"        # Too many warnings for now
  75   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  76   nw="$nw -Wunreachable-code"       # Too many warnings for now
  77   nw="$nw -Wpadded"                 # Our structs are not padded
  78   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  79   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  80   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  81   nw="$nw -Wvla"                    # warnings in gettext.h
  82   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  83   nw="$nw -Wswitch-enum"            # Too many warnings for now
  84   nw="$nw -Wswitch-default"         # Too many warnings for now
  85   nw="$nw -Wstack-protector"        # not worth working around
  86   # things I might fix soon:
  87   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  88   nw="$nw -Wmissing-format-attribute" # copy.c
  89   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  90   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  91   nw="$nw -Wstrict-overflow"        # expr.c, pr.c, tr.c, factor.c
  92   # ?? -Wstrict-overflow
  93
  94   gl_MANYWARN_ALL_GCC([ws])
  95   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  96   for w in $ws; do
  97     gl_WARN_ADD([$w])
  98   done
  99   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 100   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 101   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 102
 103   # In spite of excluding -Wlogical-op above, it is enabled, as of
 104   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 105   gl_WARN_ADD([-Wno-logical-op])
 106
 107   gl_WARN_ADD([-fdiagnostics-show-option])
 108   gl_WARN_ADD([-funit-at-a-time])
 109
 110   AC_SUBST([WARN_CFLAGS])
 111
 112   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 113   AC_DEFINE([_FORTIFY_SOURCE], [2],
 114     [enable compile-time and run-time bounds-checking, and some warnings])
 115   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 116
 117   # We use a slightly smaller set of warning options for lib/.
 118   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 119   nw=
 120   nw="$nw -Wuninitialized"
 121   nw="$nw -Wunused-macros"
 122   nw="$nw -Wmissing-prototypes"
 123   nw="$nw -Wold-style-definition"
 124   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 125   AC_SUBST([GNULIB_WARN_CFLAGS])
 126
 127   # For gnulib-tests, the set is slightly smaller still.
 128   nw=
 129   nw="$nw -Wstrict-prototypes"
 130   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 131                          [$GNULIB_WARN_CFLAGS], [$nw])
 132   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 133 fi
 134
 135 AC_FUNC_FORK
 136
 137 optional_bin_progs=
 138 AC_CHECK_FUNCS([chroot],
 139         gl_ADD_PROG([optional_bin_progs], [chroot]))
 140 AC_CHECK_FUNCS([gethostid],
 141         gl_ADD_PROG([optional_bin_progs], [hostid]))
 142
 143 gl_WINSIZE_IN_PTEM
 144
 145 AC_MSG_CHECKING([whether localtime caches TZ])
 146 AC_CACHE_VAL([utils_cv_localtime_cache],
 147 [if test x$ac_cv_func_tzset = xyes; then
 148 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 149 #if STDC_HEADERS
 150 # include <stdlib.h>
 151 #endif
 152 extern char **environ;
 153 void unset_TZ (void)
 154 {
 155   char **from, **to;
 156   for (to = from = environ; (*to = *from); from++)
 157     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 158       to++;
 159 }
 160 int main()
 161 {
 162   time_t now = time ((time_t *) 0);
 163   int hour_GMT0, hour_unset;
 164   if (putenv ("TZ=GMT0") != 0)
 165     return 1;
 166   hour_GMT0 = localtime (&now)->tm_hour;
 167   unset_TZ ();
 168   hour_unset = localtime (&now)->tm_hour;
 169   if (putenv ("TZ=PST8") != 0)
 170     return 1;
 171   if (localtime (&now)->tm_hour == hour_GMT0)
 172     return 1;
 173   unset_TZ ();
 174   if (localtime (&now)->tm_hour != hour_unset)
 175     return 1;
 176   return 0;
 177 }]])],
 178 [utils_cv_localtime_cache=no],
 179 [utils_cv_localtime_cache=yes],
 180 [# If we have tzset, assume the worst when cross-compiling.
 181 utils_cv_localtime_cache=yes])
 182 else
 183         # If we lack tzset, report that localtime does not cache TZ,
 184         # since we can't invalidate the cache if we don't have tzset.
 185         utils_cv_localtime_cache=no
 186 fi])dnl
 187 AC_MSG_RESULT([$utils_cv_localtime_cache])
 188 if test $utils_cv_localtime_cache = yes; then
 189   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 190 fi
 191
 192 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 193 AC_CHECK_FUNCS([initgroups])
 194 if test $ac_cv_func_initgroups = no; then
 195   AC_CHECK_LIB([os], [initgroups])
 196 fi
 197
 198 AC_CHECK_FUNCS([syslog])
 199 if test $ac_cv_func_syslog = no; then
 200   # syslog is not in the default libraries.  See if it's in some other.
 201   for lib in bsd socket inet; do
 202     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 203       LIBS="$LIBS -l$lib"; break])
 204   done
 205 fi
 206
 207 AC_CACHE_CHECK([for 3-argument setpriority function],
 208   [utils_cv_func_setpriority],
 209   [AC_LINK_IFELSE(
 210     [AC_LANG_PROGRAM(
 211        [[#include <sys/time.h>
 212          #include <sys/resource.h>
 213        ]],
 214        [[setpriority (0, 0, 0);]])],
 215     [utils_cv_func_setpriority=yes],
 216     [utils_cv_func_setpriority=no])])
 217 if test $utils_cv_func_setpriority = no; then
 218   AC_CHECK_FUNCS([nice])
 219 fi
 220 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 221 *yes*)
 222   gl_ADD_PROG([optional_bin_progs], [nice])
 223 esac
 224
 225 AC_DEFUN([coreutils_DUMMY_1],
 226 [
 227   AC_REQUIRE([gl_READUTMP])
 228   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 229     gl_ADD_PROG([optional_bin_progs], [who])
 230     gl_ADD_PROG([optional_bin_progs], [users])
 231     gl_ADD_PROG([optional_bin_progs], [pinky])
 232   fi
 233 ])
 234 coreutils_DUMMY_1
 235
 236 AC_MSG_CHECKING([ut_host in struct utmp])
 237 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 238 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 239 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 240   [su_cv_func_ut_host_in_utmp=yes],
 241   [su_cv_func_ut_host_in_utmp=no])])
 242 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 243 if test $su_cv_func_ut_host_in_utmp = yes; then
 244   have_ut_host=1
 245   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 246 fi
 247
 248 if test -z "$have_ut_host"; then
 249   AC_MSG_CHECKING([ut_host in struct utmpx])
 250   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 251   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 252 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 253     [su_cv_func_ut_host_in_utmpx=yes],
 254     [su_cv_func_ut_host_in_utmpx=no])])
 255   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 256   if test $su_cv_func_ut_host_in_utmpx = yes; then
 257     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 258     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 259   fi
 260 fi
 261
 262 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 263
 264 AC_SYS_POSIX_TERMIOS()
 265 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 266
 267 if test $ac_cv_sys_posix_termios = yes; then
 268   gl_ADD_PROG([optional_bin_progs], [stty])
 269
 270   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 271   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 272   [AC_EGREP_CPP([yes], [#include <termios.h>
 273 #ifdef IUCLC
 274 yes
 275 #endif], su_cv_sys_termios_needs_xopen_source=no,
 276    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 277 #include <termios.h>
 278 #ifdef IUCLC
 279 yes
 280 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 281    su_cv_sys_termios_needs_xopen_source=no))])
 282   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 283   test $su_cv_sys_termios_needs_xopen_source = yes &&
 284     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 285
 286   AC_MSG_CHECKING([c_line in struct termios])
 287   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 288   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 289 #define _XOPEN_SOURCE
 290 #endif
 291 #include <sys/types.h>
 292 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 293     [su_cv_sys_c_line_in_termios=yes],
 294     [su_cv_sys_c_line_in_termios=no])])
 295   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 296   test $su_cv_sys_c_line_in_termios = yes \
 297     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 298 fi
 299
 300 # FIXME: note that this macro appears above, too.
 301 # I'm leaving it here for now.  This whole thing needs to be modernized...
 302 gl_WINSIZE_IN_PTEM
 303
 304 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 305
 306 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 307    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 308   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 309   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 310   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 311 #ifdef WINSIZE_IN_PTEM
 312 # include <sys/stream.h>
 313 # include <sys/ptem.h>
 314 #endif
 315 #include <sys/ioctl.h>
 316 #include <sys/tty.h>
 317 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 318     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 319     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 320   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 321
 322   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 323       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 324                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 325 fi
 326
 327 # For src/kill.c.
 328 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 329   [AC_INCLUDES_DEFAULT
 330 #include <signal.h>])
 331
 332 cu_LIB_CHECK
 333 cu_GMP
 334
 335 # Build df only if there's a point to it.
 336 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 337   gl_ADD_PROG([optional_bin_progs], [df])
 338 fi
 339
 340 # Limit stdbuf to ELF systems with GCC
 341 AC_MSG_CHECKING([whether this is an ELF system])
 342 AC_EGREP_CPP([yes], [#if __ELF__
 343 yes
 344 #endif], [elf_sys=yes], [elf_sys=no])
 345 AC_MSG_RESULT([$elf_sys])
 346 if test "$elf_sys" = "yes" && \
 347    test "$GCC" = "yes"; then
 348   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 349 fi
 350
 351 ############################################################################
 352 mk="$srcdir/src/Makefile.am"
 353 # Extract all literal names from the definition of $(EXTRA_PROGRAMS)
 354 # in $mk but don't expand the variable references.
 355 # Append each literal name to $optional_bin_progs.
 356 v=EXTRA_PROGRAMS
 357 for gl_i in `sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 358     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 359     | tr -s '\\015\\012\\\\' '   '`; do
 360   gl_ADD_PROG([optional_bin_progs], $gl_i)
 361 done
 362
 363 # As above, extract literal names from the definition of $(no_install__progs)
 364 # in $mk but don't expand the variable references.
 365 v=no_install__progs
 366 t=`sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 367     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 368     | tr -s '\\015\\012\\\\' '   '`
 369 # Remove any trailing space.
 370 no_install_progs_default=`echo "$t"|sed 's/ $//'`
 371
 372 # Unfortunately, due to the way autoconf's AS_HELP_STRING works, the list
 373 # of default-not-installed programs, "arch hostname su", must appear in two
 374 # places: in this file below, and in $mk.  Using "$no_install_progs_default"
 375 # below cannot work.  And we can't substitute the names into $mk because
 376 # automake needs the literals, too.
 377 # The compromise is to ensure that the space-separated list extracted
 378 # above matches the literal 2nd argument below.
 379 c="$srcdir/configure.ac"
 380 re='^g''l_INCLUDE_EXCLUDE_PROG(.* [\[\(.*\)\]])'
 381 t=`sed -n '/'"$re"'/{s/'"$re"'/\1/;s/,/ /gp
 382 }' $c`
 383 case $t in
 384   $no_install_progs_default) ;;
 385   *) AC_MSG_ERROR([[internal error: g'l_INCLUDE_EXCLUDE_PROG's 2nd arg, $t,
 386                    does not match the list of default-not-installed programs
 387                    ($no_install_progs_default) also recorded in $mk]],
 388                    1) ;;
 389 esac
 390
 391 # Given the name of a variable containing a space-separated list of
 392 # install-by-default programs and the actual list do-not-install-by-default
 393 # programs, modify the former variable to reflect any "do-install" and
 394 # "don't-install" requests.
 395 # I.e., add any program name specified via --enable-install-program=..., and
 396 # remove any program name specified via --enable-no-install-program=...
 397 # Note how the second argument below is a literal, with "," separators.
 398 # That is required due to the way the macro works, and since the
 399 # corresponding ./configure option argument is comma-separated on input.
 400 gl_INCLUDE_EXCLUDE_PROG([optional_bin_progs], [arch,hostname,su])
 401
 402 # Now that we know which programs will actually be built up, figure out
 403 # which optional helper progs should be compiled.
 404 optional_pkglib_progs=
 405 case " $optional_bin_progs " in
 406   *' stdbuf '*) gl_ADD_PROG([optional_pkglib_progs], [libstdbuf.so]) ;;
 407 esac
 408
 409 # Set INSTALL_SU if su installation has been requested via
 410 # --enable-install-program=su.
 411 AC_SUBST([INSTALL_SU])
 412 case " $optional_bin_progs " in
 413   *' su '*) INSTALL_SU=yes ;;
 414   *)        INSTALL_SU=no ;;
 415 esac
 416
 417 MAN=`echo "$optional_bin_progs "|sed 's/ /.1 /g;s/ $//'|tr -d '\\015\\012'`
 418
 419 # Change ginstall.1 to "install.h" in $MAN.
 420 MAN=`for m in $MAN; do test $m = ginstall.1 && m=install.1; echo $m; done \
 421   | tr '\015\012' '  '; echo`
 422
 423 # Remove [.1, since writing a portable rule for it in man/Makefile.am
 424 # is not practical.  The sed LHS below uses the autoconf quadrigraph
 425 # representing '['.
 426 MAN=`echo "$MAN"|sed 's/\@<:@\.1//'`
 427
 428 OPTIONAL_BIN_PROGS=`echo "$optional_bin_progs "|sed 's/ /\$(EXEEXT) /g;s/ $//'`
 429 AC_SUBST([OPTIONAL_BIN_PROGS])
 430 OPTIONAL_PKGLIB_PROGS=`echo "$optional_pkglib_progs " | sed 's/ $//'`
 431 AC_SUBST([OPTIONAL_PKGLIB_PROGS])
 432 NO_INSTALL_PROGS_DEFAULT=$no_install_progs_default
 433 AC_SUBST([NO_INSTALL_PROGS_DEFAULT])
 434
 435 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 436
 437 # Arrange to rerun configure whenever the file, src/Makefile.am,
 438 # containing the list of program names changes.
 439 CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/src/Makefile.am'
 440 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
 441 ############################################################################
 442
 443 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 444 # translatable strings, we must use need-formatstring-macros here.
 445 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 446 AM_GNU_GETTEXT_VERSION([0.17])
 447
 448 # For a test of uniq: it uses the $LOCALE_FR envvar.
 449 gt_LOCALE_FR
 450
 451 AC_CONFIG_FILES(
 452   Makefile
 453   doc/Makefile
 454   lib/Makefile
 455   man/Makefile
 456   po/Makefile.in
 457   src/Makefile
 458   tests/Makefile
 459   gnulib-tests/Makefile
 460   )
 461 AC_OUTPUT