arch/riscv/kernel/vdso/vdso.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Copyright (C) 2012 Regents of the University of California
   4  */
   5 #include <asm/page.h>
   6 #include <asm/vdso.h>
   7
   8 OUTPUT_ARCH(riscv)
   9
  10 SECTIONS
  11 {
  12         PROVIDE(_vdso_data = . - __VVAR_PAGES * PAGE_SIZE);
  13 #ifdef CONFIG_TIME_NS
  14         PROVIDE(_timens_data = _vdso_data + PAGE_SIZE);
  15 #endif
  16         . = SIZEOF_HEADERS;
  17
  18         .hash           : { *(.hash) }                  :text
  19         .gnu.hash       : { *(.gnu.hash) }
  20         .dynsym         : { *(.dynsym) }
  21         .dynstr         : { *(.dynstr) }
  22         .gnu.version    : { *(.gnu.version) }
  23         .gnu.version_d  : { *(.gnu.version_d) }
  24         .gnu.version_r  : { *(.gnu.version_r) }
  25
  26         .dynamic        : { *(.dynamic) }               :text   :dynamic
  27
  28         .rodata         : {
  29                 *(.rodata .rodata.* .gnu.linkonce.r.*)
  30                 *(.got.plt) *(.got)
  31                 *(.data .data.* .gnu.linkonce.d.*)
  32                 *(.dynbss)
  33                 *(.bss .bss.* .gnu.linkonce.b.*)
  34         }
  35
  36         .note           : { *(.note.*) }                :text   :note
  37
  38         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  39         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  40
  41         /*
  42          * Text is well-separated from actual data: there's plenty of
  43          * stuff that isn't used at runtime in between.
  44          */
  45         . = ALIGN(16);
  46         .text           : { *(.text .text.*) }          :text
  47
  48         . = ALIGN(4);
  49         .alternative : {
  50                 *(.alternative)
  51         }
  52 }
  53
  54 /*
  55  * We must supply the ELF program headers explicitly to get just one
  56  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  57  */
  58 PHDRS
  59 {
  60         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  61         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  62         note            PT_NOTE         FLAGS(4);               /* PF_R */
  63         eh_frame_hdr    PT_GNU_EH_FRAME;
  64 }
  65
  66 /*
  67  * This controls what symbols we export from the DSO.
  68  */
  69 VERSION
  70 {
  71         LINUX_4.15 {
  72         global:
  73                 __vdso_rt_sigreturn;
  74 #ifdef HAS_VGETTIMEOFDAY
  75                 __vdso_gettimeofday;
  76                 __vdso_clock_gettime;
  77                 __vdso_clock_getres;
  78 #endif
  79                 __vdso_getcpu;
  80                 __vdso_flush_icache;
  81 #ifndef COMPAT_VDSO
  82                 __vdso_riscv_hwprobe;
  83 #endif
  84         local: *;
  85         };
  86 }