arch/powerpc/kernel/vdso/vdso32.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * This is the infamous ld script for the 32 bits vdso
   4  * library
   5  */
   6 #include <asm/vdso.h>
   7 #include <asm/page.h>
   8 #include <asm-generic/vmlinux.lds.h>
   9
  10 #ifdef __LITTLE_ENDIAN__
  11 OUTPUT_FORMAT("elf32-powerpcle", "elf32-powerpcle", "elf32-powerpcle")
  12 #else
  13 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
  14 #endif
  15 OUTPUT_ARCH(powerpc:common)
  16
  17 SECTIONS
  18 {
  19         PROVIDE(_vdso_datapage = . - 3 * PAGE_SIZE);
  20         . = SIZEOF_HEADERS;
  21
  22         .hash           : { *(.hash) }                  :text
  23         .gnu.hash       : { *(.gnu.hash) }
  24         .dynsym         : { *(.dynsym) }
  25         .dynstr         : { *(.dynstr) }
  26         .gnu.version    : { *(.gnu.version) }
  27         .gnu.version_d  : { *(.gnu.version_d) }
  28         .gnu.version_r  : { *(.gnu.version_r) }
  29
  30         .note           : { *(.note.*) }                :text   :note
  31
  32         . = ALIGN(16);
  33         .text           : {
  34                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  35         }                                               :text
  36         PROVIDE(__etext = .);
  37         PROVIDE(_etext = .);
  38         PROVIDE(etext = .);
  39
  40         . = ALIGN(8);
  41         VDSO_ftr_fixup_start = .;
  42         __ftr_fixup     : { *(__ftr_fixup) }
  43         VDSO_ftr_fixup_end = .;
  44
  45         . = ALIGN(8);
  46         VDSO_mmu_ftr_fixup_start = .;
  47         __mmu_ftr_fixup : { *(__mmu_ftr_fixup) }
  48         VDSO_mmu_ftr_fixup_end = .;
  49
  50         . = ALIGN(8);
  51         VDSO_lwsync_fixup_start = .;
  52         __lwsync_fixup  : { *(__lwsync_fixup) }
  53         VDSO_lwsync_fixup_end = .;
  54
  55 #ifdef CONFIG_PPC64
  56         . = ALIGN(8);
  57         VDSO_fw_ftr_fixup_start = .;
  58         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  59         VDSO_fw_ftr_fixup_end = .;
  60 #endif
  61
  62         /*
  63          * Other stuff is appended to the text segment:
  64          */
  65         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  66         .rodata1        : { *(.rodata1) }
  67
  68         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  69         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  70         .gcc_except_table : { *(.gcc_except_table) }
  71         .fixup          : { *(.fixup) }
  72
  73         .dynamic        : { *(.dynamic) }               :text   :dynamic
  74         .got            : { *(.got) }                   :text
  75         .plt            : { *(.plt) }
  76
  77         .rela.dyn       : { *(.rela .rela*) }
  78
  79         _end = .;
  80         __end = .;
  81         PROVIDE(end = .);
  82
  83         DWARF_DEBUG
  84         ELF_DETAILS
  85
  86         /DISCARD/       : {
  87                 *(.note.GNU-stack)
  88                 *(*.EMB.apuinfo)
  89                 *(.branch_lt)
  90                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
  91                 *(.bss .sbss .dynbss .dynsbss)
  92                 *(.got1 .glink .iplt)
  93         }
  94 }
  95
  96 /*
  97  * Very old versions of ld do not recognize this name token; use the constant.
  98  */
  99 #define PT_GNU_EH_FRAME 0x6474e550
 100
 101 /*
 102  * We must supply the ELF program headers explicitly to get just one
 103  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 104  */
 105 PHDRS
 106 {
 107         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 108         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 109         note            PT_NOTE FLAGS(4);               /* PF_R */
 110         eh_frame_hdr    PT_GNU_EH_FRAME;
 111 }
 112
 113 /*
 114  * This controls what symbols we export from the DSO.
 115  */
 116 VERSION
 117 {
 118         VDSO_VERSION_STRING {
 119         global:
 120                 __kernel_get_syscall_map;
 121                 __kernel_gettimeofday;
 122                 __kernel_clock_gettime;
 123                 __kernel_clock_gettime64;
 124                 __kernel_clock_getres;
 125                 __kernel_time;
 126                 __kernel_get_tbfreq;
 127                 __kernel_sync_dicache;
 128                 __kernel_sigtramp32;
 129                 __kernel_sigtramp_rt32;
 130 #if defined(CONFIG_PPC64) || !defined(CONFIG_SMP)
 131                 __kernel_getcpu;
 132 #endif
 133                 __kernel_getrandom;
 134
 135         local: *;
 136         };
 137 }
 138
 139 /*
 140  * Make the sigreturn code visible to the kernel.
 141  */
 142 VDSO_sigtramp32         = __kernel_sigtramp32;
 143 VDSO_sigtramp_rt32      = __kernel_sigtramp_rt32;