wmclockmon/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.52])
   3
   4 AC_INIT([wmclockmon], [0.8.1], [wmaker-dev@googlegroups.com])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6 AM_INIT_AUTOMAKE([no-dist-gzip dist-xz])
   7 AC_CONFIG_SRCDIR([src/main.c])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIRS([m4])
  10
  11 AC_CANONICAL_HOST
  12
  13 dnl Checks for programs.
  14 AC_PROG_AWK
  15 AC_PROG_CC
  16 AC_PROG_INSTALL
  17 AC_PROG_LN_S
  18
  19 AX_C___ATTRIBUTE__
  20 AM_CONDITIONAL([HAVE___ATTRIBUTE__], [test "$ax_cv___attribute__" = "yes"])
  21
  22 PKG_CHECK_MODULES([gtk], [gtk+-3.0])
  23
  24 dnl ===========================================
  25 dnl             Stuff that uses X
  26 dnl ===========================================
  27
  28 PKG_CHECK_MODULES([x11],  [x11])
  29 PKG_CHECK_MODULES([xext], [xext])
  30 PKG_CHECK_MODULES([xpm],  [xpm])
  31
  32 dnl ===============================================
  33 dnl             End of stuff that uses X
  34 dnl ===============================================
  35
  36 dnl =========
  37 dnl Debugging
  38 dnl =========
  39
  40 AC_ARG_ENABLE([debug],
  41               [AS_HELP_STRING([--enable-debug], [turn on debugging [default=no]])])
  42 AS_IF([test "$enable_debug" = yes], [
  43   debug_CPPFLAGS="-D_XOPEN_SOURCE=700 -DGTK_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_DEPRECATED"
  44   debug_CFLAGS="-Wall -Wextra -std=c11 -pedantic"
  45   AC_DEFINE([DEBUG], [1], [use debug code])
  46 ])
  47 AC_SUBST([debug_CPPFLAGS])
  48 AC_SUBST([debug_CFLAGS])
  49
  50
  51 dnl ============
  52 dnl Check for OS
  53 dnl ============
  54
  55 AS_CASE([${host_os}],
  56         [freebsd*], [
  57           LIBS="$LIBS -lkvm"
  58           SETGID_FLAGS="-g kmem -m 2755 -o root"
  59         ],
  60         [linux*|netbsd*|openbsd*|solaris*], [],
  61         [AC_MSG_ERROR([Sorry, ${host_os} is not supported yet])])
  62 AC_SUBST([SETGID_FLAGS])
  63
  64 dnl Checks for header files.
  65 AC_CHECK_HEADERS([fcntl.h memory.h stddef.h stdlib.h string.h strings.h sys/param.h sys/time.h unistd.h])
  66
  67 dnl Checks for typedefs, structures, and compiler characteristics.
  68 AC_C_CONST
  69 AC_TYPE_SIZE_T
  70
  71 dnl Checks for library functions.
  72 AC_FUNC_MALLOC
  73 AC_CHECK_FUNCS([select strtoul uname])
  74
  75 AC_CONFIG_FILES([Makefile
  76                  doc/Makefile
  77                  src/Makefile
  78                  styles/Makefile
  79                  wmclockmon-config/Makefile
  80                  wmclockmon-cal/Makefile])
  81 AC_OUTPUT