m4/dpkg-types.m4

   1 # serial 2
   2 # Copyright © 2005 Scott James Remnant <scott@netsplit.com>
   3 # Copyright © 2009-2023 Guillem Jover <guillem@debian.org>
   4
   5 # DPKG_TYPE_PTRDIFF_T
   6 # -------------------
   7 # Check for the ptrdiff_t type, defining to int if not defined
   8 AC_DEFUN([DPKG_TYPE_PTRDIFF_T], [
   9   AC_CHECK_TYPE([ptrdiff_t], [], [
  10     AC_DEFINE_UNQUOTED([ptrdiff_t], [int],
  11       [Define to 'int' if <malloc.h> does not define.])
  12   ])
  13 ])# DPKG_TYPE_PTRDIFF_T
  14
  15 # DPKG_TYPE_STRUCT_PSINFO
  16 # -----------------------
  17 # Check for the struct psinfo type.
  18 AC_DEFUN([DPKG_TYPE_STRUCT_PSINFO], [
  19   AC_REQUIRE([DPKG_CHECK_HEADER_SYS_PROCFS])
  20
  21   AC_CHECK_TYPES([struct psinfo], [], [], [[
  22 #if !DPKG_STRUCTURED_PROCFS_SUPPORTS_LFS
  23 #undef _FILE_OFFSET_BITS
  24 #endif
  25 #define _STRUCTURED_PROC 1
  26 #if HAVE_SYS_PROCFS_H
  27 #include <sys/procfs.h>
  28 #endif
  29   ]])
  30 ])# DPKG_TYPE_STRUCT_PSINFO
  31
  32 # DPKG_DECL_SYS_SIGLIST
  33 # ---------------------
  34 # Check for the sys_siglist variable in either signal.h or unistd.h
  35 AC_DEFUN([DPKG_DECL_SYS_SIGLIST], [
  36   AC_CHECK_HEADERS([unistd.h])
  37   AC_CHECK_DECLS([sys_siglist], [], [], [[
  38 #include <signal.h>
  39 /* NetBSD declares sys_siglist in unistd.h.  */
  40 #if HAVE_UNISTD_H
  41 #  include <unistd.h>
  42 #endif
  43   ]])
  44 ])# DPKG_DECL_SYS_SIGLIST
  45
  46 # DPKG_DECL_SYS_ERRLIST
  47 # ---------------------
  48 # Check for the sys_errlist and sys_nerr variables in either errno.h or
  49 # stdio.h
  50 AC_DEFUN([DPKG_DECL_SYS_ERRLIST], [
  51   AC_CHECK_DECLS([sys_errlist, sys_nerr], [], [], [[
  52 #include <errno.h>
  53 /* glibc declares sys_errlist in stdio.h.  */
  54 #include <stdio.h>
  55   ]])
  56   AM_CONDITIONAL([HAVE_SYS_ERRLIST],
  57     [test "x$ac_cv_have_decl_sys_errlist" = "xyes" && \
  58      test "x$ac_cv_have_decl_sys_nerr" = "xyes"])
  59 ])# DPKG_DECL_SYS_SIGLIST
  60
  61 # DPKG_CHECK_DECL([DECL], [HEADER])
  62 # ---------------
  63 # Define HAVE_DECL to 1 if declared in HEADER
  64 AC_DEFUN([DPKG_CHECK_DECL], [
  65   AC_CHECK_DECL([$1], [
  66     AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
  67       [Define to 1 if ']$1[' is declared in <$2>])
  68   ], [], [[#include <$2>]])
  69 ])# DPKG_CHECK_DECL