configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2016 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.69])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.2 no-dist-gzip dist-xz color-tests parallel-tests
  36                   subdir-objects])
  37 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  38
  39 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  40 dnl (more than 10% execution time) to ./configure, with no benefit for
  41 dnl most users.  Using it to look for bugs requires:
  42 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  43 dnl   ./configure
  44 dnl   make
  45 dnl   make -C src clean
  46 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  47 dnl FIXME: Once we figure out how to avoid false positives, we should
  48 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  49 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  50 m4_if(m4_sysval, [0], [], [dnl
  51 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  52
  53 AC_PROG_CC_STDC
  54 AM_PROG_CC_C_O
  55 AC_PROG_CPP
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_PROG_RANLIB
  58 AC_PROG_LN_S
  59 gl_EARLY
  60 gl_INIT
  61 coreutils_MACROS
  62
  63 # The test suite needs to know if we have a working perl.
  64 # FIXME: this is suboptimal.  Ideally, we would be able to call gl_PERL
  65 # with an ACTION-IF-NOT-FOUND argument ...
  66 cu_have_perl=yes
  67 case $PERL in *"/missing "*) cu_have_perl=no;; esac
  68 AM_CONDITIONAL([HAVE_PERL], [test $cu_have_perl = yes])
  69
  70 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  71 # ------------------------------------------------
  72 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  73 # Otherwise, run RUN-IF-NOT-FOUND.
  74 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  75   [AC_PREPROC_IFELSE(
  76     [AC_LANG_PROGRAM(
  77       [[
  78 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  79 /* ok */
  80 #else
  81 # error "your version of gcc is older than $1.$2"
  82 #endif
  83       ]]),
  84     ], [$3], [$4])
  85   ]
  86 )
  87
  88 AC_ARG_ENABLE([gcc-warnings],
  89   [AS_HELP_STRING([--enable-gcc-warnings],
  90      [turn on many GCC warnings (for developers; best with GNU make)])],
  91   [case $enableval in
  92      yes|no) ;;
  93      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  94    esac
  95    gl_gcc_warnings=$enableval],
  96   [
  97    # GCC provides fine-grained control over diagnostics which
  98    # is used in gnulib for example to suppress warnings from
  99    # certain sections of code.  So if this is available and
 100    # we're running from a git repo, then auto enable the warnings.
 101    gl_gcc_warnings=no
 102    gl_GCC_VERSION_IFELSE([4], [6],
 103                          [test -d "$srcdir"/.git \
 104                           && ! test -f "$srcdir"/.tarball-version \
 105                           && gl_gcc_warnings=yes])]
 106 )
 107
 108 if test "$gl_gcc_warnings" = yes; then
 109   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 110   AC_SUBST([WERROR_CFLAGS])
 111
 112   nw=
 113   # This, $nw, is the list of warnings we disable.
 114   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 115   nw="$nw -Waggregate-return"       # anachronistic
 116   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 117   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 118   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 119   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 120   nw="$nw -Wcast-qual"              # Too many warnings for now
 121   nw="$nw -Wconversion"             # Too many warnings for now
 122   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 123   nw="$nw -Wsign-conversion"        # Too many warnings for now
 124   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 125   nw="$nw -Wunreachable-code"       # Too many warnings for now
 126   nw="$nw -Wpadded"                 # Our structs are not padded
 127   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 128   nw="$nw -Wlogical-op"             # Too many warnings until GCC 4.8.0
 129   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 130   nw="$nw -Wvla"                    # warnings in gettext.h
 131   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 132   nw="$nw -Wswitch-enum"            # Too many warnings for now
 133   nw="$nw -Wswitch-default"         # Too many warnings for now
 134   nw="$nw -Wstack-protector"        # not worth working around
 135   # things I might fix soon:
 136   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 137   nw="$nw -Wmissing-format-attribute" # copy.c
 138   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 139   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 140   nw="$nw -Wsuggest-attribute=format" # warns about copy.c and factor.c
 141
 142   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 143   # For an example, see the code that provoked this report:
 144   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 145   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 146
 147   gl_MANYWARN_ALL_GCC([ws])
 148   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 149   for w in $ws; do
 150     gl_WARN_ADD([$w])
 151   done
 152   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 153   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 154   gl_WARN_ADD([-Wno-format-nonliteral])
 155
 156   # Enable this warning only with gcc-4.8 and newer.  Before that
 157   # bounds checking as done in truncate.c was incorrectly flagged.
 158   # See: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=43772
 159   gl_GCC_VERSION_IFELSE([4], [8], [gl_WARN_ADD([-Wlogical-op])])
 160
 161   # clang is unduly picky about some things.
 162   AC_CACHE_CHECK([whether the compiler is clang], [utils_cv_clang],
 163     [AC_COMPILE_IFELSE(
 164        [AC_LANG_PROGRAM([[
 165             #ifndef __clang__
 166               #error "not clang"
 167             #endif
 168           ]])],
 169        [utils_cv_clang=yes],
 170        [utils_cv_clang=no])])
 171   if test $utils_cv_clang = yes; then
 172     gl_WARN_ADD([-Wno-format-extra-args])
 173     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 174   fi
 175
 176   gl_WARN_ADD([-fdiagnostics-show-option])
 177   gl_WARN_ADD([-funit-at-a-time])
 178
 179   AC_SUBST([WARN_CFLAGS])
 180
 181   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 182   AH_VERBATIM([FORTIFY_SOURCE],
 183   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 184       without upsetting glibc 2.15+. */
 185    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 186    # define _FORTIFY_SOURCE 2
 187    #endif
 188   ])
 189   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 190
 191   # We use a slightly smaller set of warning options for lib/.
 192   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 193   nw=
 194   nw="$nw -Wstrict-overflow"
 195   nw="$nw -Wuninitialized"
 196   nw="$nw -Wunused-macros"
 197   nw="$nw -Wmissing-prototypes"
 198   nw="$nw -Wold-style-definition"
 199   # FIXME: it may be easy to remove this, since it affects only one file:
 200   # the snprintf call at ftoastr.c:132.
 201   nw="$nw -Wdouble-promotion"
 202   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 203   AC_SUBST([GNULIB_WARN_CFLAGS])
 204
 205   # For gnulib-tests, the set is slightly smaller still.
 206   nw=
 207   nw="$nw -Wstrict-prototypes"
 208   # It's not worth being this picky about test programs.
 209   nw="$nw -Wsuggest-attribute=const"
 210   nw="$nw -Wsuggest-attribute=pure"
 211   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 212                          [$GNULIB_WARN_CFLAGS], [$nw])
 213   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 214 fi
 215
 216 AC_ARG_ENABLE([single-binary],
 217   [AS_HELP_STRING([--enable-single-binary=[shebangs|symlinks]],
 218      [Compile all the tools in a single binary, reducing the overall size.
 219       When compiled this way, shebangs (default when enabled) or symlinks are
 220       installed for each tool that points to the single binary.])],
 221   [gl_single_binary=no ;
 222    case $enableval in
 223      yes) gl_single_binary=shebangs ;;
 224      no|shebangs|symlinks) gl_single_binary=$enableval ;;
 225      *)      AC_MSG_ERROR([bad value $enableval for single-binary option.
 226                            Options are: symlinks, shebangs, no.]) ;;
 227    esac],
 228   [gl_single_binary=no]
 229 )
 230 AC_ARG_ENABLE([single-binary-exceptions],
 231   [AS_HELP_STRING([--enable-single-binary-exceptions=PROG_LIST],
 232      [When used with --enable-single-binary, exclude the PROG_LIST from
 233       it, so these programs are compiled as separated files
 234       (comma-separated, default none))])],
 235   [gl_single_binary_exceptions=$enableval],
 236   [gl_single_binary_exceptions=]
 237 )
 238 if test "$gl_single_binary" = 'symlinks'; then
 239   if ! test "`echo ls | sed \"$program_transform_name\"`" = 'ls'; then
 240     AC_MSG_ERROR([program name transformations are not currently supported
 241                   with --enable-single-binary=symlinks.])
 242   fi
 243 fi
 244 AM_CONDITIONAL([SINGLE_BINARY], [test "$gl_single_binary" != no])
 245
 246 AC_FUNC_FORK
 247
 248 optional_bin_progs=
 249 AC_CHECK_FUNCS([chroot],
 250         gl_ADD_PROG([optional_bin_progs], [chroot]))
 251 AC_CHECK_FUNCS([gethostid],
 252         gl_ADD_PROG([optional_bin_progs], [hostid]))
 253
 254 gl_WINSIZE_IN_PTEM
 255
 256 AC_MSG_CHECKING([whether localtime caches TZ])
 257 AC_CACHE_VAL([utils_cv_localtime_cache],
 258 [if test x$ac_cv_func_tzset = xyes; then
 259 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 260 #if STDC_HEADERS
 261 # include <stdlib.h>
 262 #endif
 263 extern char **environ;
 264 void unset_TZ (void)
 265 {
 266   char **from, **to;
 267   for (to = from = environ; (*to = *from); from++)
 268     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 269       to++;
 270 }
 271 int main()
 272 {
 273   time_t now = time ((time_t *) 0);
 274   int hour_GMT0, hour_unset;
 275   if (putenv ("TZ=GMT0") != 0)
 276     return 1;
 277   hour_GMT0 = localtime (&now)->tm_hour;
 278   unset_TZ ();
 279   hour_unset = localtime (&now)->tm_hour;
 280   if (putenv ("TZ=PST8") != 0)
 281     return 1;
 282   if (localtime (&now)->tm_hour == hour_GMT0)
 283     return 1;
 284   unset_TZ ();
 285   if (localtime (&now)->tm_hour != hour_unset)
 286     return 1;
 287   return 0;
 288 }]])],
 289 [utils_cv_localtime_cache=no],
 290 [utils_cv_localtime_cache=yes],
 291 [# If we have tzset, assume the worst when cross-compiling.
 292 utils_cv_localtime_cache=yes])
 293 else
 294         # If we lack tzset, report that localtime does not cache TZ,
 295         # since we can't invalidate the cache if we don't have tzset.
 296         utils_cv_localtime_cache=no
 297 fi])dnl
 298 AC_MSG_RESULT([$utils_cv_localtime_cache])
 299 if test $utils_cv_localtime_cache = yes; then
 300   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 301 fi
 302
 303 # Assume that if getattrat exists, it's compatible with Solaris 11.
 304 AC_CHECK_FUNCS([getattrat])
 305 if test $ac_cv_func_getattrat = yes; then
 306   LIB_NVPAIR=-lnvpair
 307   AC_SUBST([LIB_NVPAIR])
 308 fi
 309
 310 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 311 AC_CHECK_FUNCS([initgroups])
 312 if test $ac_cv_func_initgroups = no; then
 313   AC_CHECK_LIB([os], [initgroups])
 314 fi
 315
 316 AC_CHECK_FUNCS([syslog])
 317 if test $ac_cv_func_syslog = no; then
 318   # syslog is not in the default libraries.  See if it's in some other.
 319   for lib in bsd socket inet; do
 320     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 321       LIBS="$LIBS -l$lib"; break])
 322   done
 323 fi
 324
 325 AC_CACHE_CHECK([for 3-argument setpriority function],
 326   [utils_cv_func_setpriority],
 327   [AC_LINK_IFELSE(
 328     [AC_LANG_PROGRAM(
 329        [[#include <sys/time.h>
 330          #include <sys/resource.h>
 331        ]],
 332        [[setpriority (0, 0, 0);]])],
 333     [utils_cv_func_setpriority=yes],
 334     [utils_cv_func_setpriority=no])])
 335 if test $utils_cv_func_setpriority = no; then
 336   AC_CHECK_FUNCS([nice])
 337 fi
 338 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 339 *yes*)
 340   gl_ADD_PROG([optional_bin_progs], [nice])
 341 esac
 342
 343 AC_DEFUN([coreutils_DUMMY_1],
 344 [
 345   AC_REQUIRE([gl_READUTMP])
 346   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 347     gl_ADD_PROG([optional_bin_progs], [who])
 348     gl_ADD_PROG([optional_bin_progs], [users])
 349     gl_ADD_PROG([optional_bin_progs], [pinky])
 350   fi
 351 ])
 352 coreutils_DUMMY_1
 353
 354 AC_MSG_CHECKING([ut_host in struct utmp])
 355 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 356 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 357                                    #include <utmp.h>
 358                                    struct utmp ut;
 359                                    int s = sizeof ut.ut_host;]])],
 360   [su_cv_func_ut_host_in_utmp=yes],
 361   [su_cv_func_ut_host_in_utmp=no])])
 362 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 363 if test $su_cv_func_ut_host_in_utmp = yes; then
 364   have_ut_host=1
 365   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 366 fi
 367
 368 if test -z "$have_ut_host"; then
 369   AC_MSG_CHECKING([ut_host in struct utmpx])
 370   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 371   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 372                                      #include <utmpx.h>
 373                                      struct utmpx ut;
 374                                      int s = sizeof ut.ut_host;]])],
 375     [su_cv_func_ut_host_in_utmpx=yes],
 376     [su_cv_func_ut_host_in_utmpx=no])])
 377   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 378   if test $su_cv_func_ut_host_in_utmpx = yes; then
 379     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 380     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 381   fi
 382 fi
 383
 384 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 385
 386 AC_SYS_POSIX_TERMIOS()
 387 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 388
 389 if test $ac_cv_sys_posix_termios = yes; then
 390   gl_ADD_PROG([optional_bin_progs], [stty])
 391
 392   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 393   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 394   [AC_EGREP_CPP([yes], [#include <termios.h>
 395 #ifdef IUCLC
 396 yes
 397 #endif], su_cv_sys_termios_needs_xopen_source=no,
 398    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 399 #include <termios.h>
 400 #ifdef IUCLC
 401 yes
 402 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 403    su_cv_sys_termios_needs_xopen_source=no))])
 404   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 405   test $su_cv_sys_termios_needs_xopen_source = yes &&
 406     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 407
 408   AC_MSG_CHECKING([c_line in struct termios])
 409   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 410   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 411                                       #define _XOPEN_SOURCE
 412                                      #endif
 413                                      #include <sys/types.h>
 414                                      #include <termios.h>
 415                                      struct termios t;
 416                                      int s = sizeof t.c_line;]])],
 417     [su_cv_sys_c_line_in_termios=yes],
 418     [su_cv_sys_c_line_in_termios=no])])
 419   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 420   test $su_cv_sys_c_line_in_termios = yes \
 421     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 422 fi
 423
 424 # FIXME: note that this macro appears above, too.
 425 # I'm leaving it here for now.  This whole thing needs to be modernized...
 426 gl_WINSIZE_IN_PTEM
 427
 428 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 429
 430 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 431    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 432   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 433   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 434   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 435 #ifdef WINSIZE_IN_PTEM
 436 # include <sys/stream.h>
 437 # include <sys/ptem.h>
 438 #endif
 439 #include <sys/ioctl.h>
 440 #include <sys/tty.h>
 441 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 442     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 443     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 444   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 445
 446   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 447       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 448                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 449 fi
 450
 451 # For src/kill.c.
 452 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 453   [AC_INCLUDES_DEFAULT
 454 #include <signal.h>])
 455
 456 cu_GMP
 457
 458 # Build df only if there's a point to it.
 459 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 460   gl_ADD_PROG([optional_bin_progs], [df])
 461 fi
 462
 463 # Build stdbuf only if supported
 464 ac_save_CFLAGS=$CFLAGS
 465 ac_save_LDFLAGS=$LDFLAGS
 466 # Detect warnings about ignored "constructor" attributes.
 467 gl_WARN_ADD([-Werror], [CFLAGS])
 468 gl_WARN_ADD([-errwarn], [CFLAGS])
 469 # Put this message here, after gl_WARN_ADD's chatter.
 470 AC_MSG_CHECKING([whether this system supports stdbuf])
 471 CFLAGS="-fPIC $CFLAGS"
 472 LDFLAGS="-shared $LDFLAGS"
 473 stdbuf_supported=no
 474 # Note we only LINK here rather than RUN to support cross compilation
 475 AC_LINK_IFELSE(
 476   [AC_LANG_PROGRAM([[
 477     static int stdbuf = 0;
 478
 479     void __attribute__ ((constructor))
 480     stdbuf_init (void)
 481     {
 482       stdbuf = 1;
 483     }]],[[
 484     if (stdbuf != 1)
 485       return 1;]])
 486   ],
 487   [stdbuf_supported=yes])
 488 AC_MSG_RESULT([$stdbuf_supported])
 489 if test "$stdbuf_supported" = "yes" && test -z "$EXEEXT"; then
 490   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 491 fi
 492 CFLAGS=$ac_save_CFLAGS
 493 LDFLAGS=$ac_save_LDFLAGS
 494
 495 ############################################################################
 496
 497 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 498 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 499 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 500 dnl of coreutils programs to be built only upon explicit user request,
 501 dnl saving that list in the $no_install_progs_default shell variable.
 502 m4_include([m4/cu-progs.m4])
 503
 504 # Now that we know which programs will actually be built, determine
 505 # which optional helper progs should be compiled.
 506 # Note it adding to pkglibexec_PROGRAMS, $(transform) in src/local.mk
 507 # may need to be updated accordingly.
 508 case " $optional_bin_progs " in
 509   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 510   *) pkglibexec_PROGRAMS='';;
 511 esac
 512
 513 man1_MANS=`
 514   for p in $optional_bin_progs; do
 515     # Change "ginstall.1" to "install.1".
 516     test $p = ginstall && p=install
 517     # Ignore the "[" program, since writing a portable make rule to
 518     # generate its manpage is not practical.
 519     dnl Use the autoconf-provided quadrigraph to represent "[",
 520     dnl otherwise we will incur in dreadful quoting issues.
 521     test x$p = x'@<:@' && continue
 522     echo "man/$p.1"
 523   done`
 524
 525 # Not installed by "make install", but must be built when creating
 526 # a distribution tarball.
 527 EXTRA_MANS=`for p in $no_install_progs_default $gl_no_install_prog; do
 528               echo man/$p.1
 529             done`
 530
 531 # Replace all the programs by the single binary and symlinks if specified.
 532 single_binary_progs=
 533 single_binary_libs=
 534 single_binary_deps=
 535 single_binary_install_type=
 536 if test "$gl_single_binary" != no; then
 537   man1_MANS="$man1_MANS man/coreutils.1"
 538   # Convert the list to a space separated list
 539   gl_single_binary_exceptions=`echo $gl_single_binary_exceptions | tr ',' ' '`
 540
 541   single_binary_progs=`echo $optional_bin_progs`
 542   optional_bin_progs="coreutils"
 543   for prog in $gl_single_binary_exceptions; do
 544     # Fail if requested to exclude a program than was not part of coreutils.
 545     case " $single_binary_progs " in
 546       *" $prog "*)
 547         gl_REMOVE_PROG([single_binary_progs], [$prog]) ;
 548         gl_ADD_PROG([optional_bin_progs], [$prog]) ;;
 549       *) AC_MSG_ERROR(['$prog' is not being compiled.]) ;;
 550     esac
 551   done
 552
 553   # single_binary_libs holds the list of libs required by the selected
 554   # programs, such as for example -lrt.
 555   single_binary_libs=`
 556     for p in $single_binary_progs; do
 557       # Convert '[' to '_'
 558       test x"$p" = x'@<:@' && p='_'
 559       printf '$(src_libsinglebin_%s_a_ldadd) ' "$p"
 560     done`
 561   # single_binary_deps holds the list of libsinglebin_*.a files that have the
 562   # compiled code of each selected program in a "library" format.
 563   single_binary_deps=`
 564     for p in $single_binary_progs; do
 565       # Convert '[' to '_'
 566       test x"$p" = x'@<:@' && p='_'
 567       printf 'src/libsinglebin_%s.a ' "$p"
 568     done`
 569   single_binary_install_type="$gl_single_binary"
 570 fi
 571 AC_SUBST([single_binary_progs], [$single_binary_progs])
 572 AC_SUBST([single_binary_libs], [$single_binary_libs])
 573 AC_SUBST([single_binary_deps], [$single_binary_deps])
 574 AC_SUBST([single_binary_install_type], [$single_binary_install_type])
 575
 576
 577 # The programs built and installed by "make && make install".
 578 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 579 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 580 # this case, only for $(bin_PROGRAMS).
 581 bin_PROGRAMS=`
 582   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 583
 584 # Normalize whitespace.
 585 man1_MANS=`echo $man1_MANS`
 586 EXTRA_MANS=`echo $EXTRA_MANS`
 587 bin_PROGRAMS=`echo $bin_PROGRAMS`
 588 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 589
 590 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 591 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 592 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 593 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 594
 595 AC_SUBST([built_programs], [$optional_bin_progs])
 596
 597 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 598
 599 ############################################################################
 600
 601 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 602 # translatable strings, we must use need-formatstring-macros here.
 603 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 604 AM_GNU_GETTEXT_VERSION([0.19.2])
 605
 606 # For a test of uniq: it uses the $LOCALE_FR envvar.
 607 gt_LOCALE_FR
 608
 609 AC_CONFIG_FILES(
 610   Makefile
 611   po/Makefile.in
 612   gnulib-tests/Makefile
 613   )
 614 AC_OUTPUT