m4/utimbuf.m4

   1 #serial 6
   2
   3 dnl From Jim Meyering
   4
   5 dnl Define HAVE_STRUCT_UTIMBUF if `struct utimbuf' is declared --
   6 dnl usually in <utime.h>.
   7 dnl Some systems have utime.h but don't declare the struct anywhere.
   8
   9 AC_DEFUN([gl_CHECK_TYPE_STRUCT_UTIMBUF],
  10 [
  11   AC_CHECK_HEADERS_ONCE(sys/time.h utime.h)
  12   AC_REQUIRE([AC_HEADER_TIME])
  13   AC_CACHE_CHECK([for struct utimbuf], fu_cv_sys_struct_utimbuf,
  14     [AC_TRY_COMPILE(
  15       [
  16 #ifdef TIME_WITH_SYS_TIME
  17 # include <sys/time.h>
  18 # include <time.h>
  19 #else
  20 # ifdef HAVE_SYS_TIME_H
  21 #  include <sys/time.h>
  22 # else
  23 #  include <time.h>
  24 # endif
  25 #endif
  26 #ifdef HAVE_UTIME_H
  27 # include <utime.h>
  28 #endif
  29       ],
  30       [static struct utimbuf x; x.actime = x.modtime;],
  31       fu_cv_sys_struct_utimbuf=yes,
  32       fu_cv_sys_struct_utimbuf=no)
  33     ])
  34
  35   if test $fu_cv_sys_struct_utimbuf = yes; then
  36     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1,
  37       [Define if struct utimbuf is declared -- usually in <utime.h>.
  38        Some systems have utime.h but don't declare the struct anywhere. ])
  39   fi
  40 ])