tools/testing/selftests/sgx/test_encl.lds

   1 OUTPUT_FORMAT(elf64-x86-64)
   2
   3 PHDRS
   4 {
   5         tcs PT_LOAD;
   6         text PT_LOAD;
   7         data PT_LOAD;
   8 }
   9
  10 SECTIONS
  11 {
  12         . = 0;
  13         __encl_base = .;
  14         .tcs : {
  15                 *(.tcs*)
  16         } : tcs
  17
  18         . = ALIGN(4096);
  19         .text : {
  20                 *(.text*)
  21                 *(.rodata*)
  22                 FILL(0xDEADBEEF);
  23                 . = ALIGN(4096);
  24         } : text
  25
  26         .data : {
  27                 *(.data.encl_buffer)
  28                 *(.data*)
  29         } : data
  30
  31         /DISCARD/ : {
  32                 *(.comment*)
  33                 *(.note*)
  34                 *(.debug*)
  35                 *(.eh_frame*)
  36                 *(.dyn*)
  37                 *(.gnu.hash)
  38         }
  39 }
  40
  41 ASSERT(!DEFINED(_GLOBAL_OFFSET_TABLE_), "Libcalls through GOT are not supported in enclaves")