m4/regex.m4

   1 #serial 5
   2
   3 dnl Initially derived from code in GNU grep.
   4 dnl Mostly written by Jim Meyering.
   5
   6 dnl Usage: jm_INCLUDED_REGEX([lib/regex.c])
   7 dnl
   8 AC_DEFUN(jm_INCLUDED_REGEX,
   9   [
  10     dnl Even packages that don't use regex.c can use this macro.
  11     dnl Of course, for them it doesn't do anything.
  12
  13     # Assume we'll default to using the included regex.c.
  14     ac_use_included_regex=yes
  15
  16     # However, if the system regex support is good enough that it passes the
  17     # the following run test, then default to *not* using the included regex.c.
  18     # If cross compiling, assume the test would fail and use the included
  19     # regex.c.  The failing regular expression is from `Spencer ere test #75'
  20     # in grep-2.3.
  21     AC_CACHE_CHECK([for working re_compile_pattern],
  22                    jm_cv_func_working_re_compile_pattern,
  23       AC_TRY_RUN(
  24         changequote(<<, >>)dnl
  25         <<
  26 #include <stdio.h>
  27 #include <regex.h>
  28           int
  29           main ()
  30           {
  31             static struct re_pattern_buffer regex;
  32             const char *s;
  33             re_set_syntax (RE_SYNTAX_POSIX_EGREP);
  34             /* Add this third left square bracket, [, to balance the
  35                three right ones below.  Otherwise autoconf-2.14 chokes.  */
  36             s = re_compile_pattern ("a[[:]:]]b\n", 9, &regex);
  37             /* This should fail with _Invalid character class name_ error.  */
  38             exit (s ? 0 : 1);
  39           }
  40         >>,
  41         changequote([, ])dnl
  42
  43                jm_cv_func_working_re_compile_pattern=yes,
  44                jm_cv_func_working_re_compile_pattern=no,
  45                dnl When crosscompiling, assume it's broken.
  46                jm_cv_func_working_re_compile_pattern=no))
  47     if test $jm_cv_func_working_re_compile_pattern = yes; then
  48       ac_use_included_regex=no
  49     fi
  50
  51     test -n "$1" || AC_MSG_ERROR([missing argument])
  52     syscmd([test -f $1])
  53     ifelse(sysval, 0,
  54       [
  55
  56         AC_ARG_WITH(included-regex,
  57         [  --without-included-regex don't compile regex; this is the default on
  58                           systems with version 2 of the GNU C library
  59                           (use with caution on other system)],
  60                     jm_with_regex=$withval,
  61                     jm_with_regex=$ac_use_included_regex)
  62         if test "$jm_with_regex" = yes; then
  63           AC_SUBST(LIBOBJS)
  64           LIBOBJS="$LIBOBJS regex.$ac_objext"
  65         fi
  66       ],
  67     )
  68   ]
  69 )