wmclockmon/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.52])
   3
   4 AC_INIT([wmclockmon], [0.8.1], [tnemeth@free.fr])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6 AM_INIT_AUTOMAKE([no-dist-gzip dist-xz])
   7 AC_CONFIG_SRCDIR([src/main.c])
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AC_CANONICAL_HOST
  11
  12 dnl Checks for programs.
  13 AC_PROG_AWK
  14 AC_PROG_CC
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17
  18 PKG_CHECK_MODULES([gtk], [gtk+-2.0])
  19
  20 dnl ===========================================
  21 dnl             Stuff that uses X
  22 dnl ===========================================
  23
  24 PKG_CHECK_MODULES([x11],  [x11])
  25 PKG_CHECK_MODULES([xext], [xext])
  26 PKG_CHECK_MODULES([xpm],  [xpm])
  27
  28 dnl ===============================================
  29 dnl             End of stuff that uses X
  30 dnl ===============================================
  31
  32 dnl =========
  33 dnl Debugging
  34 dnl =========
  35
  36 AC_ARG_ENABLE([debug],
  37               [AS_HELP_STRING([--enable-debug], [turn on debugging [default=no]])])
  38 AS_IF([test "$enable_debug" = yes], [
  39   debug_CFLAGS="-Wall -g -ansi -pedantic"
  40   AC_DEFINE([DEBUG], [1], [use debug code])
  41 ])
  42 AC_SUBST([debug_CFLAGS])
  43
  44
  45 dnl ============
  46 dnl Check for OS
  47 dnl ============
  48
  49 AS_CASE([${host_os}],
  50         [freebsd*], [
  51           LIBS="$LIBS -lkvm"
  52           SETGID_FLAGS="-g kmem -m 2755 -o root"
  53         ],
  54         [linux*|netbsd*|openbsd*|solaris*], [],
  55         [AC_MSG_ERROR([Sorry, ${host_os} is not supported yet])])
  56 AC_SUBST([SETGID_FLAGS])
  57
  58 dnl Checks for header files.
  59 AC_CHECK_HEADERS([fcntl.h memory.h stddef.h stdlib.h string.h strings.h sys/param.h sys/time.h unistd.h])
  60
  61 dnl Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_TYPE_SIZE_T
  64
  65 dnl Checks for library functions.
  66 AC_FUNC_MALLOC
  67 AC_CHECK_FUNCS([select strtoul uname])
  68
  69 AC_CONFIG_FILES([Makefile
  70                  doc/Makefile
  71                  src/Makefile
  72                  styles/Makefile
  73                  wmclockmon-config/Makefile
  74                  wmclockmon-cal/Makefile])
  75 AC_OUTPUT