m4/jm-macros.m4

   1 #serial 110   -*- autoconf -*-
   2
   3 dnl Misc type-related macros for coreutils.
   4
   5 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # Written by Jim Meyering.
  21
  22 AC_DEFUN([coreutils_MACROS],
  23 [
  24   AM_MISSING_PROG(HELP2MAN, help2man)
  25   AC_SUBST([MAN])
  26
  27   dnl This macro actually runs replacement code.  See isc-posix.m4.
  28   AC_REQUIRE([AC_ISC_POSIX])dnl
  29
  30   gl_CHECK_ALL_TYPES
  31
  32   AC_REQUIRE([gl_CHECK_DECLS])
  33
  34   AC_REQUIRE([gl_PREREQ])
  35
  36   AC_REQUIRE([AC_FUNC_FSEEKO])
  37
  38   # By default, argmatch should fail calling usage (EXIT_FAILURE).
  39   AC_DEFINE([ARGMATCH_DIE], [usage (EXIT_FAILURE)],
  40             [Define to the function xargmatch calls on failures.])
  41   AC_DEFINE([ARGMATCH_DIE_DECL], [void usage (int _e)],
  42             [Define to the declaration of the xargmatch failure function.])
  43
  44   # used by shred
  45   AC_CHECK_FUNCS_ONCE([directio])
  46
  47   # Used by install.c.
  48   coreutils_saved_libs=$LIBS
  49     LIBS="$LIBS $LIB_SELINUX"
  50     AC_CHECK_FUNCS([matchpathcon_init_prefix], [],
  51     [
  52       case "$ac_cv_search_setfilecon:$ac_cv_header_selinux_selinux_h" in
  53         no:*) # SELinux disabled
  54           ;;
  55         *:no) # SELinux disabled
  56           ;;
  57         *)
  58         AC_MSG_WARN([SELinux enabled, but matchpathcon_init_prefix not found])
  59         AC_MSG_WARN([The install utility may run slowly])
  60       esac
  61     ])
  62   LIBS=$coreutils_saved_libs
  63
  64   # Used by sort.c.
  65   AC_CHECK_FUNCS_ONCE([nl_langinfo])
  66   # Used by timeout.c
  67   AC_CHECK_FUNCS_ONCE([setrlimit])
  68
  69   # Used by tail.c.
  70   AC_CHECK_FUNCS([inotify_init],
  71     [AC_DEFINE([HAVE_INOTIFY], [1],
  72      [Define to 1 if you have usable inotify support.])])
  73
  74   AC_CHECK_FUNCS_ONCE([
  75     endgrent
  76     endpwent
  77     fchown
  78     fchmod
  79     ftruncate
  80     iswspace
  81     mkfifo
  82     mbrlen
  83     setgroups
  84     sethostname
  85     siginterrupt
  86     sync
  87     sysctl
  88     sysinfo
  89     tcgetpgrp
  90   ])
  91
  92   # These checks are for Interix, to avoid its getgr* functions, in favor
  93   # of these replacements.  The replacement functions are much more efficient
  94   # because they do not query the domain controller for user information
  95   # when it is not needed.
  96   AC_CHECK_FUNCS_ONCE([
  97     getgrgid_nomembers
  98     getgrnam_nomembers
  99     getgrent_nomembers
 100   ])
 101
 102   dnl This can't use AC_REQUIRE; I'm not quite sure why.
 103   cu_PREREQ_STAT_PROG
 104
 105   # for dd.c and shred.c
 106   #
 107   # Use fdatasync only if declared.  On MacOS X 10.7, fdatasync exists but
 108   # is not declared, and is ineffective.
 109   LIB_FDATASYNC=
 110   AC_SUBST([LIB_FDATASYNC])
 111   AC_CHECK_DECLS_ONCE([fdatasync])
 112   if test $ac_cv_have_decl_fdatasync = yes; then
 113     coreutils_saved_libs=$LIBS
 114     AC_SEARCH_LIBS([fdatasync], [rt posix4],
 115                    [test "$ac_cv_search_fdatasync" = "none required" ||
 116                     LIB_FDATASYNC=$ac_cv_search_fdatasync])
 117     AC_CHECK_FUNCS([fdatasync])
 118     LIBS=$coreutils_saved_libs
 119   fi
 120
 121   # Check whether libcap is usable -- for ls --color support
 122   LIB_CAP=
 123   AC_ARG_ENABLE([libcap],
 124     AC_HELP_STRING([--disable-libcap], [disable libcap support]))
 125   if test "X$enable_libcap" != "Xno"; then
 126     AC_CHECK_LIB([cap], [cap_get_file],
 127       [AC_CHECK_HEADER([sys/capability.h],
 128         [LIB_CAP=-lcap
 129          AC_DEFINE([HAVE_CAP], [1], [libcap usability])]
 130       )])
 131     if test "X$LIB_CAP" = "X"; then
 132       if test "X$enable_libcap" = "Xyes"; then
 133         AC_MSG_ERROR([libcap library was not found or not usable])
 134       else
 135         AC_MSG_WARN([libcap library was not found or not usable.])
 136         AC_MSG_WARN([AC_PACKAGE_NAME will be built without capability support.])
 137       fi
 138     fi
 139   else
 140     AC_MSG_WARN([libcap support disabled by user])
 141   fi
 142   AC_SUBST([LIB_CAP])
 143
 144   # See if linking 'seq' requires -lm.
 145   # It does on nearly every system.  The single exception (so far) is
 146   # BeOS which has all the math functions in the normal runtime library
 147   # and doesn't have a separate math library.
 148
 149   AC_SUBST([SEQ_LIBM])
 150   ac_seq_body='
 151      static double x, y;
 152      x = floor (x);
 153      x = rint (x);
 154      x = modf (x, &y);'
 155   AC_TRY_LINK([#include <math.h>], [$ac_seq_body], ,
 156     [ac_seq_save_LIBS="$LIBS"
 157      LIBS="$LIBS -lm"
 158      AC_TRY_LINK([#include <math.h>], [$ac_seq_body], [SEQ_LIBM=-lm])
 159      LIBS="$ac_seq_save_LIBS"
 160     ])
 161
 162   AC_REQUIRE([AM_LANGINFO_CODESET])
 163
 164   # Accept configure options: --with-tty-group[=GROUP], --without-tty-group
 165   # You can determine the group of a TTY via 'stat --format %G /dev/tty'
 166   # Omitting this option is equivalent to using --without-tty-group.
 167   AC_ARG_WITH([tty-group],
 168     AS_HELP_STRING([--with-tty-group[[[=NAME]]]],
 169       [group used by system for TTYs, "tty" when not specified]
 170       [ (default: do not rely on any group used for TTYs)]),
 171     [tty_group_name=$withval],
 172     [tty_group_name=no])
 173
 174   if test "x$tty_group_name" != xno; then
 175     if test "x$tty_group_name" = xyes; then
 176       tty_group_name=tty
 177     fi
 178     AC_MSG_NOTICE([TTY group used by system set to "$tty_group_name"])
 179     AC_DEFINE_UNQUOTED([TTY_GROUP_NAME], ["$tty_group_name"],
 180       [group used by system for TTYs])
 181   fi
 182 ])
 183
 184 AC_DEFUN([gl_CHECK_ALL_HEADERS],
 185 [
 186   AC_CHECK_HEADERS_ONCE([
 187     hurd.h
 188     paths.h
 189     priv.h
 190     stropts.h
 191     sys/param.h
 192     sys/systeminfo.h
 193     syslog.h
 194   ])
 195   AC_CHECK_HEADERS([sys/sysctl.h], [], [],
 196     [AC_INCLUDES_DEFAULT
 197      [#if HAVE_SYS_PARAM_H
 198        #include <sys/param.h>
 199       #endif]])
 200 ])
 201
 202 # This macro must be invoked before any tests that run the compiler.
 203 AC_DEFUN([gl_CHECK_ALL_TYPES],
 204 [
 205   dnl Checks for typedefs, structures, and compiler characteristics.
 206   AC_REQUIRE([gl_BIGENDIAN])
 207   AC_REQUIRE([AC_C_VOLATILE])
 208   AC_REQUIRE([AC_C_INLINE])
 209   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
 210
 211   AC_REQUIRE([gl_CHECK_ALL_HEADERS])
 212   AC_CHECK_MEMBERS(
 213     [struct stat.st_author],,,
 214     [$ac_includes_default
 215 #include <sys/stat.h>
 216   ])
 217   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
 218
 219   AC_REQUIRE([AC_TYPE_GETGROUPS])
 220   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 221   AC_REQUIRE([AC_TYPE_MODE_T])
 222   AC_REQUIRE([AC_TYPE_OFF_T])
 223   AC_REQUIRE([AC_TYPE_PID_T])
 224   AC_REQUIRE([AC_TYPE_SIZE_T])
 225   AC_REQUIRE([AC_TYPE_UID_T])
 226   AC_CHECK_TYPE([ino_t], [unsigned long int])
 227
 228   dnl This relies on the fact that Autoconf's implementation of
 229   dnl AC_CHECK_TYPE checks includes unistd.h.
 230   AC_CHECK_TYPE([major_t], [unsigned int])
 231   AC_CHECK_TYPE([minor_t], [unsigned int])
 232
 233   AC_REQUIRE([AC_HEADER_MAJOR])
 234 ])