configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 m4_pattern_forbid([^_?DPKG_])
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([dpkg], m4_esyscmd([build-aux/get-version]),
   7         [debian-dpkg@lists.debian.org], [dpkg],
   8         [https://wiki.debian.org/Teams/Dpkg])
   9 DPKG_DIST_IS_RELEASE
  10 AC_SUBST([PACKAGE_COPYRIGHT_HOLDER], ['Dpkg Developers'])
  11 AC_SUBST([PACKAGE_VCS_ID], m4_esyscmd([build-aux/get-vcs-id]))
  12 AC_SUBST([PACKAGE_VCS_TYPE], [git])
  13 AC_SUBST([PACKAGE_VCS_URL], [https://git.dpkg.org/git/dpkg/dpkg.git])
  14 AC_SUBST([PACKAGE_VCS_WEB], [https://git.dpkg.org/cgit/dpkg/dpkg.git])
  15 AC_SUBST([PACKAGE_BUG_WEB], [https://bugs.debian.org/src:dpkg])
  16 AC_SUBST([PACKAGE_CPAN_NAME], [Dpkg])
  17 AC_CONFIG_SRCDIR([lib/dpkg/dpkg.h])
  18 AC_CONFIG_MACRO_DIR([m4])
  19 AC_CONFIG_AUX_DIR([build-aux])
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_INIT_AUTOMAKE(
  24   [1.11]
  25   [-Wall]
  26   [foreign]
  27   [nostdinc]
  28   [subdir-objects]
  29   [tar-ustar no-dist-gzip dist-xz]
  30 )
  31 AM_SILENT_RULES([yes])
  32
  33 # Require at least this gettext version, but will take any later version too.
  34 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
  35 # XXX: We cannot remove the following macro due to backwards compatibility
  36 # reasons. The above macro is set unconditionally to the minimal version
  37 # required, and the below is set to 0.19.6, the first version introducing
  38 # the AM_GNU_GETTEXT_REQUIRE_VERSION macro.
  39 AM_GNU_GETTEXT_VERSION([0.19.6])
  40 AM_GNU_GETTEXT([external])
  41 DPKG_DIST_CHECK([test "$GMSGFMT" = ":" && test "$USE_NLS" = "yes"],
  42   [gettext required when NLS support enabled])
  43
  44 # Shared libraries are disabled on purpose, currently there is no ABI stability
  45 # guarantee, and it will be broken at will. The infrastructure is in place just
  46 # to be able to test that its future activation will work.
  47 AM_PROG_AR
  48 LT_INIT([disable-shared])
  49 DPKG_BUILD_SHARED_LIBS
  50 DPKG_LINKER_AS_NEEDED
  51 DPKG_LINKER_VERSION_SCRIPT
  52
  53 # Allow compilation without optional programs
  54 DPKG_BUILD_PROG([dselect])
  55 DPKG_BUILD_PROG([start-stop-daemon])
  56 DPKG_BUILD_PROG([update-alternatives])
  57
  58 DPKG_BUILD_RELEASE_DATE
  59 DPKG_BUILD_DEVEL_DOCS
  60
  61 # Allow alternate directories
  62 DPKG_WITH_DIR([devlibdir], [${libdir}],
  63   [dpkg development library directory [LIBDIR]])
  64 DPKG_WITH_DIR([pkgconfdir], [${sysconfdir}/${PACKAGE_TARNAME}],
  65   [dpkg configuration directory [SYSCONFDIR/dpkg]])
  66 DPKG_WITH_DIR([docspecdir], [${docdir}/spec],
  67   [dpkg specifications directory [DOCDIR/spec]])
  68 DPKG_WITH_DIR([methodsdir], [${libexecdir}/${PACKAGE_TARNAME}/methods],
  69   [dpkg download methods directory [LIBEXECDIR/dpkg/methods]])
  70 DPKG_WITH_DIR([admindir], [${localstatedir}/lib/${PACKAGE_TARNAME}],
  71   [dpkg database directory [LOCALSTATEDIR/lib/dpkg]])
  72 DPKG_WITH_DIR([backupsdir], [${localstatedir}/backups],
  73   [dpkg database backups directory [LOCALSTATEDIR/backups]])
  74 DPKG_WITH_DIR([logdir], [${localstatedir}/log],
  75   [system logging directory [LOCALSTATEDIR/log]])
  76 DPKG_WITH_DIR([pkgconfigdir], [${devlibdir}/pkgconfig],
  77   [pkg-config .pc fragments directory [DEVLIBDIR/pkgconfig]])
  78 DPKG_WITH_DIR([aclocaldir], [${datadir}/aclocal],
  79   [aclocal m4 fragments files directory [DATADIR/aclocal]])
  80 DPKG_WITH_DIR([polkitactionsdir], [${datadir}/polkit-1/actions],
  81   [polkit .policy actions directory [DATADIR/polkit-1/actions]])
  82 DPKG_WITH_DIR([bashcompletionsdir], [${datadir}/bash-completion/completions],
  83   [bash completions directory [DATADIR/bash-completion/completions]])
  84 DPKG_WITH_DIR([zshcompletionsdir], [${datadir}/zsh/vendor-completions],
  85   [zsh vendor completions directory [DATADIR/zsh/vendor-completions]])
  86
  87 # Set default dpkg-deb values
  88 DPKG_DEB_COMPRESSOR([xz])
  89
  90 # Checks for programs.
  91 DPKG_PROG_SHELL
  92 DPKG_PROG_PAGER
  93 AC_PROG_SED
  94 AC_PROG_GREP
  95 AC_PROG_EGREP
  96 AC_PROG_CC
  97 DPKG_C_STD([99])
  98 AC_PROG_CXX
  99 DPKG_CXX_STD([14])
 100 DPKG_PROG_PATCH
 101 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 102 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
 103 DPKG_PROG_TAR
 104 DPKG_PROG_PO4A
 105 DPKG_PROG_PERL
 106 DPKG_PROG_POD2MAN
 107 DPKG_CODE_COVERAGE
 108
 109 # Checks for operating system services and capabilities.
 110 AC_SYS_LARGEFILE
 111
 112 # Checks for libraries.
 113 DPKG_LIB_RT
 114 DPKG_LIB_MD
 115 DPKG_LIB_Z
 116 DPKG_LIB_BZ2
 117 DPKG_LIB_LZMA
 118 DPKG_LIB_ZSTD
 119 DPKG_LIB_SELINUX
 120 AS_IF([test "x$build_dselect" = "xyes"], [
 121   DPKG_LIB_CURSES
 122 ])
 123 AS_IF([test "x$build_start_stop_daemon" = "xyes"], [
 124   DPKG_LIB_SOCKET
 125   DPKG_LIB_PS
 126   DPKG_LIB_KVM
 127 ])
 128
 129 # Checks for header files.
 130 AC_CHECK_HEADERS([\
 131   error.h \
 132   err.h \
 133   locale.h \
 134   xlocale.h \
 135   libintl.h \
 136   kvm.h \
 137   sys/sysmacros.h \
 138   sys/param.h \
 139   sys/syscall.h \
 140   sys/user.h \
 141   sys/mkdev.h \
 142   sys/pstat.h \
 143   linux/fiemap.h \
 144 ])
 145 AS_CASE([$host_os],
 146   [linux-gnu*], [
 147     # The glibc project has deprecated the <sys/sysctl.h> header and emits
 148     # warnings on its usage, and removed it in 2.32. The Linux kernel removed
 149     # support for it in 5.5.
 150   ], [
 151     # On other systems, we need to check whether to use it.
 152     AC_CHECK_HEADERS([\
 153       sys/sysctl.h \
 154     ])
 155   ]
 156 )
 157 DPKG_CHECK_HEADER_SYS_PROCFS
 158 AC_CHECK_HEADERS([sys/proc.h], [], [], [
 159 #ifdef HAVE_SYS_PARAM_H
 160 #include <sys/param.h>
 161 #endif
 162 ])
 163
 164 AS_IF([test "x$build_dselect" = "xyes"], [
 165   AC_LANG_PUSH([C++])
 166   AC_CHECK_HEADERS([cxxabi.h])
 167   AC_LANG_POP([C++])
 168 ])
 169
 170 # Checks for typedefs, structures, and compiler characteristics.
 171 DPKG_ARCH_ABI
 172 AC_C_CONST
 173 AC_C_INLINE
 174 AC_C_VOLATILE
 175 AC_TYPE_MODE_T
 176 AC_TYPE_PID_T
 177 AC_TYPE_SIZE_T
 178 DPKG_TYPE_PTRDIFF_T
 179 DPKG_TYPE_STRUCT_PSINFO
 180 DPKG_DECL_SYS_SIGLIST
 181 DPKG_DECL_SYS_ERRLIST
 182
 183 # Checks for library functions.
 184 DPKG_FUNC_VA_COPY
 185 DPKG_FUNC_C99_SNPRINTF
 186 DPKG_FUNC_FSYNC_DIR
 187 DPKG_CHECK_DECL([offsetof], [stddef.h])
 188 DPKG_CHECK_DECL([makedev], [sys/types.h])
 189 DPKG_CHECK_DECL([WCOREDUMP], [sys/wait.h])
 190 DPKG_CHECK_DECL([TIOCNOTTY], [sys/ioctl.h])
 191 DPKG_CHECK_DECL([O_NOFOLLOW], [fcntl.h])
 192 DPKG_CHECK_DECL([F_ALLOCSP64], [fcntl.h])
 193 DPKG_CHECK_DECL([F_PREALLOCATE], [fcntl.h])
 194 DPKG_CHECK_DECL([P_tmpdir], [stdio.h])
 195 DPKG_CHECK_PROGNAME
 196 DPKG_CHECK_COMPAT_FUNCS([\
 197   getopt \
 198   getopt_long \
 199   obstack_free \
 200   strchrnul \
 201   strnlen \
 202   strndup \
 203   strerror \
 204   strsignal \
 205   asprintf \
 206   scandir \
 207   alphasort \
 208   unsetenv \
 209 ])
 210 AC_CHECK_FUNCS([\
 211   lchown \
 212 ], [], [AC_MSG_ERROR([missing required function])])
 213 AC_CHECK_FUNCS([\
 214   setsid \
 215   getdtablesize \
 216   closefrom \
 217   close_range \
 218   getprocs64 \
 219   getprogname \
 220   getexecname \
 221   lutimes \
 222   fallocate \
 223   posix_fallocate \
 224   posix_fadvise \
 225   uselocale \
 226 ])
 227
 228 AS_IF([test "x$build_dselect" = "xyes"], [
 229   AC_LANG_PUSH([C++])
 230   AC_CHECK_FUNCS([__cxa_pure_virtual])
 231   AC_LANG_POP([C++])
 232 ])
 233
 234 DPKG_USE_MMAP
 235 DPKG_USE_DISK_PREALLOCATE
 236
 237 # Checks for the build machinery.
 238 AC_DEFINE([LIBDPKG_VOLATILE_API], [1], [Acknowledge the volatility of the API.])
 239 DPKG_COMPILER_WARNINGS
 240 DPKG_COMPILER_SANITIZER
 241 DPKG_COMPILER_ANALYZER
 242 DPKG_COMPILER_OPTIMIZATIONS
 243 DPKG_LINKER_OPTIMIZATIONS
 244 DPKG_ARCHITECTURE
 245 AC_DEFINE([PACKAGE_RELEASE], [PACKAGE_VERSION " (" ARCHITECTURE ")"],
 246   [Define the project release information, version and architecture])
 247
 248 AC_CONFIG_TESTDIR([src/at])
 249 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 250
 251 AC_CONFIG_FILES([
 252   Makefile
 253   dselect/Makefile
 254   dselect/methods/Makefile
 255   dselect/po/Makefile.in
 256   lib/Makefile
 257   lib/compat/Makefile
 258   lib/dpkg/Makefile
 259   lib/dpkg/libdpkg.pc
 260   doc/Doxyfile
 261   man/Makefile
 262   po/Makefile.in
 263   scripts/Build.PL
 264   scripts/Makefile
 265   scripts/README.cpan
 266   scripts/mk/Makefile
 267   scripts/po/Makefile.in
 268   src/Makefile
 269   src/at/atlocal
 270   utils/Makefile
 271 ])
 272 AC_CONFIG_HEADERS([config.h])
 273 AC_OUTPUT
 274
 275 # Print the current configuration
 276 cat <<CONFIG
 277
 278 Release:
 279   Version . . . . . : $PACKAGE_VERSION
 280   VCS id  . . . . . : $PACKAGE_VCS_ID
 281
 282 Configuration:
 283   Arch attributes:
 284     cpu name  . . . . . . . . . . : ${cpu_type}
 285     os name . . . . . . . . . . . : ${os_type}
 286     arch name . . . . . . . . . . : ${dpkg_arch}
 287     arch bits . . . . . . . . . . : ${dpkg_arch_bits}
 288     arch endian . . . . . . . . . : ${dpkg_arch_endian}
 289     char bits . . . . . . . . . . : ${dpkg_char_bits}
 290     char sign . . . . . . . . . . : ${dpkg_char_sign}
 291     sizeof(short) . . . . . . . . : ${ac_cv_sizeof_short}
 292     sizeof(int) . . . . . . . . . : ${ac_cv_sizeof_int}
 293     sizeof(long)  . . . . . . . . : ${ac_cv_sizeof_long}
 294     sizeof(long long) . . . . . . : ${ac_cv_sizeof_long_long}
 295     sizeof(float) . . . . . . . . : ${ac_cv_sizeof_float}
 296     sizeof(double)  . . . . . . . : ${ac_cv_sizeof_double}
 297     sizeof(long double) . . . . . : ${ac_cv_sizeof_long_double}
 298     sizeof(void *)  . . . . . . . : ${ac_cv_sizeof_void_p}
 299     sizeof(off_t) . . . . . . . . : ${ac_cv_sizeof_off_t}
 300     sizeof(time_t)  . . . . . . . : ${ac_cv_sizeof_time_t}
 301     alignof(max_align_t)  . . . . : ${ac_cv_alignof_max_align_t}
 302
 303   Features:
 304     native language support . . . : $USE_NLS
 305     unicode support . . . . . . . : $USE_UNICODE
 306     development documentation . . : $build_devel_docs
 307     code coverage . . . . . . . . : $enable_coverage
 308     build shared libraries  . . . : $enable_shared
 309     mmap loaders  . . . . . . . . : $enable_mmap
 310     disk pre-allocation . . . . . : $enable_disk_preallocate
 311     default dpkg-deb compressor . : $with_deb_compressor
 312     default shell interpreter . . : $DPKG_SHELL
 313     default pager program . . . . : $DPKG_PAGER
 314
 315   Paths:
 316     devlibdir . . . . . . . . . . : $devlibdir
 317     pkgconfdir  . . . . . . . . . : $pkgconfdir
 318     docspecdir  . . . . . . . . . : $docspecdir
 319     methodsdir  . . . . . . . . . : $methodsdir
 320     admindir  . . . . . . . . . . : $admindir
 321     backupsdir  . . . . . . . . . : $backupsdir
 322     logdir  . . . . . . . . . . . : $logdir
 323     pkg-config dir  . . . . . . . : $pkgconfigdir
 324     aclocal dir   . . . . . . . . : $aclocaldir
 325     polkit actions dir  . . . . . : $polkitactionsdir
 326     bash completions dir  . . . . : $bashcompletionsdir
 327     zsh completions dir . . . . . : $zshcompletionsdir
 328     perl interpreter  . . . . . . : $PERL
 329     perl libdir . . . . . . . . . : $PERL_LIBDIR
 330
 331   Programs:
 332     update-alternatives . . . . . : $build_update_alternatives
 333     start-stop-daemon . . . . . . : $build_start_stop_daemon
 334     dselect . . . . . . . . . . . : $build_dselect
 335
 336   System Libraries:
 337     librt . . . . . . . . . . . . : $have_librt
 338     libsocket . . . . . . . . . . : ${have_libsocket:-no}
 339     libps . . . . . . . . . . . . : ${have_libps:-no}
 340     libkvm  . . . . . . . . . . . : ${have_libkvm:-no}
 341     libselinux  . . . . . . . . . : $have_libselinux
 342     libmd . . . . . . . . . . . . : $have_libmd
 343     libz  . . . . . . . . . . . . : $have_libz_impl
 344     liblzma . . . . . . . . . . . : $have_liblzma
 345     libzstd . . . . . . . . . . . : $have_libzstd
 346     libbz2  . . . . . . . . . . . : $have_libbz2
 347     libcurses . . . . . . . . . . : ${have_libcurses:-no}
 348 CONFIG