arch/arm/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r1 contains the address limit, which must be preserved
  20  * Outputs:     r0 is the error code
  21  *              r2, r3 contains the zero-extended value
  22  *              lr corrupted
  23  *
  24  * No other registers must be altered.  (see <asm/uaccess.h>
  25  * for specific ASM register usage).
  26  *
  27  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  28  * Note also that it is intended that __get_user_bad is not global.
  29  */
  30 #include <linux/linkage.h>
  31 #include <asm/assembler.h>
  32 #include <asm/errno.h>
  33 #include <asm/domain.h>
  34
  35 ENTRY(__get_user_1)
  36         check_uaccess r0, 1, r1, r2, __get_user_bad
  37 1: TUSER(ldrb)  r2, [r0]
  38         mov     r0, #0
  39         ret     lr
  40 ENDPROC(__get_user_1)
  41
  42 ENTRY(__get_user_2)
  43         check_uaccess r0, 2, r1, r2, __get_user_bad
  44 #ifdef CONFIG_CPU_USE_DOMAINS
  45 rb      .req    ip
  46 2:      ldrbt   r2, [r0], #1
  47 3:      ldrbt   rb, [r0], #0
  48 #else
  49 rb      .req    r0
  50 2:      ldrb    r2, [r0]
  51 3:      ldrb    rb, [r0, #1]
  52 #endif
  53 #ifndef __ARMEB__
  54         orr     r2, r2, rb, lsl #8
  55 #else
  56         orr     r2, rb, r2, lsl #8
  57 #endif
  58         mov     r0, #0
  59         ret     lr
  60 ENDPROC(__get_user_2)
  61
  62 ENTRY(__get_user_4)
  63         check_uaccess r0, 4, r1, r2, __get_user_bad
  64 4: TUSER(ldr)   r2, [r0]
  65         mov     r0, #0
  66         ret     lr
  67 ENDPROC(__get_user_4)
  68
  69 ENTRY(__get_user_8)
  70         check_uaccess r0, 8, r1, r2, __get_user_bad8
  71 #ifdef CONFIG_THUMB2_KERNEL
  72 5: TUSER(ldr)   r2, [r0]
  73 6: TUSER(ldr)   r3, [r0, #4]
  74 #else
  75 5: TUSER(ldr)   r2, [r0], #4
  76 6: TUSER(ldr)   r3, [r0]
  77 #endif
  78         mov     r0, #0
  79         ret     lr
  80 ENDPROC(__get_user_8)
  81
  82 #ifdef __ARMEB__
  83 ENTRY(__get_user_32t_8)
  84         check_uaccess r0, 8, r1, r2, __get_user_bad
  85 #ifdef CONFIG_CPU_USE_DOMAINS
  86         add     r0, r0, #4
  87 7:      ldrt    r2, [r0]
  88 #else
  89 7:      ldr     r2, [r0, #4]
  90 #endif
  91         mov     r0, #0
  92         ret     lr
  93 ENDPROC(__get_user_32t_8)
  94
  95 ENTRY(__get_user_64t_1)
  96         check_uaccess r0, 1, r1, r2, __get_user_bad8
  97 8: TUSER(ldrb)  r3, [r0]
  98         mov     r0, #0
  99         ret     lr
 100 ENDPROC(__get_user_64t_1)
 101
 102 ENTRY(__get_user_64t_2)
 103         check_uaccess r0, 2, r1, r2, __get_user_bad8
 104 #ifdef CONFIG_CPU_USE_DOMAINS
 105 rb      .req    ip
 106 9:      ldrbt   r3, [r0], #1
 107 10:     ldrbt   rb, [r0], #0
 108 #else
 109 rb      .req    r0
 110 9:      ldrb    r3, [r0]
 111 10:     ldrb    rb, [r0, #1]
 112 #endif
 113         orr     r3, rb, r3, lsl #8
 114         mov     r0, #0
 115         ret     lr
 116 ENDPROC(__get_user_64t_2)
 117
 118 ENTRY(__get_user_64t_4)
 119         check_uaccess r0, 4, r1, r2, __get_user_bad8
 120 11: TUSER(ldr)  r3, [r0]
 121         mov     r0, #0
 122         ret     lr
 123 ENDPROC(__get_user_64t_4)
 124 #endif
 125
 126 __get_user_bad8:
 127         mov     r3, #0
 128 __get_user_bad:
 129         mov     r2, #0
 130         mov     r0, #-EFAULT
 131         ret     lr
 132 ENDPROC(__get_user_bad)
 133 ENDPROC(__get_user_bad8)
 134
 135 .pushsection __ex_table, "a"
 136         .long   1b, __get_user_bad
 137         .long   2b, __get_user_bad
 138         .long   3b, __get_user_bad
 139         .long   4b, __get_user_bad
 140         .long   5b, __get_user_bad8
 141         .long   6b, __get_user_bad8
 142 #ifdef __ARMEB__
 143         .long   7b, __get_user_bad
 144         .long   8b, __get_user_bad8
 145         .long   9b, __get_user_bad8
 146         .long   10b, __get_user_bad8
 147         .long   11b, __get_user_bad8
 148 #endif
 149 .popsection