lib/CXGN/DB/Ima.pm

   1 package CXGN::DB::Ima;
   2
   3 =head1 NAME
   4
   5 CXGN::Ima::DBI - subclass of Ima::DBI, customizing it for use with the
   6 CXGN DB infrastructure
   7
   8 =head1 SYNOPSIS
   9
  10   ## this is a complete working script, notice you don't
  11   ## have to create any database connections
  12
  13   package mything;
  14   use base qw/ Ima::DBI /;
  15
  16   __PACKAGE__->set_sql( get_all_foos => <<EOSQL );
  17   select name from foo
  18   EOSQL
  19
  20   my $sth = __PACKAGE__->sql_get_all_foos;
  21   $sth->execute;
  22   my $foo_names = $sth->fetchall_arrayref;
  23
  24 =head1 DESCRIPTION
  25
  26 This is a customized subclass of Ima::DBI, an off-the-shelf,
  27 well-tested connection sharing solution used by the popular
  28 object-relational mapping package Class::DBI.
  29
  30 The reasons to use this package is that ALL SUBCLASSES OF THIS
  31 PACKAGE SHARE THE SAME 'cxgn' DATABASE HANDLE.
  32
  33 The changes are:
  34   - the DB handles it manages are now CXGN::DB::Connections,
  35     not regular DBI connections
  36   - the DB name in set_sql now defaults to 'cxgn', whereas in
  37     vanilla Ima::DBI, it had no default
  38
  39 =head1 BASE CLASS(ES)
  40
  41 L<Ima::DBI>
  42
  43 =head1 AUTHOR(S)
  44
  45 Robert Buels
  46
  47 =cut
  48
  49 use strict;
  50 use base qw/ Ima::DBI /;
  51 use CXGN::DB::Connection;
  52
  53 sub set_db {
  54   my $class = shift;
  55   my $db_name = shift or $class->_croak("Need a db name");
  56   $db_name =~ s/\s/_/g;
  57
  58   $class->_remember_handle($db_name);
  59   no strict 'refs';
  60   *{ $class . "::db_$db_name" } =
  61     $class->_make_cxgn_db_closure(@_);
  62
  63   return 1;
  64 }
  65
  66 sub _make_cxgn_db_closure {
  67   my ($class, @connection) = @_;
  68   my $dbh;
  69   return sub {
  70     unless ($dbh && $dbh->FETCH('Active') && $dbh->ping) {
  71       $dbh = CXGN::DB::Connection->new(@connection);
  72     }
  73     return $dbh;
  74   };
  75 }
  76
  77 #add a 'cxgn' default
  78 sub set_sql {
  79   my $class = shift;
  80   $_[2] ||= 'cxgn';
  81   $class->SUPER::set_sql(@_);
  82 }
  83
  84 #make a db_Main with default connection args
  85 __PACKAGE__->set_db( 'cxgn' );