lib/CXGN/Metadata/Dbpatch.pm

   1 =head1 NAME
   2
   3 CXGN::Metadata::Dbpatch
   4
   5 =head1 SYNOPSIS
   6
   7 my $dbpatch = CXGN::Metadata::Dbpatch->new()
   8
   9 =head1 DESCRIPTION
  10
  11 This should be a parent class of all cxgn db patches.
  12 This class takes care of storing a new Metadata and Dbversion objects,
  13 which help us keep track of running db patches on the database.
  14
  15   Options:
  16     -D <dbname> (mandatory)
  17     dbname to load into
  18
  19     -H <dbhost> (mandatory)
  20     dbhost to load into
  21
  22     -u <script_executor_user> (mandatory)
  23     username to run the script
  24
  25     -F force to run this script and don't stop it by
  26     missing previous db_patches
  27
  28     -t test run. Rollback the transaction.
  29
  30   Note: If the first time that you run this script, obviously
  31     you have no previous dbversion row in the md_dbversion
  32     table, so you need to force the execution of this script
  33     using -F
  34
  35
  36 This class has to be sub-classed by a dbpatch script.  The subclass
  37 script has to be named exactly the same as the package name
  38
  39 =head2 Example MyDbpatch.pm
  40
  41   package MyDbpatch;
  42
  43   use Moose;
  44   extends 'CXGN::Metadata::Dbpatch';
  45
  46
  47   #now override init_patch() and patch()
  48    sub init_patch  {
  49       my $self=shift;
  50       # You can name your patch any way you want,
  51       # but it is easiest just to name it with the package name:
  52       #
  53       my $name=__PACKAGE__;
  54       my $description = 'my dbpatch description';
  55       my @prev_patches = (); # list any prerequisites of other patches
  56
  57       # now set the  above 3 params
  58       $self->name($name);
  59       $self->description($description);
  60       $self->prereq(\@prev_patches);
  61   }
  62
  63
  64   sub patch {
  65       my $self=shift;
  66       ### Now you can insert the data using different options:
  67
  68       ##  1- By sql queryes using $dbh->do(<<EOSQL); and detailing in the tag the queries
  69       ##
  70       ##  2- Using objects with the store function
  71       ##
  72       ##  3- Using DBIx::Class first level objects
  73       ##
  74   }
  75
  76   1;
  77
  78
  79 Now you can run the db patch from the command line like this:
  80
  81 mx-run MyDbpatch -H dbhost -D dbname -u username
  82
  83 =head1 AUTHORS
  84
  85  Naama Menda<nm249@cornell.edu>
  86  Lukas Mueller<lam87@cornell.edu>
  87  Aureliano Bombarely<ab782@cornell.edu>
  88
  89 =head1 COPYRIGHT & LICENSE
  90
  91 Copyright 2010 Boyce Thompson Institute for Plant Research
  92
  93 This program is free software; you can redistribute it and/or modify
  94 it under the same terms as Perl itself.
  95
  96
  97 =cut
  98
  99
 100 package CXGN::Metadata::Dbpatch;
 101
 102 use strict;
 103 use warnings;
 104
 105 use CXGN::DB::InsertDBH;
 106 use CXGN::Metadata::Schema;
 107 use CXGN::Metadata::Dbversion;
 108 use Moose;
 109
 110 with 'MooseX::Getopt';
 111 with 'MooseX::Runnable';
 112
 113 has "md_schema" => (
 114     is       => 'rw',
 115     isa      => 'CXGN::Metadata::Schema',
 116     required => 0,
 117     traits   => ['NoGetopt'],
 118 );
 119
 120 has "dbh" => (
 121     is       => 'rw',
 122     isa      => 'Ref',
 123     traits   => ['NoGetopt'],
 124     required => 0,
 125 );
 126
 127 has "dbhost" => (
 128     is            => 'rw',
 129     isa           => 'Str',
 130     required      => 1,
 131     traits        => ['Getopt'],
 132     cmd_aliases   => 'H',
 133     documentation => 'required, database host',
 134 );
 135
 136 has "dbname" => (
 137     is            => 'rw',
 138     isa           => 'Str',
 139     required      => 1,
 140     traits        => ['Getopt'],
 141     documentation => 'required, database name',
 142     cmd_aliases   => 'D',
 143 );
 144
 145 has "name" => (
 146     is       => 'rw',
 147     isa      => 'Str',
 148     traits   => ['NoGetopt'],
 149     required => 0,
 150 );
 151
 152 has "description" => (
 153     is       => 'rw',
 154     isa      => 'Str',
 155     required => 0,
 156     traits   => ['NoGetopt'],
 157 );
 158
 159 has "username" => (
 160     is            => 'rw',
 161     isa           => 'Str',
 162     required      => 1,
 163     traits        => ['Getopt'],
 164     documentation => 'required, your SGN site login name',
 165     cmd_aliases   => 'u'
 166 );
 167
 168 has "prereq" => (
 169     is       => 'rw',
 170     isa      => 'ArrayRef',
 171     required => 0,
 172     traits   => ['NoGetopt'],
 173     default  => sub { [] }
 174
 175 );
 176
 177 has 'force' => (
 178     is          => 'rw',
 179     isa         => 'Bool',
 180     required    => 0,
 181     default     => 0,
 182     traits      => ['Getopt'],
 183     cmd_aliases => 'F',
 184     documentation =>
 185       'force apply, ignoring prereqs and possible duplicate application',
 186 );
 187
 188 has 'trial' => (
 189     is          => 'rw',
 190     isa         => 'Bool',
 191     required    => 0,
 192     default     => 0,
 193     traits      => ['Getopt'],
 194     cmd_aliases => 't',
 195     documentation =>
 196       'Test run. Rollback the transaction.',
 197 );
 198
 199 sub run {
 200     my $self = shift;
 201
 202     ##override this in the parent class
 203     $self->init_patch;
 204     ###
 205
 206     my $dbh =  CXGN::DB::InsertDBH->new(
 207         {
 208             dbname =>$self->dbname,
 209             dbhost => $self->dbhost,
 210         }
 211         )->get_actual_dbh();
 212
 213     $self->dbh($dbh);
 214
 215
 216     my $metadata_schema = CXGN::Metadata::Schema->connect(
 217         sub { $dbh },
 218         { on_connect_do => ['SET search_path TO metadata;'] },
 219         );
 220
 221     ### Now it will check if you have runned this patch or the previous patches
 222
 223     my $dbversion = CXGN::Metadata::Dbversion->new($metadata_schema)
 224         ->complete_checking( {
 225             patch_name  => $self->name,
 226             patch_descr => $self->description,
 227             prepatch => $self->prereq,
 228             force => $self->force
 229                              }
 230         );
 231
 232
 233     #CREATE A METADATA OBJECT and a new metadata_id in the database for this data
 234
 235     my $metadata = CXGN::Metadata::Metadbdata->new($metadata_schema, $self->username);
 236
 237     #Get a new metadata_id (if you are using store function you only need to supply $metadbdata object)
 238
 239     #override this in the sub-class
 240     my $error = $self->patch;
 241     if ($error ne '1') {
 242         print "Failed! Rolling back! \n $error \n ";
 243         $dbh->rollback();
 244         exit();
 245     }
 246     ##
 247
 248     $metadata->get_dbh->do('set search_path to metadata');
 249
 250     my $metadata_id = $metadata->store()->get_metadata_id();
 251     $dbversion->store($metadata);
 252     if ($self->trial) { $dbh->rollback; }
 253     else { $dbh->commit; }
 254 }
 255
 256
 257
 258 sub init_patch {
 259     my $self=shift;
 260     warn "You have to override init_patch in your sub-class!";
 261
 262 }
 263
 264 sub patch {
 265     my $self=shift;
 266     warn "You have to override patch in your sub-class!";
 267 }
 268
 269 ###
 270 1;#
 271 ###