m4/boottime.m4

   1 # boottime.m4 serial 2
   2 # Determine whether this system has infrastructure for obtaining the boot time.
   3
   4 # Copyright (C) 1996, 2000, 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software Foundation,
  18 # Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 # GNULIB_BOOT_TIME([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  21 * ----------------------------------------------------------
  22 AC_DEFUN([GNULIB_BOOT_TIME],
  23 [
  24   AC_CHECK_FUNCS(sysctl)
  25   AC_CHECK_HEADERS_ONCE(sys/param.h)
  26   AC_CHECK_HEADERS(sys/sysctl.h, [], [],
  27     [AC_INCLUDES_DEFAULT
  28      [#if HAVE_SYS_PARAM_H
  29        #include <sys/param.h>
  30       #endif]])
  31   AC_CACHE_CHECK(
  32     [whether we can get the system boot time],
  33     [gnulib_cv_have_boot_time],
  34     [
  35       AC_COMPILE_IFELSE(
  36        [AC_LANG_PROGRAM(
  37 [AC_INCLUDES_DEFAULT
  38 #if HAVE_SYSCTL && HAVE_SYS_SYSCTL_H
  39 # if HAVE_SYS_PARAM_H
  40 #  include <sys/param.h> /* needed for OpenBSD 3.0 */
  41 # endif
  42 # include <sys/sysctl.h>
  43 #endif
  44 #ifdef HAVE_UTMPX_H
  45 # include <utmpx.h>
  46 #else
  47 # include <utmp.h>
  48 #endif
  49 ],
  50 [[
  51 #if defined BOOT_TIME || (defined CTL_KERN && defined KERN_BOOTTIME)
  52 /* your system *does* have the infrastructure to determine boot time */
  53 #else
  54 please_tell_us_how_to_determine_boot_time_on_your_system
  55 #endif
  56 ]])],
  57        gnulib_cv_have_boot_time=yes,
  58        gnulib_cv_have_boot_time=no)
  59     ])
  60   AS_IF([test $gnulib_cv_have_boot_time = yes], [$1], [$2])
  61 ])