arch/powerpc/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #ifdef CONFIG_PPC64
   3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   4 #else
   5 #define PROVIDE32(x)    PROVIDE(x)
   6 #endif
   7 #include <asm/page.h>
   8 #include <asm-generic/vmlinux.lds.h>
   9 #include <asm/cache.h>
  10 #include <asm/thread_info.h>
  11
  12 #if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32)
  13 #define STRICT_ALIGN_SIZE       (1 << 24)
  14 #else
  15 #define STRICT_ALIGN_SIZE       PAGE_SIZE
  16 #endif
  17
  18 ENTRY(_stext)
  19
  20 PHDRS {
  21         kernel PT_LOAD FLAGS(7); /* RWX */
  22         notes PT_NOTE FLAGS(0);
  23         dummy PT_NOTE FLAGS(0);
  24
  25         /* binutils < 2.18 has a bug that makes it misbehave when taking an
  26            ELF file with all segments at load address 0 as input.  This
  27            happens when running "strip" on vmlinux, because of the AT() magic
  28            in this linker script.  People using GCC >= 4.2 won't run into
  29            this problem, because the "build-id" support will put some data
  30            into the "notes" segment (at a non-zero load address).
  31
  32            To work around this, we force some data into both the "dummy"
  33            segment and the kernel segment, so the dummy segment will get a
  34            non-zero load address.  It's not enough to always create the
  35            "notes" segment, since if nothing gets assigned to it, its load
  36            address will be zero.  */
  37 }
  38
  39 #ifdef CONFIG_PPC64
  40 OUTPUT_ARCH(powerpc:common64)
  41 jiffies = jiffies_64;
  42 #else
  43 OUTPUT_ARCH(powerpc:common)
  44 jiffies = jiffies_64 + 4;
  45 #endif
  46 SECTIONS
  47 {
  48         . = KERNELBASE;
  49
  50 /*
  51  * Text, read only data and other permanent read-only sections
  52  */
  53
  54         _text = .;
  55         _stext = .;
  56
  57         /*
  58          * Head text.
  59          * This needs to be in its own output section to avoid ld placing
  60          * branch trampoline stubs randomly throughout the fixed sections,
  61          * which it will do (even if the branch comes from another section)
  62          * in order to optimize stub generation.
  63          */
  64         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  65 #ifdef CONFIG_PPC64
  66                 KEEP(*(.head.text.first_256B));
  67 #ifdef CONFIG_PPC_BOOK3E
  68 #else
  69                 KEEP(*(.head.text.real_vectors));
  70                 *(.head.text.real_trampolines);
  71                 KEEP(*(.head.text.virt_vectors));
  72                 *(.head.text.virt_trampolines);
  73 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  74                 KEEP(*(.head.data.fwnmi_page));
  75 # endif
  76 #endif
  77 #else /* !CONFIG_PPC64 */
  78                 HEAD_TEXT
  79 #endif
  80         } :kernel
  81
  82         __head_end = .;
  83
  84 #ifdef CONFIG_PPC64
  85         /*
  86          * BLOCK(0) overrides the default output section alignment because
  87          * this needs to start right after .head.text in order for fixed
  88          * section placement to work.
  89          */
  90         .text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  91 #ifdef CONFIG_LD_HEAD_STUB_CATCH
  92                 *(.linker_stub_catch);
  93                 . = . ;
  94 #endif
  95
  96 #else
  97         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  98                 ALIGN_FUNCTION();
  99 #endif
 100                 /* careful! __ftr_alt_* sections need to be close to .text */
 101                 *(.text.hot .text .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
 102                 SCHED_TEXT
 103                 CPUIDLE_TEXT
 104                 LOCK_TEXT
 105                 KPROBES_TEXT
 106                 IRQENTRY_TEXT
 107                 SOFTIRQENTRY_TEXT
 108                 /*
 109                  * -Os builds call FP save/restore functions. The powerpc64
 110                  * linker generates those on demand in the .sfpr section.
 111                  * .sfpr gets placed at the beginning of a group of input
 112                  * sections, which can break start-of-text offset if it is
 113                  * included with the main text sections, so put it by itself.
 114                  */
 115                 *(.sfpr);
 116                 MEM_KEEP(init.text)
 117                 MEM_KEEP(exit.text)
 118
 119 #ifdef CONFIG_PPC32
 120                 *(.got1)
 121                 __got2_start = .;
 122                 *(.got2)
 123                 __got2_end = .;
 124 #endif /* CONFIG_PPC32 */
 125
 126         } :kernel
 127
 128         . = ALIGN(PAGE_SIZE);
 129         _etext = .;
 130         PROVIDE32 (etext = .);
 131
 132         /* Read-only data */
 133         RO_DATA(PAGE_SIZE)
 134
 135         EXCEPTION_TABLE(0)
 136
 137         NOTES :kernel :notes
 138
 139         /* The dummy segment contents for the bug workaround mentioned above
 140            near PHDRS.  */
 141         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
 142                 LONG(0)
 143                 LONG(0)
 144                 LONG(0)
 145         } :kernel :dummy
 146
 147 /*
 148  * Init sections discarded at runtime
 149  */
 150         . = ALIGN(STRICT_ALIGN_SIZE);
 151         __init_begin = .;
 152         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
 153
 154         /* .exit.text is discarded at runtime, not link time,
 155          * to deal with references from __bug_table
 156          */
 157         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 158                 EXIT_TEXT
 159         }
 160
 161         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 162                 INIT_DATA
 163                 __vtop_table_begin = .;
 164                 *(.vtop_fixup);
 165                 __vtop_table_end = .;
 166                 __ptov_table_begin = .;
 167                 *(.ptov_fixup);
 168                 __ptov_table_end = .;
 169         }
 170
 171         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 172                 INIT_SETUP(16)
 173         }
 174
 175         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 176                 INIT_CALLS
 177         }
 178
 179         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 180                 CON_INITCALL
 181         }
 182
 183         SECURITY_INIT
 184
 185         . = ALIGN(8);
 186         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 187                 __start___ftr_fixup = .;
 188                 *(__ftr_fixup)
 189                 __stop___ftr_fixup = .;
 190         }
 191         . = ALIGN(8);
 192         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 193                 __start___mmu_ftr_fixup = .;
 194                 *(__mmu_ftr_fixup)
 195                 __stop___mmu_ftr_fixup = .;
 196         }
 197         . = ALIGN(8);
 198         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 199                 __start___lwsync_fixup = .;
 200                 *(__lwsync_fixup)
 201                 __stop___lwsync_fixup = .;
 202         }
 203 #ifdef CONFIG_PPC64
 204         . = ALIGN(8);
 205         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 206                 __start___fw_ftr_fixup = .;
 207                 *(__fw_ftr_fixup)
 208                 __stop___fw_ftr_fixup = .;
 209         }
 210 #endif
 211         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 212                 INIT_RAM_FS
 213         }
 214
 215         PERCPU_SECTION(L1_CACHE_BYTES)
 216
 217         . = ALIGN(8);
 218         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 219                 __machine_desc_start = . ;
 220                 *(.machine.desc)
 221                 __machine_desc_end = . ;
 222         }
 223 #ifdef CONFIG_RELOCATABLE
 224         . = ALIGN(8);
 225         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 226         {
 227 #ifdef CONFIG_PPC32
 228                 __dynamic_symtab = .;
 229 #endif
 230                 *(.dynsym)
 231         }
 232         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 233         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 234         {
 235                 __dynamic_start = .;
 236                 *(.dynamic)
 237         }
 238         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 239         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 240         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 241         {
 242                 __rela_dyn_start = .;
 243                 *(.rela*)
 244         }
 245 #endif
 246         /* .exit.data is discarded at runtime, not link time,
 247          * to deal with references from .exit.text
 248          */
 249         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 250                 EXIT_DATA
 251         }
 252
 253         /* freed after init ends here */
 254         . = ALIGN(PAGE_SIZE);
 255         __init_end = .;
 256
 257 /*
 258  * And now the various read/write data
 259  */
 260
 261         . = ALIGN(PAGE_SIZE);
 262         _sdata = .;
 263
 264 #ifdef CONFIG_PPC32
 265         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 266                 DATA_DATA
 267                 *(.sdata)
 268                 *(.sdata2)
 269                 *(.got.plt) *(.got)
 270                 *(.plt)
 271         }
 272 #else
 273         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 274                 DATA_DATA
 275                 *(.data.rel*)
 276                 *(.toc1)
 277                 *(.branch_lt)
 278         }
 279
 280         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 281                 *(.opd)
 282         }
 283
 284         . = ALIGN(256);
 285         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 286                 __toc_start = .;
 287 #ifndef CONFIG_RELOCATABLE
 288                 __prom_init_toc_start = .;
 289                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 290                 __prom_init_toc_end = .;
 291 #endif
 292                 *(.got)
 293                 *(.toc)
 294         }
 295 #endif
 296
 297         /* The initial task and kernel stack */
 298         INIT_TASK_DATA_SECTION(THREAD_SIZE)
 299
 300         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 301                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 302         }
 303
 304         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 305                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 306         }
 307
 308         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 309                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 310         }
 311
 312         . = ALIGN(PAGE_SIZE);
 313         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 314                 NOSAVE_DATA
 315         }
 316
 317         BUG_TABLE
 318
 319         . = ALIGN(PAGE_SIZE);
 320         _edata  =  .;
 321         PROVIDE32 (edata = .);
 322
 323 /*
 324  * And finally the bss
 325  */
 326
 327         BSS_SECTION(0, 0, 0)
 328
 329         . = ALIGN(PAGE_SIZE);
 330         _end = . ;
 331         PROVIDE32 (end = .);
 332
 333         STABS_DEBUG
 334
 335         DWARF_DEBUG
 336
 337         DISCARDS
 338         /DISCARD/ : {
 339                 *(*.EMB.apuinfo)
 340                 *(.glink .iplt .plt .rela* .comment)
 341                 *(.gnu.version*)
 342                 *(.gnu.attributes)
 343                 *(.eh_frame)
 344         }
 345 }