m4/types.m4

   1 # DPKG_TYPE_PTRDIFF_T
   2 # -------------------
   3 # Check for the ptrdiff_t type, defining to int if not defined
   4 AC_DEFUN([DPKG_TYPE_PTRDIFF_T],
   5 [AC_CHECK_TYPE([ptrdiff_t],,
   6         AC_DEFINE_UNQUOTED([ptrdiff_t], [int],
   7                            [Define to `int' if <malloc.h> does not define.]))dnl
   8 ])# DPKG_TYPE_PTRDIFF_T
   9
  10 # DPKG_DECL_SYS_SIGLIST
  11 # ---------------------
  12 # Check for the sys_siglist variable in either signal.h or unistd.h
  13 AC_DEFUN([DPKG_DECL_SYS_SIGLIST],
  14 [AC_CHECK_HEADERS([unistd.h])
  15 AC_CHECK_DECLS([sys_siglist],,,
  16 [#include <signal.h>
  17 /* NetBSD declares sys_siglist in unistd.h.  */
  18 #if HAVE_UNISTD_H
  19 #  include <unistd.h>
  20 #endif
  21 ])dnl
  22 ])# DPKG_DECL_SYS_SIGLIST
  23
  24 # DPKG_CHECK_DEFINE([DEFINE], [HEADER])
  25 # -------------------------------------
  26 # Defines HAVE_DEFINE to 1 if declared in HEADER, 0 otherwise
  27 AC_DEFUN([DPKG_CHECK_DEFINE],
  28 [AC_CACHE_CHECK([whether $1 is defined in $2], [dpkg_cv_define_$1],
  29 [AC_TRY_COMPILE(
  30 [#include <$2>
  31 ],
  32 [int i = $1;
  33 ],
  34         [dpkg_cv_define_$1=yes],
  35         [dpkg_cv_define_$1=no])])
  36 AS_IF([test "x$dpkg_cv_define" = "xyes"],
  37         [AC_DEFINE([HAVE_]$1, 1, [Define to 1 if you have the macro `]$1[' in
  38                                   `]$2[', and to 0 if you don't.])],
  39         [AC_DEFINE([HAVE_]$1, 0)])[]dnl
  40 ])# DPKG_CHECK_DEFINE