TextGemini.hs

   1 -- This file is part of Diohsc
   2 -- Copyright (C) 2020 Martin Bays <mbays@sdf.org>
   3 --
   4 -- This program is free software: you can redistribute it and/or modify
   5 -- it under the terms of version 3 of the GNU General Public License as
   6 -- published by the Free Software Foundation, or any later version.
   7 --
   8 -- You should have received a copy of the GNU General Public License
   9 -- along with this program.  If not, see http://www.gnu.org/licenses/.
  10
  11 {-# LANGUAGE CPP               #-}
  12 {-# LANGUAGE OverloadedStrings #-}
  13 {-# LANGUAGE Safe              #-}
  14
  15 module TextGemini where
  16
  17 import           Control.Monad.State
  18 import           Data.Maybe          (catMaybes, isJust, mapMaybe)
  19
  20 import           ANSIColour
  21
  22 import qualified Data.Text.Lazy      as T
  23 import           URI
  24
  25 data Link = Link { linkUri :: URIRef, linkDescription :: T.Text }
  26     deriving (Eq,Ord,Show)
  27
  28 data GeminiLine
  29     = TextLine T.Text
  30     | LinkLine { linkLineIndex :: Int, linkLineLink :: Link }
  31     | AltTextLine T.Text
  32     | PreformatToggleLine
  33     | PreformattedLine T.Text T.Text
  34     | HeadingLine Int T.Text
  35     | ItemLine T.Text
  36     | QuoteLine T.Text
  37     | ErrorLine T.Text
  38     deriving (Eq,Ord,Show)
  39
  40 newtype GeminiDocument = GeminiDocument { geminiDocumentLines :: [GeminiLine] }
  41     deriving (Eq,Ord,Show)
  42
  43 extractLinks :: GeminiDocument -> [Link]
  44 extractLinks (GeminiDocument ls) = mapMaybe linkOfLine ls
  45     where
  46     linkOfLine (LinkLine _ link) = Just link
  47     linkOfLine _                 = Nothing
  48
  49 data PreOpt
  50     = PreOptAlt
  51     | PreOptPre
  52     | PreOptBoth
  53     deriving (Eq,Ord,Show)
  54
  55 showPreOpt :: PreOpt -> String
  56 showPreOpt PreOptAlt  = "alt"
  57 showPreOpt PreOptPre  = "pre"
  58 showPreOpt PreOptBoth = "both"
  59
  60 data GemRenderOpts = GemRenderOpts
  61     { grOptsAnsi          :: Bool
  62     , grOptsPre           :: PreOpt
  63     , grOptsWrapWidth     :: Int
  64     , grOptsLinkDescFirst :: Bool
  65     } deriving (Eq,Ord,Show)
  66
  67 printGemDoc :: GemRenderOpts -> (URIRef -> T.Text) -> GeminiDocument -> [T.Text]
  68 printGemDoc (GemRenderOpts ansi preOpt width linkDescFirst)
  69         showUri (GeminiDocument doc) = concatMap printLine doc
  70     where
  71     printLine (TextLine line) = wrapWith "" False line
  72     printLine (AltTextLine line)
  73         | preOpt == PreOptPre || T.null line = []
  74         | otherwise = (:[]) $ applyIf ansi withBoldStr "`` " <> line
  75
  76     printLine PreformatToggleLine = []
  77
  78     printLine (PreformattedLine alt line)
  79         | preOpt == PreOptAlt && not (T.null alt) = []
  80         | otherwise = (:[]) $ applyIf ansi ((resetCode <>) . withBoldStr) "` " <> line
  81     printLine (HeadingLine level line) =
  82         wrapWith (T.take (fromIntegral level) (T.repeat '#') <> " ") False
  83         . applyIf ansi
  84             ( applyIf (level /= 2) withUnderlineStr
  85             . applyIf (level < 3) withBoldStr ) $ line
  86     printLine (ItemLine line) = wrapWith "* " False line
  87     printLine (QuoteLine line) = wrapWith "> " True line
  88     printLine (ErrorLine line) = (:[]) $ applyIf ansi (withColourStr Red)
  89         "! Formatting error in text/gemini: " <> line
  90     printLine (LinkLine n (Link uri desc)) =
  91         wrapWith (T.pack $ '[' : show (n+1) ++ if n+1 < 10 then "]  " else "] ") False
  92             $ (if T.null desc then id
  93                 else (if linkDescFirst then id else flip) (\a b -> a <> " " <> b)
  94                     $ applyIf ansi (withColourStr Cyan) desc)
  95                 (showUri uri)
  96
  97     wrapWith :: T.Text -> Bool -> T.Text -> [T.Text]
  98     wrapWith pre onAll line =
  99         concat . zipWith prependHeader lineHeaders $ wrap (width - n) line
 100         where
 101             n = visibleLength pre
 102             lineHeaders = (pre:) . repeat $
 103                 if onAll then pre else T.replicate (fromIntegral n) " "
 104             splitWordHeader = if n > 0 then "|" <> T.replicate (fromIntegral n - 1) " " else ""
 105             prependHeader header (l:ls) = header <> l : ((splitWordHeader <>) <$> ls)
 106             prependHeader _ [] = []
 107
 108     wrap :: Int -> T.Text -> [[T.Text]]
 109     wrap wrapWidth line = wrap' [] "" 0 $ T.words line
 110         where
 111         maxWCWidth = 2
 112         ww = max maxWCWidth wrapWidth
 113         wrap' ls l _ [] = [ls <> [l] ]
 114         wrap' ls l n (w:ws) =
 115             let nw = visibleLength w
 116                 l' = if T.null l then w else l <> " " <> w
 117                 n' = n + nw + (if T.null l then 0 else 1)
 118             in if nw > ww && n + 1 < ww
 119                 then let (a,b) = splitAtVisible ww l'
 120                     in wrap' (ls <> [a]) "" 0 $ b:ws
 121                 else if n' > ww
 122                     then (ls <> [l]:) $ wrap' [] "" 0 $ w:ws
 123                     else wrap' ls l' n' ws
 124
 125
 126 data GeminiParseState = GeminiParseState { numLinks :: Int, preformatted :: Maybe T.Text }
 127
 128 initialParseState :: GeminiParseState
 129 initialParseState = GeminiParseState 0 Nothing
 130
 131 parseGemini :: T.Text -> GeminiDocument
 132 parseGemini text = GeminiDocument . catMaybes $ evalState
 133         (forM (T.lines text) (parseLine . stripTrailingCR)) initialParseState
 134     where
 135     stripTrailingCR = T.dropWhileEnd (== '\r')
 136     parseLine :: T.Text -> State GeminiParseState (Maybe GeminiLine)
 137     parseLine line = do
 138         pre <- gets preformatted
 139         case T.take 1 line of
 140             "`" | T.take 3 line == "```", isJust pre ->  do
 141                 modify $ \s -> s { preformatted = Nothing }
 142                 return $ case T.strip $ T.drop 3 line of
 143                     "" -> Nothing
 144                     _ -> Just . ErrorLine $ "Illegal non-empty text after closing '```'"
 145                     -- ^The spec says we MUST ignore any text on a "```" line closing a preformatted
 146                     -- block. This seems like a gaping extensibility hole to me, so I'm interpreting it
 147                     -- as not disallowing an error message.
 148             "`" | T.take 3 line == "```" ->
 149                 let alt = T.strip $ T.drop 3 line in do
 150                     modify $ \s -> s { preformatted = Just alt }
 151                     return . Just . AltTextLine $ alt
 152             _ | Just alt <- pre ->
 153                 return . Just $ PreformattedLine alt line
 154             "=" | T.take 2 line == "=>" ->
 155                 case parseLink . T.dropWhile isGemWhitespace $ T.drop 2 line of
 156                     Nothing -> return . Just . ErrorLine $ "Unparseable link line: " <> line
 157                     Just link -> do
 158                         n <- gets numLinks
 159                         modify $ \s -> s { numLinks = n + 1 }
 160                         return . Just $ LinkLine n link
 161             "#" | headers <- T.length . T.takeWhile (== '#') $ line,
 162                     headers > 0 && headers < 4 ->
 163                 return . Just . HeadingLine (fromIntegral headers) .
 164                     T.dropWhile isGemWhitespace . T.dropWhile (== '#') $ line
 165             "*" | T.take 2 line == "* " ->
 166                 return . Just . ItemLine $ T.drop 2 line
 167             ">" ->
 168                 return . Just . QuoteLine $ T.drop 1 line
 169             _ ->
 170                 return . Just $ TextLine line
 171
 172     parseLink :: T.Text -> Maybe Link
 173     parseLink linkInfo =
 174         let uriText = T.takeWhile (not . isGemWhitespace) linkInfo
 175             desc = T.dropWhile isGemWhitespace . T.dropWhile (not . isGemWhitespace) $ linkInfo
 176         in (`Link` desc) <$> parseUriReference (
 177 #ifdef IRILinks
 178         escapeIRI $
 179 #endif
 180         T.unpack uriText)
 181
 182     isGemWhitespace :: Char -> Bool
 183     isGemWhitespace = (`elem` (" \t"::String))