scripts/Dpkg/BuildTypes.pm

   1 # Copyright © 2007 Frank Lichtenheld <djpig@debian.org>
   2 # Copyright © 2010, 2013-2016 Guillem Jover <guillem@debian.org>
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  16
  17 =encoding utf8
  18
  19 =head1 NAME
  20
  21 Dpkg::BuildTypes - track build types
  22
  23 =head1 DESCRIPTION
  24
  25 The Dpkg::BuildTypes module is used by various tools to track and decide
  26 what artifacts need to be built.
  27
  28 The build types are bit constants that are exported by default. Multiple
  29 types can be ORed.
  30
  31 B<Note>: This is a private module, its API can change at any time.
  32
  33 =cut
  34
  35 package Dpkg::BuildTypes 0.02;
  36
  37 use strict;
  38 use warnings;
  39
  40 our @EXPORT = qw(
  41     BUILD_DEFAULT
  42     BUILD_SOURCE
  43     BUILD_ARCH_DEP
  44     BUILD_ARCH_INDEP
  45     BUILD_BINARY
  46     BUILD_FULL
  47     build_has_any
  48     build_has_all
  49     build_has_none
  50     build_is
  51     set_build_type
  52     set_build_type_from_options
  53     set_build_type_from_targets
  54     get_build_options_from_type
  55 );
  56
  57 use Exporter qw(import);
  58
  59 use Dpkg::Gettext;
  60 use Dpkg::ErrorHandling;
  61
  62 =head1 CONSTANTS
  63
  64 =over 4
  65
  66 =item BUILD_DEFAULT
  67
  68 This build is the default.
  69
  70 =item BUILD_SOURCE
  71
  72 This build includes source artifacts.
  73
  74 =item BUILD_ARCH_DEP
  75
  76 This build includes architecture dependent binary artifacts.
  77
  78 =item BUILD_ARCH_INDEP
  79
  80 This build includes architecture independent binary artifacts.
  81
  82 =item BUILD_BINARY
  83
  84 This build includes binary artifacts.
  85
  86 =item BUILD_FULL
  87
  88 This build includes source and binary artifacts.
  89
  90 =cut
  91
  92 # Simple types.
  93 use constant {
  94     BUILD_DEFAULT      => 1,
  95     BUILD_SOURCE       => 2,
  96     BUILD_ARCH_DEP     => 4,
  97     BUILD_ARCH_INDEP   => 8,
  98 };
  99
 100 # Composed types.
 101 use constant BUILD_BINARY => BUILD_ARCH_DEP | BUILD_ARCH_INDEP;
 102 use constant BUILD_FULL   => BUILD_BINARY | BUILD_SOURCE;
 103
 104 my $current_type = BUILD_FULL | BUILD_DEFAULT;
 105 my $current_option = undef;
 106
 107 my @build_types = qw(full source binary any all);
 108 my %build_types = (
 109     full => BUILD_FULL,
 110     source => BUILD_SOURCE,
 111     binary => BUILD_BINARY,
 112     any => BUILD_ARCH_DEP,
 113     all => BUILD_ARCH_INDEP,
 114 );
 115 my %build_targets = (
 116     'clean' => BUILD_SOURCE,
 117     'build' => BUILD_BINARY,
 118     'build-arch' => BUILD_ARCH_DEP,
 119     'build-indep' => BUILD_ARCH_INDEP,
 120     'binary' => BUILD_BINARY,
 121     'binary-arch' => BUILD_ARCH_DEP,
 122     'binary-indep' => BUILD_ARCH_INDEP,
 123 );
 124
 125 =back
 126
 127 =head1 FUNCTIONS
 128
 129 =over 4
 130
 131 =item build_has_any($bits)
 132
 133 Return a boolean indicating whether the current build type has any of the
 134 specified $bits.
 135
 136 =cut
 137
 138 sub build_has_any
 139 {
 140     my ($bits) = @_;
 141
 142     return $current_type & $bits;
 143 }
 144
 145 =item build_has_all($bits)
 146
 147 Return a boolean indicating whether the current build type has all the
 148 specified $bits.
 149
 150 =cut
 151
 152 sub build_has_all
 153 {
 154     my ($bits) = @_;
 155
 156     return ($current_type & $bits) == $bits;
 157 }
 158
 159 =item build_has_none($bits)
 160
 161 Return a boolean indicating whether the current build type has none of the
 162 specified $bits.
 163
 164 =cut
 165
 166 sub build_has_none
 167 {
 168     my ($bits) = @_;
 169
 170     return !($current_type & $bits);
 171 }
 172
 173 =item build_is($bits)
 174
 175 Return a boolean indicating whether the current build type is the specified
 176 set of $bits.
 177
 178 =cut
 179
 180 sub build_is
 181 {
 182     my ($bits) = @_;
 183
 184     return $current_type == $bits;
 185 }
 186
 187 =item set_build_type($build_type, $build_option, %opts)
 188
 189 Set the current build type to $build_type, which was specified via the
 190 $build_option command-line option.
 191
 192 The function will check and abort on incompatible build type assignments,
 193 this behavior can be disabled by using the boolean option "nocheck".
 194
 195 =cut
 196
 197 sub set_build_type
 198 {
 199     my ($build_type, $build_option, %opts) = @_;
 200
 201     usageerr(g_('cannot combine %s and %s'), $current_option, $build_option)
 202         if not $opts{nocheck} and
 203            build_has_none(BUILD_DEFAULT) and $current_type != $build_type;
 204
 205     $current_type = $build_type;
 206     $current_option = $build_option;
 207 }
 208
 209 =item set_build_type_from_options($build_types, $build_option, %opts)
 210
 211 Set the current build type from a list of comma-separated build type
 212 components.
 213
 214 The function will check and abort on incompatible build type assignments,
 215 this behavior can be disabled by using the boolean option "nocheck".
 216
 217 =cut
 218
 219 sub set_build_type_from_options
 220 {
 221     my ($build_parts, $build_option, %opts) = @_;
 222
 223     my $build_type = 0;
 224     foreach my $type (split /,/, $build_parts) {
 225         usageerr(g_('unknown build type %s'), $type)
 226             unless exists $build_types{$type};
 227         $build_type |= $build_types{$type};
 228     }
 229
 230     set_build_type($build_type, $build_option, %opts);
 231 }
 232
 233 =item set_build_type_from_targets($build_targets, $build_option, %opts)
 234
 235 Set the current build type from a list of comma-separated build target
 236 components.
 237
 238 The function will check and abort on incompatible build type assignments,
 239 this behavior can be disabled by using the boolean option "nocheck".
 240
 241 =cut
 242
 243 sub set_build_type_from_targets
 244 {
 245     my ($build_targets, $build_option, %opts) = @_;
 246
 247     my $build_type = 0;
 248     foreach my $target (split /,/, $build_targets) {
 249         $build_type |= $build_targets{$target} // BUILD_BINARY;
 250     }
 251
 252     set_build_type($build_type, $build_option, %opts);
 253 }
 254
 255 =item get_build_options_from_type()
 256
 257 Get the current build type as a set of comma-separated string options.
 258
 259 =cut
 260
 261 sub get_build_options_from_type
 262 {
 263     my $local_type = $current_type;
 264
 265     my @parts;
 266     foreach my $type (@build_types) {
 267         my $part_bits = $build_types{$type};
 268         if (($local_type & $part_bits) == $part_bits) {
 269             push @parts, $type;
 270             $local_type &= ~$part_bits;
 271         }
 272     }
 273
 274     return join ',', @parts;
 275 }
 276
 277 =back
 278
 279 =head1 CHANGES
 280
 281 =head2 Version 0.xx
 282
 283 This is a private module.
 284
 285 =cut
 286
 287 1;