meson.build

   1 project(
   2         'edid-decode',
   3         'cpp',
   4 )
   5
   6 edid_decode_args = [
   7         '-Wno-missing-field-initializers',
   8         '-Wno-unused-parameter',
   9         '-Wimplicit-fallthrough',
  10         '-Wno-variadic-macros',
  11 ]
  12 edid_decode_link_args = []
  13
  14 git = find_program('git', native: true, required: false)
  15 if git.found()
  16         git_commit = run_command(
  17                 [git, 'rev-parse', '--short=12', 'HEAD'],
  18                 check: false,
  19         )
  20         git_date = run_command(
  21                 [git, 'show', '--quiet', '--date=format-local:%F %T', '--format=%cd'],
  22                 env: {'TZ': 'UTC'},
  23                 check: false,
  24         )
  25
  26         if git_commit.returncode() == 0
  27                 edid_decode_args += ['-DSHA=' + git_commit.stdout().strip()]
  28         endif
  29         if git_date.returncode() == 0
  30                 edid_decode_args += ['-DDATE=' + git_date.stdout().strip()]
  31         endif
  32 endif
  33
  34 if target_machine.system() == 'emscripten'
  35         edid_decode_link_args += [
  36                 '-sEXPORTED_FUNCTIONS=_parse_edid',
  37                 '-sEXPORTED_RUNTIME_METHODS=ccall,cwrap'
  38         ]
  39
  40         fs = import('fs')
  41         foreach filename : ['edid-decode.html', 'edid-decode.ico']
  42                 fs.copyfile(
  43                         'emscripten' / filename,
  44                         install: true,
  45                         install_dir: 'bin',
  46                 )
  47         endforeach
  48 endif
  49
  50 edid_decode_sources = [
  51         'calc-gtf-cvt.cpp',
  52         'calc-ovt.cpp',
  53         'ddc.cpp',
  54         'edid-decode.cpp',
  55         'parse-base-block.cpp',
  56         'parse-cta-block.cpp',
  57         'parse-di-ext-block.cpp',
  58         'parse-displayid-block.cpp',
  59         'parse-ls-ext-block.cpp',
  60         'parse-vtb-ext-block.cpp',
  61         'parse-if.cpp',
  62 ]
  63
  64 edid_decode = executable(
  65         'edid-decode',
  66         sources: edid_decode_sources,
  67         cpp_args: edid_decode_args,
  68         link_args: edid_decode_link_args,
  69         install: true,
  70 )
  71
  72 meson.override_find_program(
  73         'edid-decode',
  74         edid_decode,
  75 )
  76
  77 install_man('edid-decode.1')