m4/jm-macros.m4

   1 #serial 109   -*- autoconf -*-
   2
   3 dnl Misc type-related macros for coreutils.
   4
   5 # Copyright (C) 1998, 2000-2009 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # Written by Jim Meyering.
  21
  22 AC_DEFUN([coreutils_MACROS],
  23 [
  24   AM_MISSING_PROG(HELP2MAN, help2man)
  25   AC_SUBST([MAN])
  26
  27   dnl This macro actually runs replacement code.  See isc-posix.m4.
  28   AC_REQUIRE([AC_ISC_POSIX])dnl
  29
  30   gl_CHECK_ALL_TYPES
  31
  32   AC_REQUIRE([gl_CHECK_DECLS])
  33
  34   AC_REQUIRE([gl_PREREQ])
  35
  36   AC_REQUIRE([AC_FUNC_FSEEKO])
  37
  38   # By default, argmatch should fail calling usage (1).
  39   AC_DEFINE([ARGMATCH_DIE], [usage (1)],
  40             [Define to the function xargmatch calls on failures.])
  41   AC_DEFINE([ARGMATCH_DIE_DECL], [void usage (int _e)],
  42             [Define to the declaration of the xargmatch failure function.])
  43
  44   # used by ls
  45   AC_REQUIRE([gl_CLOCK_TIME])
  46   # used by shred
  47   AC_CHECK_FUNCS_ONCE([directio])
  48
  49   # Used by install.c.
  50   AC_CHECK_FUNCS_ONCE([matchpathcon_init_prefix])
  51
  52   # Used by sort.c.
  53   AC_CHECK_FUNCS_ONCE([nl_langinfo])
  54
  55   AC_CHECK_FUNCS_ONCE( \
  56     endgrent \
  57     endpwent \
  58     fchown \
  59     fchmod \
  60     ftruncate \
  61     iswspace \
  62     mkfifo \
  63     mbrlen \
  64     setgroups \
  65     sethostname \
  66     siginterrupt \
  67     sync \
  68     sysctl \
  69     sysinfo \
  70     tcgetpgrp \
  71   )
  72
  73   dnl This can't use AC_REQUIRE; I'm not quite sure why.
  74   cu_PREREQ_STAT_PROG
  75
  76   # for dd.c and shred.c
  77   coreutils_saved_libs=$LIBS
  78     AC_SEARCH_LIBS([fdatasync], [rt posix4],
  79                    [test "$ac_cv_search_fdatasync" = "none required" ||
  80                     LIB_FDATASYNC=$ac_cv_search_fdatasync])
  81     AC_SUBST([LIB_FDATASYNC])
  82     AC_CHECK_FUNCS([fdatasync])
  83   LIBS=$coreutils_saved_libs
  84
  85   # Check whether libcap is usable -- for ls --color support
  86   AC_ARG_ENABLE([libcap],
  87     AC_HELP_STRING([--disable-libcap], [disable libcap support]),
  88     AC_MSG_WARN([libcap support disabled by user]),
  89     [AC_CHECK_LIB([cap], [cap_get_file],
  90       [AC_CHECK_HEADER([sys/capability.h],
  91         [LIB_CAP=-lcap
  92          AC_DEFINE([HAVE_CAP], [1], [libcap usability])],
  93         [AC_MSG_WARN([header sys/capability.h was not found, support for libcap will not be built])]
  94       )],
  95       [AC_MSG_WARN([libcap library was not found or not usable, support for libcap will not be built])])
  96     ])
  97   AC_SUBST([LIB_CAP])
  98
  99   # See if linking `seq' requires -lm.
 100   # It does on nearly every system.  The single exception (so far) is
 101   # BeOS which has all the math functions in the normal runtime library
 102   # and doesn't have a separate math library.
 103
 104   AC_SUBST([SEQ_LIBM])
 105   ac_seq_body='
 106      static double x, y;
 107      x = floor (x);
 108      x = rint (x);
 109      x = modf (x, &y);'
 110   AC_TRY_LINK([#include <math.h>], [$ac_seq_body], ,
 111     [ac_seq_save_LIBS="$LIBS"
 112      LIBS="$LIBS -lm"
 113      AC_TRY_LINK([#include <math.h>], [$ac_seq_body], [SEQ_LIBM=-lm])
 114      LIBS="$ac_seq_save_LIBS"
 115     ])
 116
 117   AC_REQUIRE([AM_LANGINFO_CODESET])
 118 ])
 119
 120 AC_DEFUN([gl_CHECK_ALL_HEADERS],
 121 [
 122   AC_CHECK_HEADERS_ONCE( \
 123     hurd.h \
 124     paths.h \
 125     priv.h \
 126     stropts.h \
 127     sys/ioctl.h \
 128     sys/param.h \
 129     sys/resource.h \
 130     sys/systeminfo.h \
 131     sys/time.h \
 132     sys/wait.h \
 133     syslog.h \
 134     termios.h \
 135   )
 136   AC_CHECK_HEADERS([sys/sysctl.h], [], [],
 137     [AC_INCLUDES_DEFAULT
 138      [#if HAVE_SYS_PARAM_H
 139        #include <sys/param.h>
 140       #endif]])
 141 ])
 142
 143 # This macro must be invoked before any tests that run the compiler.
 144 AC_DEFUN([gl_CHECK_ALL_TYPES],
 145 [
 146   dnl This test must come as early as possible after the compiler configuration
 147   dnl tests, because the choice of the file model can (in principle) affect
 148   dnl whether functions and headers are available, whether they work, etc.
 149   AC_REQUIRE([AC_SYS_LARGEFILE])
 150
 151   dnl This test must precede tests of compiler characteristics like
 152   dnl that for the inline keyword, since it may change the degree to
 153   dnl which the compiler supports such features.
 154   AC_REQUIRE([AM_C_PROTOTYPES])
 155
 156   dnl Checks for typedefs, structures, and compiler characteristics.
 157   AC_REQUIRE([gl_BIGENDIAN])
 158   AC_REQUIRE([AC_C_VOLATILE])
 159   AC_REQUIRE([AC_C_INLINE])
 160   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
 161
 162   AC_REQUIRE([gl_CHECK_ALL_HEADERS])
 163   AC_CHECK_MEMBERS(
 164     [struct stat.st_author],,,
 165     [$ac_includes_default
 166 #include <sys/stat.h>
 167   ])
 168   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
 169
 170   AC_REQUIRE([AC_TYPE_GETGROUPS])
 171   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 172   AC_REQUIRE([AC_TYPE_MODE_T])
 173   AC_REQUIRE([AC_TYPE_OFF_T])
 174   AC_REQUIRE([AC_TYPE_PID_T])
 175   AC_REQUIRE([AC_TYPE_SIZE_T])
 176   AC_REQUIRE([AC_TYPE_UID_T])
 177   AC_CHECK_TYPE([ino_t], [unsigned long int])
 178
 179   dnl This relies on the fact that Autoconf's implementation of
 180   dnl AC_CHECK_TYPE checks includes unistd.h.
 181   AC_CHECK_TYPE([major_t], [unsigned int])
 182   AC_CHECK_TYPE([minor_t], [unsigned int])
 183
 184   AC_REQUIRE([AC_HEADER_MAJOR])
 185 ])