config/adb.exp

   1 # Copyright (C) 2013-2016 Free Software Foundation, Inc.
   2 #
   3 # This file is part of DejaGnu.
   4 #
   5 # DejaGnu is free software: you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # DejaGnu is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with DejaGnu.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 #
  19 # Get serial number in case of multiple devices
  20 #
  21 proc adb_serial {} {
  22     # If the user has ADB_SERIAL set, use that, otherwise default to the
  23     # only device.
  24     set serial "[getenv ADB_SERIAL]"
  25     if { $serial eq "" } {
  26         set status [catch "exec adb devices |& wc -l" output]
  27         if { $output > 3 } {
  28             perror "Set ADB_SERIAL in your environment to specify the correct target device!"
  29         }
  30         return ""
  31     } else {
  32         return "-s $serial"
  33     }
  34 }
  35
  36 #
  37 # Connect to hostname using adb
  38 #
  39 proc adb_open { hostname } {
  40     global spawn_id
  41
  42     set tries 0
  43     set result -1
  44
  45     if {[board_info $hostname exists shell_prompt]} {
  46         set shell_prompt [board_info $hostname shell_prompt]
  47     } else {
  48         set shell_prompt "root@android:/ # "
  49     }
  50
  51     if {[board_info $hostname exists fileid]} {
  52         unset board_info($hostname,fileid)
  53     }
  54
  55     set serial [adb_serial]
  56     if { $serial ne "" } {
  57       spawn adb [adb_serial] shell
  58     } else {
  59       spawn adb shell
  60     }
  61     if { $spawn_id < 0 } {
  62         perror "invalid spawn id from adb"
  63         return -1
  64     }
  65
  66     send "\r\n"
  67     while { $tries <= 3 } {
  68         expect {
  69             -re ".*$shell_prompt.*$" {
  70                 verbose "Got prompt\n"
  71                 set result 0
  72                 break
  73             }
  74             timeout {
  75                 warning "adb shell: timed out trying to connect."
  76             }
  77             eof {
  78                 perror "adb shell: got EOF while trying to connect."
  79                 break
  80             }
  81         }
  82         incr tries
  83     }
  84
  85     if { $result < 0 } {
  86         #       perror "adb shell: couldn't connect after $tries tries."
  87         catch "close -i $spawn_id"
  88         set spawn_id -1
  89     } else {
  90         set board_info($hostname,fileid) $spawn_id
  91     }
  92
  93     return $spawn_id
  94 }
  95
  96 #
  97 # Download $srcfile to $destfile on $desthost.
  98 #
  99
 100 proc adb_download {desthost srcfile destfile} {
 101     set serial [adb_serial]
 102     verbose "Removing old executable: adb $serial shell rm $destfile" 3
 103     set status [catch "exec adb $serial shell rm $destfile |& cat" output]
 104     verbose "Downloading: adb $serial shell push $srcfile $destfile" 3
 105     set status [catch "exec adb $serial push $srcfile $destfile |& cat" output]
 106     if { $status == 0 } {
 107         verbose "Copied $srcfile to $destfile" 2
 108         return $destfile
 109     } else {
 110         verbose "Download to target failed, $output."
 111         return ""
 112     }
 113 }
 114
 115 proc adb_file {dest op args} {
 116     set file [lindex $args 0]
 117     verbose "Executing command: $op $args" 2
 118     switch -- $op {
 119         exists {
 120             set status [catch "exec adb [adb_serial] shell ls |& cat" out]
 121         }
 122         delete {
 123             set status [catch "exec adb [adb_serial] shell rm $file |& cat" rmout]
 124         }
 125     }
 126     return [eval remote_raw_file \"$dest\" \"$op\" $args]
 127 }
 128
 129 proc adb_upload {desthost srcfile destfile} {
 130     set status [catch "exec adb [adb_serial] pull $srcfile $destfile |& cat" output]
 131     if { $status == 0 } {
 132         verbose "Copied $srcfile to $destfile" 2
 133         return $destfile
 134     } else {
 135         verbose "Upload from $desthost failed, $output."
 136         return ""
 137     }
 138 }
 139
 140 #
 141 # Execute "$cmd $args[0]" on $boardname.
 142 #
 143 proc adb_exec { boardname cmd args } {
 144     global remove_test
 145
 146     if { [llength $args] > 0 } {
 147         set pargs [lindex $args 0]
 148         if { [llength $args] > 1 } {
 149             set inp [lindex $args 1]
 150         } else {
 151             set inp ""
 152         }
 153     } else {
 154         set pargs ""
 155         set inp ""
 156     }
 157
 158     # If CMD sends any output to stderr, exec will think it failed.  More often
 159     # than not that will be true, but it doesn't catch the case where there is
 160     # no output but the exit code is non-zero.
 161     if { $inp eq "" } {
 162         set inp "/dev/null"
 163     }
 164
 165     verbose "Executing on $boardname: $cmd $pargs < $inp"
 166
 167     # Execute commands only from temporary folder, therefore do "cd" first
 168     global android_tmp_dir
 169     set status [catch "exec cat $inp | adb [adb_serial] shell cd $android_tmp_dir \&\& \( $cmd $pargs \) \\; echo XYZ\\\$\\\{\?\\\}ZYX |& cat" output]
 170
 171     # `status' doesn't mean much here other than adb worked ok.
 172     # What we want is whether $cmd ran ok.
 173     if { $status != 0 } {
 174         regsub "XYZ(\[0-9\]*)ZYX\n?" $output "" output
 175         return [list -1 "adb to $boardname failed for $cmd, $output"]
 176     }
 177
 178     regexp "XYZ(\[0-9\]*)ZYX" $output junk status
 179     verbose "adb_exec: status:$status text:$output" 4
 180     if { $status eq "" } {
 181         return [list -1 "Couldn't parse adb output, $output."]
 182     }
 183     regsub "XYZ(\[0-9\]*)ZYX\n?" $output "" output
 184     # Delete one trailing \n because that is what `exec' will do and we want
 185     # to behave identical to it.
 186     regsub "\n$" $output "" output
 187     return [list [expr {$status != 0}] $output]
 188 }