configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2015 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.69])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.2 no-dist-gzip dist-xz color-tests parallel-tests
  36                   subdir-objects])
  37 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  38
  39 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  40 dnl (more than 10% execution time) to ./configure, with no benefit for
  41 dnl most users.  Using it to look for bugs requires:
  42 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  43 dnl   ./configure
  44 dnl   make
  45 dnl   make -C src clean
  46 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  47 dnl FIXME: Once we figure out how to avoid false positives, we should
  48 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  49 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  50 m4_if(m4_sysval, [0], [], [dnl
  51 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  52
  53 AC_PROG_CC_STDC
  54 AM_PROG_CC_C_O
  55 AC_PROG_CPP
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_PROG_RANLIB
  58 AC_PROG_LN_S
  59 gl_EARLY
  60 gl_INIT
  61 coreutils_MACROS
  62
  63 # The test suite needs to know if we have a working perl.
  64 # FIXME: this is suboptimal.  Ideally, we would be able to call gl_PERL
  65 # with an ACTION-IF-NOT-FOUND argument ...
  66 cu_have_perl=yes
  67 case $PERL in *"/missing "*) cu_have_perl=no;; esac
  68 AM_CONDITIONAL([HAVE_PERL], [test $cu_have_perl = yes])
  69
  70 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  71 # ------------------------------------------------
  72 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  73 # Otherwise, run RUN-IF-NOT-FOUND.
  74 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  75   [AC_PREPROC_IFELSE(
  76     [AC_LANG_PROGRAM(
  77       [[
  78 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  79 /* ok */
  80 #else
  81 # error "your version of gcc is older than $1.$2"
  82 #endif
  83       ]]),
  84     ], [$3], [$4])
  85   ]
  86 )
  87
  88 AC_ARG_ENABLE([gcc-warnings],
  89   [AS_HELP_STRING([--enable-gcc-warnings],
  90      [turn on many GCC warnings (for developers; best with GNU make)])],
  91   [case $enableval in
  92      yes|no) ;;
  93      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  94    esac
  95    gl_gcc_warnings=$enableval],
  96   [
  97    # GCC provides fine-grained control over diagnostics which
  98    # is used in gnulib for example to suppress warnings from
  99    # certain sections of code.  So if this is available and
 100    # we're running from a git repo, then auto enable the warnings.
 101    gl_gcc_warnings=no
 102    gl_GCC_VERSION_IFELSE([4], [6],
 103                          [test -d "$srcdir"/.git \
 104                           && ! test -f "$srcdir"/.tarball-version \
 105                           && gl_gcc_warnings=yes])]
 106 )
 107
 108 if test "$gl_gcc_warnings" = yes; then
 109   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 110   AC_SUBST([WERROR_CFLAGS])
 111
 112   nw=
 113   # This, $nw, is the list of warnings we disable.
 114   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 115   nw="$nw -Waggregate-return"       # anachronistic
 116   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 117   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 118   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 119   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 120   nw="$nw -Wcast-qual"              # Too many warnings for now
 121   nw="$nw -Wconversion"             # Too many warnings for now
 122   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 123   nw="$nw -Wsign-conversion"        # Too many warnings for now
 124   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 125   nw="$nw -Wunreachable-code"       # Too many warnings for now
 126   nw="$nw -Wpadded"                 # Our structs are not padded
 127   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 128   nw="$nw -Wlogical-op"             # Too many warnings until GCC 4.8.0
 129   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 130   nw="$nw -Wvla"                    # warnings in gettext.h
 131   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 132   nw="$nw -Wswitch-enum"            # Too many warnings for now
 133   nw="$nw -Wswitch-default"         # Too many warnings for now
 134   nw="$nw -Wstack-protector"        # not worth working around
 135   # things I might fix soon:
 136   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 137   nw="$nw -Wmissing-format-attribute" # copy.c
 138   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 139   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 140   nw="$nw -Wsuggest-attribute=format" # warns about copy.c and factor.c
 141
 142   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 143   # For an example, see the code that provoked this report:
 144   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 145   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 146
 147   gl_MANYWARN_ALL_GCC([ws])
 148   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 149   for w in $ws; do
 150     gl_WARN_ADD([$w])
 151   done
 152   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 153   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 154   gl_WARN_ADD([-Wno-format-nonliteral])
 155
 156   # Enable this warning only with gcc-4.8 and newer.  Before that
 157   # bounds checking as done in truncate.c was incorrectly flagged.
 158   # See: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=43772
 159   gl_GCC_VERSION_IFELSE([4], [8], [gl_WARN_ADD([-Wlogical-op])])
 160
 161   # clang is unduly picky about some things.
 162   AC_CACHE_CHECK([whether the compiler is clang], [utils_cv_clang],
 163     [AC_COMPILE_IFELSE(
 164        [AC_LANG_PROGRAM([[
 165             #ifndef __clang__
 166               #error "not clang"
 167             #endif
 168           ]])],
 169        [utils_cv_clang=yes],
 170        [utils_cv_clang=no])])
 171   if test $utils_cv_clang = yes; then
 172     gl_WARN_ADD([-Wno-format-extra-args])
 173     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 174   fi
 175
 176   gl_WARN_ADD([-fdiagnostics-show-option])
 177   gl_WARN_ADD([-funit-at-a-time])
 178
 179   AC_SUBST([WARN_CFLAGS])
 180
 181   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 182   AH_VERBATIM([FORTIFY_SOURCE],
 183   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 184       without upsetting glibc 2.15+. */
 185    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 186    # define _FORTIFY_SOURCE 2
 187    #endif
 188   ])
 189   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 190
 191   # We use a slightly smaller set of warning options for lib/.
 192   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 193   nw=
 194   nw="$nw -Wstrict-overflow"
 195   nw="$nw -Wuninitialized"
 196   nw="$nw -Wunused-macros"
 197   nw="$nw -Wmissing-prototypes"
 198   nw="$nw -Wold-style-definition"
 199   # FIXME: it may be easy to remove this, since it affects only one file:
 200   # the snprintf call at ftoastr.c:132.
 201   nw="$nw -Wdouble-promotion"
 202   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 203   AC_SUBST([GNULIB_WARN_CFLAGS])
 204
 205   # For gnulib-tests, the set is slightly smaller still.
 206   nw=
 207   nw="$nw -Wstrict-prototypes"
 208   # It's not worth being this picky about test programs.
 209   nw="$nw -Wsuggest-attribute=const"
 210   nw="$nw -Wsuggest-attribute=pure"
 211   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 212                          [$GNULIB_WARN_CFLAGS], [$nw])
 213   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 214 fi
 215
 216 AC_ARG_ENABLE([single-binary],
 217   [AS_HELP_STRING([--enable-single-binary=[shebangs|symlinks]],
 218      [Compile all the tools in a single binary, reducing the overall size.
 219       When compiled this way, shebangs (default when enabled) or symlinks are
 220       installed for each tool that points to the single binary.])],
 221   [gl_single_binary=no ;
 222    case $enableval in
 223      yes) gl_single_binary=shebangs ;;
 224      no|shebangs|symlinks) gl_single_binary=$enableval ;;
 225      *)      AC_MSG_ERROR([bad value $enableval for single-binary option.
 226                            Options are: symlinks, shebangs, no.]) ;;
 227    esac],
 228   [gl_single_binary=no]
 229 )
 230 AC_ARG_ENABLE([single-binary-exceptions],
 231   [AS_HELP_STRING([--enable-single-binary-exceptions=PROG_LIST],
 232      [When used with --enable-single-binary, exclude the PROG_LIST from
 233       it, so these programs are compiled as separated files
 234       (comma-separated, default none))])],
 235   [gl_single_binary_exceptions=$enableval],
 236   [gl_single_binary_exceptions=]
 237 )
 238 if test "$gl_single_binary" = 'symlinks'; then
 239   if ! test "`echo ls | sed \"$program_transform_name\"`" = 'ls'; then
 240     AC_MSG_ERROR([program name transformations are not currently supported
 241                   with --enable-single-binary=symlinks.])
 242   fi
 243 fi
 244 AM_CONDITIONAL([SINGLE_BINARY], [test "$gl_single_binary" != no])
 245
 246 AC_FUNC_FORK
 247
 248 optional_bin_progs=
 249 AC_CHECK_FUNCS([chroot],
 250         gl_ADD_PROG([optional_bin_progs], [chroot]))
 251 AC_CHECK_FUNCS([gethostid],
 252         gl_ADD_PROG([optional_bin_progs], [hostid]))
 253
 254 gl_WINSIZE_IN_PTEM
 255
 256 AC_MSG_CHECKING([whether localtime caches TZ])
 257 AC_CACHE_VAL([utils_cv_localtime_cache],
 258 [if test x$ac_cv_func_tzset = xyes; then
 259 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 260 #if STDC_HEADERS
 261 # include <stdlib.h>
 262 #endif
 263 extern char **environ;
 264 void unset_TZ (void)
 265 {
 266   char **from, **to;
 267   for (to = from = environ; (*to = *from); from++)
 268     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 269       to++;
 270 }
 271 int main()
 272 {
 273   time_t now = time ((time_t *) 0);
 274   int hour_GMT0, hour_unset;
 275   if (putenv ("TZ=GMT0") != 0)
 276     return 1;
 277   hour_GMT0 = localtime (&now)->tm_hour;
 278   unset_TZ ();
 279   hour_unset = localtime (&now)->tm_hour;
 280   if (putenv ("TZ=PST8") != 0)
 281     return 1;
 282   if (localtime (&now)->tm_hour == hour_GMT0)
 283     return 1;
 284   unset_TZ ();
 285   if (localtime (&now)->tm_hour != hour_unset)
 286     return 1;
 287   return 0;
 288 }]])],
 289 [utils_cv_localtime_cache=no],
 290 [utils_cv_localtime_cache=yes],
 291 [# If we have tzset, assume the worst when cross-compiling.
 292 utils_cv_localtime_cache=yes])
 293 else
 294         # If we lack tzset, report that localtime does not cache TZ,
 295         # since we can't invalidate the cache if we don't have tzset.
 296         utils_cv_localtime_cache=no
 297 fi])dnl
 298 AC_MSG_RESULT([$utils_cv_localtime_cache])
 299 if test $utils_cv_localtime_cache = yes; then
 300   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 301 fi
 302
 303 # Assume that if getattrat exists, it's compatible with Solaris 11.
 304 AC_CHECK_FUNCS([getattrat])
 305 if test $ac_cv_func_getattrat = yes; then
 306   LIB_NVPAIR=-lnvpair
 307   AC_SUBST([LIB_NVPAIR])
 308 fi
 309
 310 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 311 AC_CHECK_FUNCS([initgroups])
 312 if test $ac_cv_func_initgroups = no; then
 313   AC_CHECK_LIB([os], [initgroups])
 314 fi
 315
 316 AC_CHECK_FUNCS([syslog])
 317 if test $ac_cv_func_syslog = no; then
 318   # syslog is not in the default libraries.  See if it's in some other.
 319   for lib in bsd socket inet; do
 320     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 321       LIBS="$LIBS -l$lib"; break])
 322   done
 323 fi
 324
 325 AC_CACHE_CHECK([for 3-argument setpriority function],
 326   [utils_cv_func_setpriority],
 327   [AC_LINK_IFELSE(
 328     [AC_LANG_PROGRAM(
 329        [[#include <sys/time.h>
 330          #include <sys/resource.h>
 331        ]],
 332        [[setpriority (0, 0, 0);]])],
 333     [utils_cv_func_setpriority=yes],
 334     [utils_cv_func_setpriority=no])])
 335 if test $utils_cv_func_setpriority = no; then
 336   AC_CHECK_FUNCS([nice])
 337 fi
 338 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 339 *yes*)
 340   gl_ADD_PROG([optional_bin_progs], [nice])
 341 esac
 342
 343 AC_DEFUN([coreutils_DUMMY_1],
 344 [
 345   AC_REQUIRE([gl_READUTMP])
 346   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 347     gl_ADD_PROG([optional_bin_progs], [who])
 348     gl_ADD_PROG([optional_bin_progs], [users])
 349     gl_ADD_PROG([optional_bin_progs], [pinky])
 350   fi
 351 ])
 352 coreutils_DUMMY_1
 353
 354 AC_MSG_CHECKING([ut_host in struct utmp])
 355 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 356 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 357 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 358   [su_cv_func_ut_host_in_utmp=yes],
 359   [su_cv_func_ut_host_in_utmp=no])])
 360 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 361 if test $su_cv_func_ut_host_in_utmp = yes; then
 362   have_ut_host=1
 363   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 364 fi
 365
 366 if test -z "$have_ut_host"; then
 367   AC_MSG_CHECKING([ut_host in struct utmpx])
 368   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 369   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 370 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 371     [su_cv_func_ut_host_in_utmpx=yes],
 372     [su_cv_func_ut_host_in_utmpx=no])])
 373   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 374   if test $su_cv_func_ut_host_in_utmpx = yes; then
 375     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 376     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 377   fi
 378 fi
 379
 380 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 381
 382 AC_SYS_POSIX_TERMIOS()
 383 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 384
 385 if test $ac_cv_sys_posix_termios = yes; then
 386   gl_ADD_PROG([optional_bin_progs], [stty])
 387
 388   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 389   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 390   [AC_EGREP_CPP([yes], [#include <termios.h>
 391 #ifdef IUCLC
 392 yes
 393 #endif], su_cv_sys_termios_needs_xopen_source=no,
 394    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 395 #include <termios.h>
 396 #ifdef IUCLC
 397 yes
 398 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 399    su_cv_sys_termios_needs_xopen_source=no))])
 400   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 401   test $su_cv_sys_termios_needs_xopen_source = yes &&
 402     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 403
 404   AC_MSG_CHECKING([c_line in struct termios])
 405   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 406   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 407 #define _XOPEN_SOURCE
 408 #endif
 409 #include <sys/types.h>
 410 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 411     [su_cv_sys_c_line_in_termios=yes],
 412     [su_cv_sys_c_line_in_termios=no])])
 413   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 414   test $su_cv_sys_c_line_in_termios = yes \
 415     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 416 fi
 417
 418 # FIXME: note that this macro appears above, too.
 419 # I'm leaving it here for now.  This whole thing needs to be modernized...
 420 gl_WINSIZE_IN_PTEM
 421
 422 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 423
 424 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 425    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 426   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 427   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 428   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 429 #ifdef WINSIZE_IN_PTEM
 430 # include <sys/stream.h>
 431 # include <sys/ptem.h>
 432 #endif
 433 #include <sys/ioctl.h>
 434 #include <sys/tty.h>
 435 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 436     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 437     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 438   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 439
 440   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 441       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 442                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 443 fi
 444
 445 # For src/kill.c.
 446 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 447   [AC_INCLUDES_DEFAULT
 448 #include <signal.h>])
 449
 450 cu_GMP
 451
 452 # Build df only if there's a point to it.
 453 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 454   gl_ADD_PROG([optional_bin_progs], [df])
 455 fi
 456
 457 # Build stdbuf only if supported
 458 ac_save_CFLAGS=$CFLAGS
 459 ac_save_LDFLAGS=$LDFLAGS
 460 # Detect warnings about ignored "constructor" attributes.
 461 gl_WARN_ADD([-Werror], [CFLAGS])
 462 gl_WARN_ADD([-errwarn], [CFLAGS])
 463 # Put this message here, after gl_WARN_ADD's chatter.
 464 AC_MSG_CHECKING([whether this system supports stdbuf])
 465 CFLAGS="-fPIC $CFLAGS"
 466 LDFLAGS="-shared $LDFLAGS"
 467 stdbuf_supported=no
 468 # Note we only LINK here rather than RUN to support cross compilation
 469 AC_LINK_IFELSE(
 470   [AC_LANG_PROGRAM([[
 471     static int stdbuf = 0;
 472
 473     void __attribute__ ((constructor))
 474     stdbuf_init (void)
 475     {
 476       stdbuf = 1;
 477     }]],[[
 478     return !(stdbuf == 1);]])
 479   ],
 480   [stdbuf_supported=yes])
 481 AC_MSG_RESULT([$stdbuf_supported])
 482 if test "$stdbuf_supported" = "yes" && test -z "$EXEEXT"; then
 483   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 484 fi
 485 CFLAGS=$ac_save_CFLAGS
 486 LDFLAGS=$ac_save_LDFLAGS
 487
 488 ############################################################################
 489
 490 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 491 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 492 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 493 dnl of coreutils programs to be built only upon explicit user request,
 494 dnl saving that list in the $no_install_progs_default shell variable.
 495 m4_include([m4/cu-progs.m4])
 496
 497 # Now that we know which programs will actually be built, determine
 498 # which optional helper progs should be compiled.
 499 # Note it adding to pkglibexec_PROGRAMS, $(transform) in src/local.mk
 500 # may need to be updated accordingly.
 501 case " $optional_bin_progs " in
 502   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 503   *) pkglibexec_PROGRAMS='';;
 504 esac
 505
 506 man1_MANS=`
 507   for p in $optional_bin_progs; do
 508     # Change "ginstall.1" to "install.1".
 509     test $p = ginstall && p=install
 510     # Ignore the "[" program, since writing a portable make rule to
 511     # generate its manpage is not practical.
 512     dnl Use the autoconf-provided quadrigraph to represent "[",
 513     dnl otherwise we will incur in dreadful quoting issues.
 514     test x$p = x'@<:@' && continue
 515     echo "man/$p.1"
 516   done`
 517
 518 # Not installed by "make install", but must be built when creating
 519 # a distribution tarball.
 520 EXTRA_MANS=`for p in $no_install_progs_default; do echo man/$p.1; done`
 521
 522 # Replace all the programs by the single binary and symlinks if specified.
 523 single_binary_progs=
 524 single_binary_libs=
 525 single_binary_deps=
 526 single_binary_install_type=
 527 if test "$gl_single_binary" != no; then
 528   man1_MANS="$man1_MANS man/coreutils.1"
 529   # Convert the list to a space separated list
 530   gl_single_binary_exceptions=`echo $gl_single_binary_exceptions | tr ',' ' '`
 531
 532   single_binary_progs=`echo $optional_bin_progs`
 533   optional_bin_progs="coreutils"
 534   for prog in $gl_single_binary_exceptions; do
 535     # Fail if requested to exclude a program than was not part of coreutils.
 536     case " $single_binary_progs " in
 537       *" $prog "*)
 538         gl_REMOVE_PROG([single_binary_progs], [$prog]) ;
 539         gl_ADD_PROG([optional_bin_progs], [$prog]) ;;
 540       *) AC_MSG_ERROR(['$prog' is not being compiled.]) ;;
 541     esac
 542   done
 543
 544   # single_binary_libs holds the list of libs required by the selected
 545   # programs, such as for example -lrt.
 546   single_binary_libs=`
 547     for p in $single_binary_progs; do
 548       # Convert '[' to '_'
 549       test x"$p" = x'@<:@' && p='_'
 550       printf '$(src_libsinglebin_%s_a_ldadd) ' "$p"
 551     done`
 552   # single_binary_deps holds the list of libsinglebin_*.a files that have the
 553   # compiled code of each selected program in a "library" format.
 554   single_binary_deps=`
 555     for p in $single_binary_progs; do
 556       # Convert '[' to '_'
 557       test x"$p" = x'@<:@' && p='_'
 558       printf 'src/libsinglebin_%s.a ' "$p"
 559     done`
 560   single_binary_install_type="$gl_single_binary"
 561 fi
 562 AC_SUBST([single_binary_progs], [$single_binary_progs])
 563 AC_SUBST([single_binary_libs], [$single_binary_libs])
 564 AC_SUBST([single_binary_deps], [$single_binary_deps])
 565 AC_SUBST([single_binary_install_type], [$single_binary_install_type])
 566
 567
 568 # The programs built and installed by "make && make install".
 569 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 570 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 571 # this case, only for $(bin_PROGRAMS).
 572 bin_PROGRAMS=`
 573   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 574
 575 # Normalize whitespace.
 576 man1_MANS=`echo $man1_MANS`
 577 EXTRA_MANS=`echo $EXTRA_MANS`
 578 bin_PROGRAMS=`echo $bin_PROGRAMS`
 579 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 580
 581 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 582 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 583 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 584 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 585
 586 AC_SUBST([built_programs], [$optional_bin_progs])
 587
 588 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 589
 590 ############################################################################
 591
 592 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 593 # translatable strings, we must use need-formatstring-macros here.
 594 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 595 AM_GNU_GETTEXT_VERSION([0.19.2])
 596
 597 # For a test of uniq: it uses the $LOCALE_FR envvar.
 598 gt_LOCALE_FR
 599
 600 AC_CONFIG_FILES(
 601   Makefile
 602   po/Makefile.in
 603   gnulib-tests/Makefile
 604   )
 605 AC_OUTPUT