m4/realloc.m4

   1 #serial 4
   2
   3 dnl From Jim Meyering.
   4 dnl Determine whether realloc works when both arguments are 0.
   5 dnl If it doesn't, arrange to use the replacement function.
   6 dnl
   7
   8 AC_DEFUN(jm_FUNC_REALLOC,
   9 [
  10  dnl xmalloc.c requires that this symbol be defined so it doesn't
  11  dnl mistakenly use a broken realloc -- as it might if this test were omitted.
  12  AC_DEFINE_UNQUOTED(HAVE_DONE_WORKING_REALLOC_CHECK, 1,
  13                     [Define if the realloc check has been performed. ])
  14
  15  AC_CACHE_CHECK([for working realloc], jm_cv_func_working_realloc,
  16   [AC_TRY_RUN([
  17     char *realloc ();
  18     int
  19     main ()
  20     {
  21       exit (realloc (0, 0) ? 0 : 1);
  22     }
  23           ],
  24          jm_cv_func_working_realloc=yes,
  25          jm_cv_func_working_realloc=no,
  26          dnl When crosscompiling, assume realloc is broken.
  27          jm_cv_func_working_realloc=no)
  28   ])
  29   if test $jm_cv_func_working_realloc = no; then
  30     AC_LIBOBJ(realloc)
  31     AC_DEFINE_UNQUOTED(realloc, rpl_realloc,
  32       [Define to rpl_realloc if the replacement function should be used.])
  33   fi
  34 ])