announce-gen

   1 #!/usr/bin/perl -w
   2 # Generate an announcement message.
   3 use strict;
   4
   5 use Getopt::Long;
   6 use Digest::MD5;
   7 use Digest::SHA1;
   8
   9 (my $VERSION = '$Revision: 1.11 $ ') =~ tr/[0-9].//cd;
  10 (my $ME = $0) =~ s|.*/||;
  11
  12 my %valid_release_types = map {$_ => 1} qw (alpha beta major);
  13
  14 END
  15 {
  16   # Nobody ever checks the status of print()s.  That's okay, because
  17   # if any do fail, we're guaranteed to get an indicator when we close()
  18   # the filehandle.
  19   #
  20   # Close stdout now, and if there were no errors, return happy status.
  21   # If stdout has already been closed by the script, though, do nothing.
  22   defined fileno STDOUT
  23     or return;
  24   close STDOUT
  25     and return;
  26
  27   # Errors closing stdout.  Indicate that, and hope stderr is OK.
  28   warn "$ME: closing standard output: $!\n";
  29
  30   # Don't be so arrogant as to assume that we're the first END handler
  31   # defined, and thus the last one invoked.  There may be others yet
  32   # to come.  $? will be passed on to them, and to the final _exit().
  33   #
  34   # If it isn't already an error, make it one (and if it _is_ an error,
  35   # preserve the value: it might be important).
  36   $? ||= 1;
  37 }
  38
  39 sub usage ($)
  40 {
  41   my ($exit_code) = @_;
  42   my $STREAM = ($exit_code == 0 ? *STDOUT : *STDERR);
  43   if ($exit_code != 0)
  44     {
  45       print $STREAM "Try `$ME --help' for more information.\n";
  46     }
  47   else
  48     {
  49       my @types = sort keys %valid_release_types;
  50       print $STREAM <<EOF;
  51 Usage: $ME [OPTIONS]
  52
  53 OPTIONS:
  54
  55   Generate an announcement message.
  56
  57   FIXME: describe the following
  58
  59    --release-type=TYPE          TYPE must be one of @types
  60    --package-name=PACKAGE_NAME
  61    --previous-version=VER
  62    --current-version=VER
  63    --release-archive-directory=DIR
  64    --url-directory=URL_DIR
  65    --news=NEWS_FILE             optional
  66
  67    --help             display this help and exit
  68    --version          output version information and exit
  69
  70 EOF
  71     }
  72   exit $exit_code;
  73 }
  74
  75 sub print_changelog_deltas ($$)
  76 {
  77   my ($package_name, $prev_version) = @_;
  78
  79   # Print new ChangeLog entries.
  80
  81   # First find all CVS-controlled ChangeLog files.
  82   use File::Find;
  83   my @changelog;
  84   find ({wanted => sub {$_ eq 'ChangeLog' && -d 'CVS'
  85                           and push @changelog, $File::Find::name}},
  86         '.');
  87
  88   # If there are no ChangeLog files, we're done.
  89   @changelog
  90     or return;
  91   my %changelog = map {$_ => 1} @changelog;
  92
  93   # Reorder the list of files so that if there are ChangeLog
  94   # files in the specified directories, they're listed first,
  95   # in this order:
  96   my @dir = qw ( . src lib m4 config doc );
  97
  98   # A typical @changelog array might look like this:
  99   # ./ChangeLog
 100   # ./po/ChangeLog
 101   # ./m4/ChangeLog
 102   # ./lib/ChangeLog
 103   # ./doc/ChangeLog
 104   # ./config/ChangeLog
 105   my @reordered;
 106   foreach my $d (@dir)
 107     {
 108       my $dot_slash = $d eq '.' ? $d : "./$d";
 109       my $target = "$dot_slash/ChangeLog";
 110       delete $changelog{$target}
 111         and push @reordered, $target;
 112     }
 113
 114   # Append any remaining ChangeLog files.
 115   push @reordered, sort keys %changelog;
 116
 117   # Remove leading `./'.
 118   @reordered = map { s!^\./!!; $_ } @reordered;
 119
 120   print "ChangeLog entries:\n";
 121   # print join ("\n", @reordered), "\n";
 122
 123   $prev_version =~ s/\./_/g;
 124   my $prev_cvs_tag = "\U$package_name\E-$prev_version";
 125
 126   my $cmd = "cvs -n diff -u -r$prev_cvs_tag -rHEAD @reordered";
 127   open DIFF, '-|', $cmd
 128     or die "$ME: cannot run `$cmd': $!\n";
 129   # Print two types of lines, making minor changes:
 130   # Lines starting with `+++ ', e.g.,
 131   # +++ ChangeLog   22 Feb 2003 16:52:51 -0000      1.247
 132   # and those starting with `+'.
 133   # Don't print the others.
 134   while (defined (my $line = <DIFF>))
 135     {
 136       if ($line =~ /^\+\+\+ /)
 137         {
 138           my $separator = "*"x70 ."\n";
 139           $line =~ s///;
 140           $line =~ s/\s.*//;
 141           print $separator, $line, $separator;
 142         }
 143       elsif ($line =~ /^\+/)
 144         {
 145           $line =~ s///;
 146           print $line;
 147         }
 148     }
 149   close DIFF;
 150
 151   # The exit code should be 1.
 152   # Allow in case there are no modified ChangeLog entries.
 153   $? == 256 || $? == 128
 154     or warn "$ME: warning: `cmd' had unexpected exit code or signal ($?)\n";
 155 }
 156
 157 {
 158   my $release_type;
 159   my $package_name;
 160   my $prev_version;
 161   my $curr_version;
 162   my $release_archive_dir;
 163   my @url_dir_list;
 164   my $news_file;
 165
 166   GetOptions
 167     (
 168      'release-type=s' => \$release_type,
 169      'package-name=s' => \$package_name,
 170      'previous-version=s' => \$prev_version,
 171      'current-version=s' => \$curr_version,
 172      'release-archive-directory=s' => \$release_archive_dir,
 173      'url-directory=s@' => \@url_dir_list,
 174      'news=s@' => \$news_file,
 175
 176      help => sub { usage 0 },
 177      version => sub { print "$ME version $VERSION\n"; exit },
 178     ) or usage 1;
 179
 180   my $fail = 0;
 181   # Ensure that sure each required option is specified.
 182   $release_type
 183     or (warn "$ME: release type not specified\n"), $fail = 1;
 184   $package_name
 185     or (warn "$ME: package name not specified\n"), $fail = 1;
 186   $prev_version
 187     or (warn "$ME: previous version string not specified\n"), $fail = 1;
 188   $curr_version
 189     or (warn "$ME: current version string not specified\n"), $fail = 1;
 190   $release_archive_dir
 191     or (warn "$ME: release directory name not specified\n"), $fail = 1;
 192   @url_dir_list
 193     or (warn "$ME: URL directory name(s) not specified\n"), $fail = 1;
 194
 195   exists $valid_release_types{$release_type}
 196     or (warn "$ME: `$release_type': invalid release type\n"), $fail = 1;
 197
 198   @ARGV
 199     and (warn "$ME: too many arguments\n"), $fail = 1;
 200   $fail
 201     and usage 1;
 202
 203   my $my_distdir = "$package_name-$curr_version";
 204   my $tgz = "$my_distdir.tar.gz";
 205   my $tbz = "$my_distdir.tar.bz2";
 206   my $xd = "$package_name-$prev_version-$curr_version.xdelta";
 207
 208   my %size;
 209
 210   foreach my $f (($tgz, $tbz, $xd))
 211     {
 212       my $cmd = "du --human $f";
 213       my $t = `$cmd`;
 214       # FIXME-someday: give a better diagnostic, a la $PROCESS_STATUS
 215       $@
 216         and (warn "$ME: command failed: `$cmd'\n"), $fail = 1;
 217       chomp $t;
 218       $t =~ s/^([\d.]+[MkK]).*/${1}B/;
 219       $size{$f} = $t;
 220     }
 221
 222   $fail
 223     and exit 1;
 224
 225   print <<EOF;
 226
 227 Subject: $my_distdir released
 228
 229 <#secure method=pgpmime mode=sign>
 230
 231 FIXME: put comments here
 232
 233 EOF
 234
 235   foreach my $url (@url_dir_list)
 236     {
 237       print "  $url/$tgz   ($size{$tgz})\n";
 238       print "  $url/$tbz  ($size{$tbz})\n";
 239     }
 240
 241   print "\nAnd here are xdelta-style diffs:\n";
 242   foreach my $url (@url_dir_list)
 243     {
 244       print "  $url/$xd   ($size{$xd})\n";
 245     }
 246
 247   print "\nHere are GPG detached signatures:\n";
 248   foreach my $url (@url_dir_list)
 249     {
 250       print "  $url/$tgz.sig\n";
 251       print "  $url/$tbz.sig\n";
 252     }
 253
 254   # FIXME: clean up upon interrupt or die
 255   my $tmpdir = $ENV{TMPDIR} || '/tmp';
 256   my $tmp = "$tmpdir/$ME-$$";
 257   unlink $tmp;  # ignore failure
 258
 259   print "\nHere are the MD5 and SHA1 signatures:\n";
 260   print "\n";
 261   print "<#part type=text/plain filename=\"$tmp\" disposition=inline>\n"
 262     . "<#/part>\n";
 263
 264   open OUT, '>', $tmp
 265     or die "$ME: $tmp: cannot open for writing: $!\n";
 266
 267   foreach my $meth (qw (md5 sha1))
 268     {
 269       foreach my $f (($tgz, $tbz, $xd))
 270         {
 271           open IN, '<', $f
 272             or die "$ME: $f: cannot open for reading: $!\n";
 273           binmode IN;
 274           my $dig =
 275             ($meth eq 'md5'
 276              ? Digest::MD5->new->addfile(*IN)->hexdigest
 277              : Digest::SHA1->new->addfile(*IN)->hexdigest);
 278           close IN;
 279           print OUT "$dig  $f\n";
 280         }
 281     }
 282
 283   close OUT
 284     or die "$ME: $tmp: while writing: $!\n";
 285   chmod 0400, $tmp;  # ignore failure
 286
 287   if ($news_file)
 288     {
 289       print "\nNEWS\n\n";
 290
 291       # Print all lines from $news_file, starting with the first one
 292       # that mentions $curr_version up to but not including
 293       # the first occurrence of $prev_version.
 294       my $in_items;
 295       open NEWS, '<', $news_file
 296         or die "$ME: $news_file: cannot open for reading: $!\n";
 297       while (defined (my $line = <NEWS>))
 298         {
 299           if ( ! $in_items)
 300             {
 301               $line =~ /^[^ *].*\Q$curr_version\E/o
 302                 or next;
 303               $in_items = 1;
 304               print $line;
 305             }
 306           else
 307             {
 308               # Be careful that this regexp cannot match version numbers
 309               # in NEWS items -- they might well say `introduced in 4.5.5',
 310               # and we don't want that to match.
 311               $line =~ /^[^ *].*\Q$prev_version\E/o
 312                 and last;
 313               print $line;
 314             }
 315         }
 316       close NEWS;
 317
 318       $in_items
 319         or die "$ME: $news_file: no matching lines\n";
 320     }
 321
 322   $release_type eq 'major'
 323     or print_changelog_deltas ($package_name, $prev_version);
 324
 325   exit 0;
 326 }