configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.13.GIT
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 test -f "$srcdir/$features" && . "$srcdir/$features"
  52 test -f "$builddir/$features" && . "$builddir/$features"
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_CHECK_TOOL([LD], [ld])
  61 AC_PROG_AWK
  62 AC_PATH_PROGS(AWK, "$AWK")
  63 AC_PROG_RANLIB
  64 AC_PROG_INSTALL
  65
  66 AC_PATH_PROGS(GIT, "git")
  67 AC_PATH_PROGS(SPARSE, "sparse")
  68
  69 CONFIG_ASCIIDOC="no"
  70 CONFIG_POD2HTML="no"
  71 CONFIG_XMLTO="no"
  72 CONFIG_JW="no"
  73
  74 if test "x$CONFIG_DOC" != xno; then
  75         AC_PATH_PROGS(PYTHON, "python")
  76         if test "x$PYTHON" != "x"; then
  77                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  78                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  79                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  80         fi
  81
  82         AC_PATH_PROGS(XMLTO, "xmlto")
  83         if test "x$XMLTO" != "x"; then
  84                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  85                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  86                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  87         fi
  88
  89         AC_PATH_PROGS(JW, "jw")
  90         if test "x$JW" != "x"; then
  91                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  92                 EL_CONFIG(MANUAL_JW, [PDF])
  93         fi
  94
  95         AC_PATH_PROGS(POD2HTML, "pod2html")
  96         if test "x$POD2HTML" != "x"; then
  97                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  98         fi
  99
 100         AC_PATH_PROGS(DOXYGEN, "doxygen")
 101         if test "x$DOXYGEN" != "x"; then
 102                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 103                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 104                 AC_SUBST(api_srcdir)
 105         fi
 106 fi
 107
 108 AC_SUBST(CONFIG_ASCIIDOC)
 109 AC_SUBST(CONFIG_DOXYGEN)
 110 AC_SUBST(CONFIG_POD2HTML)
 111 AC_SUBST(CONFIG_XMLTO)
 112 AC_SUBST(CONFIG_JW)
 113
 114 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 115 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 117 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 118
 119 # gcc specific options (to be continued at the bottom of configure)
 120 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 121   # We want to see all warnings and live with none.
 122   # We can't set up -Werror here as there may be some warnings in test
 123   # suite of configure, and we don't want to fail them.
 124   CFLAGS="$CFLAGS -Wall"
 125 fi
 126
 127 # ===================================================================
 128 # Checks for special OSes.
 129 # ===================================================================
 130
 131 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 132 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 133 [
 134         AC_MSG_CHECKING([for $2])
 135
 136         for flag in $3; do
 137                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 138 kill me!
 139 #endif ]])],[$1=yes],[$1=no])
 140                 if test "[$]$1" = yes; then
 141                         EL_CONFIG([$1], [$2])
 142                         break
 143                 fi
 144         done
 145
 146         AC_MSG_RESULT([$]$1)
 147 ])
 148
 149 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 150 AC_SUBST(CONFIG_OS_BEOS)
 151
 152 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 153 AC_SUBST(CONFIG_OS_RISCOS)
 154
 155 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 156 AC_SUBST(CONFIG_OS_WIN32)
 157
 158 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 159 AC_SUBST(CONFIG_OS_OS2)
 160 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 161
 162 AC_MSG_CHECKING([for UNIX])
 163 dnl FIXME: some depend kind of mechanism
 164 if test "$CONFIG_OS_BEOS" = no && \
 165    test "$CONFIG_OS_RISCOS" = no && \
 166    test "$CONFIG_OS_WIN32" = no && \
 167    test "$CONFIG_OS_OS2" = no; then
 168         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 169 else
 170         CONFIG_OS_UNIX=no
 171 fi
 172 AC_MSG_RESULT($CONFIG_OS_UNIX)
 173 AC_SUBST(CONFIG_OS_UNIX)
 174
 175 # ===================================================================
 176 # Checks for header files.
 177 # ===================================================================
 178
 179 AC_HEADER_DIRENT
 180 AC_HEADER_STDC
 181 AC_HEADER_SYS_WAIT
 182 AC_HEADER_TIME
 183
 184 AC_CHECK_HEADERS(wchar.h wctype.h)
 185 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 186 AC_CHECK_HEADERS(sigaction.h)
 187 AC_CHECK_HEADERS(arpa/inet.h)
 188 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 189 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 190 AC_CHECK_HEADERS(ifaddrs.h)
 191 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 192 AC_CHECK_HEADERS(sys/fmutex.h)
 193 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 194 AC_CHECK_HEADERS(sys/resource.h)
 195 AC_CHECK_HEADERS(sys/select.h)
 196 AC_CHECK_HEADERS(sys/signal.h)
 197 AC_CHECK_HEADERS(sys/socket.h)
 198 AC_CHECK_HEADERS(sys/time.h)
 199 AC_CHECK_HEADERS(sys/utsname.h)
 200 AC_CHECK_HEADERS([net/if.h], [], [],
 201 [[#ifdef HAVE_SYS_SOCKET_H
 202 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 203 #endif
 204 ]])
 205 AC_CHECK_HEADERS(stdint.h inttypes.h)
 206 AC_CHECK_HEADERS(locale.h pwd.h)
 207 AC_CHECK_HEADERS(termios.h)
 208
 209
 210 AC_CHECK_HEADERS(sys/un.h,
 211         [CONFIG_INTERLINK=yes
 212          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 213         [CONFIG_INTERLINK=no])
 214 AC_SUBST(CONFIG_INTERLINK)
 215
 216 # ===================================================================
 217 # Checks for typedefs, structures, and compiler characteristics.
 218 # ===================================================================
 219
 220 AC_STRUCT_TM
 221 AC_C_CONST
 222 AC_C_INLINE
 223 AC_MSG_CHECKING([[for C99-conforming inline]])
 224 AC_COMPILE_IFELSE([[
 225         int add(int change);
 226
 227         static int sum;
 228
 229         inline int
 230         add(int change)
 231         {
 232                 sum += change;
 233                 return sum;
 234         }
 235
 236         int
 237         sub(int change)
 238         {
 239                 return add(-change);
 240         }]],
 241         [AC_MSG_RESULT([[yes]])
 242          AC_DEFINE([NONSTATIC_INLINE], [inline],
 243                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 244         [AC_MSG_RESULT([[no]])
 245          AC_DEFINE([NONSTATIC_INLINE], [])])
 246 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 247
 248 AC_SYS_LARGEFILE
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_OFF_T
 251 EL_CHECK_TYPE(ssize_t, int)
 252 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 253 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 254 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 255 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 256 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 257
 258 AC_CHECK_SIZEOF(char, 1)
 259 AC_CHECK_SIZEOF(short, 2)
 260 AC_CHECK_SIZEOF(int, 4)
 261 AC_CHECK_SIZEOF(long, 4)
 262 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 263 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 264
 265 # Check for variadic macros
 266 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 267                 [#include <stdio.h>
 268                  #define a(b,c...) printf(b,##c)],
 269                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 270
 271 # ===================================================================
 272 # Checks for library functions.
 273 # ===================================================================
 274
 275 AC_PROG_GCC_TRADITIONAL
 276 AC_FUNC_MEMCMP
 277 AC_FUNC_MMAP
 278 AC_FUNC_STRFTIME
 279 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 280 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 281 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 282 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 283 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 284 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 285 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 286 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 287 AC_CHECK_FUNCS(setitimer, HAVE_SETITIMER=yes)
 288
 289 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(unsetenv)
 293 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 294 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 295
 296 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 297
 298 # These aren't probably needed now, as they are commented in links.h.
 299 # I've no idea about their historical background, but I keep them here
 300 # just in the case they will help later. --pasky
 301 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 302 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 303 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 304 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 305
 306 AC_CHECK_FUNCS(fpathconf, HAVE_FPATHCONF=yes)
 307
 308 if test x"$HAVE_RAISE" = x; then
 309         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 310                 AC_MSG_ERROR([Unable to emulate raise()])
 311         fi
 312 fi
 313
 314 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 315 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 316 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 317 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 318         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 319 fi
 320
 321 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 322 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 323 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 324 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 325         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 326 fi
 327
 328 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 330 #include <stdio.h>
 331 #include <stdarg.h>
 332 #include <stdlib.h>
 333 #include <string.h>
 334
 335 char buf[8];
 336
 337 int bar(char *buf, const char *format, va_list ap)
 338 {
 339        return vsnprintf(buf, 0, format, ap);
 340 }
 341
 342 void foo(const char *format, ...) {
 343        va_list ap;
 344        int len;
 345
 346        va_start(ap, format);
 347        len = bar(buf, format, ap);
 348        va_end(ap);
 349        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 350
 351        va_start(ap, format);
 352        len = bar(buf, format, ap);
 353        va_end(ap);
 354        if ((len != 6) && (len != 7)) exit(1);
 355
 356        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 357
 358        exit(0);
 359 }
 360 main() { foo("hello\n"); }
 361 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 362 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 363         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 364 fi
 365
 366 # OpenSSL and Lua frequently need dlopen
 367 AC_CHECK_LIB(dl, dlopen)
 368
 369 # ===================================================================
 370 # Checks for libraries.
 371 # ===================================================================
 372
 373 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 374 if test "$cf_result" = no; then
 375         AC_CHECK_LIB(socket, socket)
 376 fi
 377
 378 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 379 if test "$cf_result" = no; then
 380         AC_CHECK_LIB(socket, setsockopt)
 381 fi
 382
 383 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 384 if test "$cf_result" = no; then
 385         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 386         if test "$cf_result" = no; then
 387                 AC_CHECK_LIB(nsl, gethostbyname)
 388         else
 389                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 390         fi
 391 fi
 392
 393 # ===================================================================
 394 # Checks for packaging specific options.
 395 # ===================================================================
 396
 397 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 398             [ if test "$withval" != no && test "$withval" != yes; then
 399                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 400               fi ])
 401
 402 # ===================================================================
 403 # Checks for a libraries, optional even if installed.
 404 # ===================================================================
 405
 406 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 407 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 408 [
 409         AC_MSG_CHECKING([for $2 support])
 410
 411         if test "[$]$1" != no; then
 412                 AC_MSG_RESULT(yes)
 413                 EL_SAVE_FLAGS
 414                 if test -n "$withval" && test -d "$withval"; then
 415                         # Be a little more careful when setting
 416                         # include and lib directories. This way
 417                         # $withval will work when includes are
 418                         # there but the library is in the common
 419                         # /usr/lib ... Does the right thing when
 420                         # looking for gc on Debian.
 421                         if test -d "$withval/include"; then
 422                                 CFLAGS="$CFLAGS -I$withval/include"
 423                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 424                         else
 425                                 CFLAGS="$CFLAGS -I$withval"
 426                                 CPPFLAGS="$CPPFLAGS -I$withval"
 427                         fi
 428                         if test -d "$withval/lib"; then
 429                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 430                         fi
 431                 fi
 432
 433                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 434                 if test "[$]$1" = yes; then
 435                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 436                 fi
 437
 438                 if test "[$]$1" = yes; then
 439                         EL_CONFIG([$1], [$2])
 440                         LIBS="$LIBS -l$4"
 441                 else
 442                         if test -n "[$]WITHVAL_$1" &&
 443                            test "x[$]WITHVAL_$1" != xno; then
 444                                 AC_MSG_ERROR([$2 not found])
 445                         fi
 446                         EL_RESTORE_FLAGS
 447                 fi
 448         else
 449                 AC_MSG_RESULT(disabled)
 450         fi
 451 ])
 452
 453 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 454 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 455 [
 456         if test "x[$]$1" != xno; then $1=yes; fi
 457         WITHVAL_$1=
 458
 459         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 460         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 461         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 462
 463         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 464
 465         EL_LOG_CONFIG([$1], [$2], [])
 466 ])
 467
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 469         [  --without-gpm           disable gpm (mouse) support])
 470
 471 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 472 # enable automatic decoding of both zlib and gzip headers.  This
 473 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 474 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 475 # that, even though ELinks does not actually call gzclearerr.
 476 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 477         [  --without-zlib          disable zlib support])
 478
 479 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 480         [  --without-bzlib         disable bzlib support])
 481
 482 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 483         [  --without-idn           disable international domain names support])
 484
 485 if test "x${with_gc}" != xno; then
 486         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 487                 [  --with-gc               enable Boehm's garbage collector])
 488 fi
 489
 490 # LZMA disabled by default, because of little usability and compilation problems
 491 # with new xz
 492 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 493         [  --with-lzma             enable lzma encoding support])
 494
 495 # ===================================================================
 496 # Check for GSSAPI, optional even if installed.
 497 # ===================================================================
 498
 499 enable_gssapi="no";
 500
 501 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 502             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 503
 504 AC_MSG_CHECKING([for GSSAPI])
 505
 506 if test "$enable_gssapi" = "yes"; then
 507         AC_MSG_RESULT(yes)
 508         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 509         GSSAPI_LIBS=`krb5-config --libs gssapi`
 510         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 511         LIBS="$GSSAPI_LIBS $LIBS"
 512         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 513 else
 514         AC_MSG_RESULT(no)
 515 fi
 516
 517 AC_SUBST(CONFIG_GSSAPI)
 518
 519 # ===================================================================
 520 # Bookmark and XBEL support
 521 # ===================================================================
 522
 523 EL_SAVE_FLAGS
 524
 525 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 526               [  --disable-bookmarks     disable bookmark support])
 527
 528 # Check whether --enable-xbel or --disable-xbel was given.
 529 if test "x${enable_xbel}" != xno; then
 530         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 531
 532         if test "$HAVE_LIBEXPAT" = yes; then
 533                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 534                 if test "$HAVE_LIBEXPAT" = yes; then
 535                         LIBS="$LIBS -lexpat"
 536                 fi
 537         fi
 538 fi
 539
 540
 541 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 542               [XBEL bookmarks],
 543               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 544
 545 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 546         EL_RESTORE_FLAGS
 547 fi
 548
 549 # ===================================================================
 550 # Checks for BSD sysmouse
 551 # ===================================================================
 552
 553 HAVE_SYSMOUSE_HEADER="no"
 554
 555 # Either of these header files provides the (same) sysmouse interface
 556 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 557
 558 # ===================================================================
 559 # Checks for OS/2
 560 # ===================================================================
 561
 562 if test "$CONFIG_OS_OS2" = yes; then
 563         EL_CONFIG_OS_OS2
 564 fi
 565
 566 # ===================================================================
 567 # Checks for Win32
 568 # ===================================================================
 569
 570 if test "$CONFIG_OS_WIN32" = yes; then
 571         EL_CONFIG_OS_WIN32
 572 fi
 573
 574 # ===================================================================
 575 # Check for SpiderMonkey, optional even if installed.
 576 # ===================================================================
 577
 578 # This option sets the $with_spidermonkey variable.
 579 AC_ARG_WITH([spidermonkey],
 580         [AS_HELP_STRING([--without-spidermonkey],
 581                 [disable SpiderMonkey Mozilla JavaScript engine support])])
 582
 583 # CONFIG_SPIDERMONKEY is initially blank.  We change it to "yes" or "no"
 584 # when we know for sure whether we're going to use SpiderMonkey or not.
 585 # (features.conf is not supposed to define it.)
 586 CONFIG_SPIDERMONKEY=
 587 EL_SAVE_FLAGS
 588
 589 case "$with_spidermonkey" in
 590         no)
 591                 # The user specified --without-spidermonkey.
 592                 # That overrides the other SpiderMonkey options.
 593                 AC_MSG_CHECKING([for SpiderMonkey])
 594                 AC_MSG_RESULT([disabled])
 595                 CONFIG_SPIDERMONKEY="no"
 596                 ;;
 597         "" | yes)
 598                 ;;
 599         *)
 600                 AC_MSG_WARN([This version of ELinks does not support --with-spidermonkey=DIRECTORY.])
 601                 ;;
 602 esac
 603
 604 # The SpiderMonkey 1.8.5 standalone sources install mozjs185.pc,
 605 # but the Debian libmozjs-dev package installs mozilla-js.pc.
 606 # Check mozjs185 first, because it has the version number in the name
 607 # and therefore is less likely to be a newer incompatible version.
 608 # (This configure script rejects older incompatible versions
 609 # but can let newer ones through.)
 610 for package in mozjs185 mozilla-js; do
 611         if test -n "$CONFIG_SPIDERMONKEY"; then
 612                 break
 613         else
 614                 AC_MSG_CHECKING([for SpiderMonkey (1.8.5 or later) in pkg-config $package])
 615                 # In pkg-config 0.25, pkg-config --exists mozjs185
 616                 # returns 0 (success) even if mozjs185 depends on
 617                 # nspr, which has not been installed.  However,
 618                 # pkg-config --cflags mozjs185 returns 1 then.
 619                 if pkg-config --cflags --libs $package > /dev/null 2>&AS_MESSAGE_LOG_FD; then
 620                         SPIDERMONKEY_LIBS="$(pkg-config --libs $package)"
 621                         SPIDERMONKEY_CFLAGS="$(pkg-config --cflags $package)"
 622                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 623                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 624                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 625                         AC_LINK_IFELSE(
 626                                 [AC_LANG_PROGRAM([[
 627                                         /* mozilla-js.pc may have -DXP_UNIX or similar in Cflags.
 628                                          * Avoid warnings about conflicting definitions.  */
 629                                         #if !defined(XP_BEOS) && !defined(XP_OS2) && !defined(XP_UNIX) && !defined(XP_WIN)
 630                                         # define XP_UNIX 1
 631                                         #endif
 632                                         #include <jsapi.h>
 633                                         #ifndef JS_VERSION
 634                                         # error <jsapi.h> did not define JS_VERSION
 635                                         #elif JS_VERSION < 185
 636                                         # error too old
 637                                         #endif]], [])],
 638                                 [CONFIG_SPIDERMONKEY=yes
 639                                  AC_MSG_RESULT([yes])],
 640                                 [# Leave CONFIG_SPIDERMONKEY blank, to continue the search.
 641                                  AC_MSG_RESULT([found but unusable])])
 642                 else
 643                         AC_MSG_RESULT([no])
 644                 fi
 645         fi
 646 done
 647
 648 if test -z "$CONFIG_SPIDERMONKEY"; then
 649         # Didn't find SpiderMonkey anywhere.
 650         CONFIG_SPIDERMONKEY=no
 651 fi
 652
 653 if test "$CONFIG_SPIDERMONKEY" = "yes"; then
 654         # LIBS, CFLAGS, and CPPFLAGS still include the SpiderMonkey options.
 655         AC_CHECK_FUNCS([JS_ReportAllocationOverflow])
 656         AC_CHECK_FUNCS([JS_SetBranchCallback])
 657         AC_CHECK_FUNCS([JS_TriggerOperationCallback], [HAVE_JS_TRIGGEROPERATIONCALLBACK=yes])
 658 elif test -n "$with_spidermonkey" && test "x$with_spidermonkey" != "xno"; then
 659         AC_MSG_WARN([SpiderMonkey was not found even though you specified --with-spidermonkey.])
 660 fi
 661 EL_RESTORE_FLAGS
 662
 663 if test "x$CONFIG_SPIDERMONKEY" = xyes; then
 664         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 665 else
 666         CONFIG_ECMASCRIPT_SMJS=no
 667 fi
 668
 669 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 670 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 671
 672 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes &&
 673    test "x$HAVE_JS_TRIGGEROPERATIONCALLBACK" = xyes &&
 674    test "x$HAVE_SETITIMER" = xyes; then
 675         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT, [ECMAScript heartbeat support])
 676 else
 677         CONFIG_ECMASCRIPT_SMJS_HEARTBEAT=no
 678 fi
 679 AC_SUBST(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT)
 680
 681
 682 # ===================================================================
 683 # Optional Spidermonkey-based ECMAScript browser scripting
 684 # ===================================================================
 685
 686 AC_ARG_ENABLE(sm-scripting,
 687               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 688               [if test "$enableval" != no; then enableval="yes"; fi
 689                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 690
 691 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 692    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 693         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 694 else
 695         CONFIG_SCRIPTING_SPIDERMONKEY=no
 696 fi
 697
 698 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 699    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 700         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 701         AC_SUBST(SPIDERMONKEY_LIBS)
 702         AC_SUBST(SPIDERMONKEY_CFLAGS)
 703         AC_SUBST(CONFIG_SPIDERMONKEY)
 704 fi
 705
 706 # ===================================================================
 707 # Check for Guile, optional even if installed.
 708 # ===================================================================
 709
 710 enable_guile="no";
 711
 712 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 713             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 714
 715 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 716 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 717 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 718 # for Guile in $PATH etc. --pasky
 719
 720 AC_MSG_CHECKING([for Guile])
 721
 722 if test "$enable_guile" = "yes"; then
 723         AC_MSG_RESULT(yes);
 724         ## Based on the GUILE_FLAGS macro.
 725
 726         if test -d "$withval"; then
 727                 GUILE_PATH="$withval:$PATH"
 728         else
 729                 GUILE_PATH="$PATH"
 730         fi
 731
 732         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 733
 734         ## First, let's just see if we can find Guile at all.
 735         if test "$GUILE_CONFIG" != no; then
 736                 cf_result="yes";
 737
 738                 GUILE_LIBS="`guile-config link`"
 739                 GUILE_CFLAGS="`guile-config compile`"
 740                 LIBS="$GUILE_LIBS $LIBS"
 741                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 742                 AC_SUBST(GUILE_CFLAGS)
 743                 cat <<EOF
 744 ***********************************************************************
 745 The Guile support is incomplete and not so well integrated to ELinks
 746 yet. That means, e.g., that you have no Guile console and there might
 747 not be all the necessary hooks. Also, the Guile interface is not too
 748 well tested (success stories heartily welcomed!).  See
 749 src/scripting/guile/README for further details and hints.
 750 ***********************************************************************
 751 EOF
 752         else
 753                 if test -n "$withval" && test "x$withval" != xno; then
 754                         AC_MSG_ERROR([Guile not found])
 755                 else
 756                         AC_MSG_WARN([Guile support disabled])
 757                 fi
 758         fi
 759 else
 760         AC_MSG_RESULT(no);
 761 fi
 762
 763 # ===================================================================
 764 # Check for Perl
 765 # ===================================================================
 766 enable_perl="no";
 767
 768 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 769             [
 770 if test "$withval" = yes; then
 771         # FIXME: If withval is a valid directory append it to PATH
 772         # so that you can specify one of several perl installations.
 773         withval="";
 774         enable_perl=yes;
 775 fi
 776             ])
 777
 778 AC_MSG_CHECKING([for Perl])
 779
 780 cf_result=no
 781
 782 EL_SAVE_FLAGS
 783
 784 if test "$enable_perl" = "yes"; then
 785         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 786         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 787         LIBS="$PERL_LIBS $LIBS"
 788         CFLAGS="$PERL_CFLAGS $CFLAGS"
 789         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 790         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 791 #include <EXTERN.h>
 792 #include <perl.h>
 793 #include <perlapi.h>
 794 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 795 fi
 796
 797 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 798
 799 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 801 #include <EXTERN.h>
 802 #include <perl.h>
 803 extern PerlInterpreter *my_perl;
 804 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 805 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 806                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 807 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 808
 809 if test "$cf_result" != "yes"; then
 810         EL_RESTORE_FLAGS
 811 else
 812         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 813
 814         CFLAGS="$CFLAGS_X"
 815         CPPFLAGS="$CPPFLAGS_X"
 816         AC_SUBST(PERL_LIBS)
 817         AC_SUBST(PERL_CFLAGS)
 818 fi
 819
 820 # ===================================================================
 821 # Check for Python
 822 # ===================================================================
 823 enable_python="no";
 824
 825 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 826             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 827
 828 EL_SAVE_FLAGS
 829 cf_result=no
 830
 831 AC_MSG_CHECKING([for Python])
 832
 833 if test "$enable_python" = "yes"; then
 834         AC_MSG_RESULT(yes);
 835
 836         if test -d "$withval"; then
 837                 PYTHON_PATH="$withval:$PATH"
 838         else
 839                 PYTHON_PATH="$PATH"
 840         fi
 841
 842         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 843
 844         if test "$PYTHON" != no; then
 845                 cf_result="yes";
 846
 847                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 848                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 849                 LIBS="$PYTHON_LIBS $LIBS"
 850                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 851                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 852
 853                 if test "$cf_result" != "yes"; then
 854                         EL_RESTORE_FLAGS
 855                 else
 856                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 857                         AC_SUBST(PYTHON_LIBS)
 858                         AC_SUBST(PYTHON_CFLAGS)
 859                         CPPFLAGS="$CPPFLAGS_X"
 860                         cat <<EOF
 861 ***********************************************************************
 862 The Python support is incomplete and not so well integrated to ELinks
 863 yet. That means, e.g., that you have no Python console and there might
 864 not be all the necessary hooks. Also, the Python interface is not too
 865 well tested (success stories heartily welcomed!).
 866 ***********************************************************************
 867 EOF
 868                 fi
 869         else
 870                 if test -n "$withval" && test "x$withval" != xno; then
 871                         AC_MSG_ERROR([Python not found])
 872                 else
 873                         AC_MSG_WARN([Python support disabled])
 874                 fi
 875         fi
 876 else
 877         AC_MSG_RESULT(no);
 878 fi
 879
 880
 881 # ===================================================================
 882 # Check for Lua, optional even if installed.
 883 # ===================================================================
 884
 885 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 886 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 887
 888 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 889             [if test "$withval" = no; then disable_lua=yes; fi])
 890 AC_MSG_CHECKING([for Lua])
 891
 892 EL_SAVE_FLAGS
 893 cf_result=no
 894
 895 if test -z "$disable_lua"; then
 896         if test ! -d "$withval"; then
 897                 withval="";
 898         fi
 899         for luadir in "$withval" "" /usr /usr/local; do
 900                 for suffix in "" 5.1 51; do
 901                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 902                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 903                                 LUA_LIBS="-L$luadir/lib -llua$suffix -lm"
 904                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 905
 906                                 LIBS="$LUA_LIBS $LIBS_X"
 907                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 908                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 909
 910                                 # Check that it is a compatible Lua version
 911                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lauxlib.h>]
 912                                                 #include <lua.h>
 913                                                 #include <lualib.h>
 914                                                 ], [[   lua_State *L = luaL_newstate();
 915                                                 luaL_openlibs(L);
 916                                                 lua_pushboolean(L, 1);
 917                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 918                         fi
 919                 done
 920         done
 921 fi
 922
 923 AC_MSG_RESULT($cf_result)
 924
 925 if test "$cf_result" != yes; then
 926         EL_RESTORE_FLAGS
 927 else
 928         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 929         AC_CHECK_HEADERS(lauxlib.h)
 930
 931         CFLAGS="$CFLAGS_X"
 932         CPPFLAGS="$CPPFLAGS_X"
 933         AC_SUBST(LUA_LIBS)
 934         AC_SUBST(LUA_CFLAGS)
 935 fi
 936
 937 # ===================================================================
 938 # Check for TRE library
 939 # ===================================================================
 940 #
 941 # This section only checks that --without-tre is not given and the
 942 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 943 # tre_log.  It does not define CONFIG_TRE, and always resets
 944 # LIBS and CFLAGS back to their original values.
 945 #
 946 # After any --enable-utf-8 and --disable-utf-8 options have been
 947 # handled, a separate section decides whether to actually use TRE.
 948 #
 949 # tre version 0.8.0 or higher is required which have the "tre_" prefix
 950 # for functions.
 951
 952 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 953 if test "$with_tre" = no; then
 954         AC_MSG_CHECKING([[for TRE]])
 955         AC_MSG_RESULT([[disabled]])
 956         tre_log="no (explicitly disabled)"
 957 else
 958         AC_MSG_CHECKING([[for TRE in pkg-config]])
 959         if pkg-config tre; then
 960                 TRE_CFLAGS=`pkg-config --cflags tre`
 961                 TRE_LIBS=`pkg-config --libs tre`
 962                 AC_MSG_RESULT([[yes]])
 963         else
 964                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 965                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 966                 # so we look for the library even if pkg-config doesn't know about it.
 967                 TRE_CFLAGS=
 968                 TRE_LIBS=-ltre
 969                 AC_MSG_RESULT([[no, but let's try defaults]])
 970         fi
 971
 972         AC_MSG_CHECKING([[for TRE header and library]])
 973         EL_SAVE_FLAGS
 974         CFLAGS="$TRE_CFLAGS $CFLAGS"
 975         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
 976         AC_TRY_LINK([#include <tre/tre.h>],
 977                     [regex_t re;
 978                      regmatch_t match[1];
 979                      tre_regwcomp(&re, L"zap", REG_ICASE);
 980                      tre_regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 981                     [AC_MSG_RESULT([[yes]])
 982                      tre_log="available"],
 983                     [AC_MSG_RESULT([[no]])
 984                      tre_log="no (TRE not found)"])
 985         EL_RESTORE_FLAGS
 986 fi
 987
 988 # ===================================================================
 989 # Check for Ruby, optional even if installed.
 990 # ===================================================================
 991
 992 EL_CONFIG_SCRIPTING_RUBY
 993
 994 # ===================================================================
 995 # Setup global scripting
 996 # ===================================================================
 997
 998 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 999 AC_SUBST(CONFIG_SCRIPTING_GUILE)
1000 AC_SUBST(CONFIG_SCRIPTING_LUA)
1001 AC_SUBST(CONFIG_SCRIPTING_PERL)
1002 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
1003 AC_SUBST(CONFIG_SCRIPTING_RUBY)
1004 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
1005 AC_SUBST(CONFIG_SCRIPTING)
1006
1007
1008 # ===================================================================
1009 # Check for SSL support.
1010 # ===================================================================
1011
1012 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
1013 # is enabled, we won't try to use OpenSSL anymore.
1014
1015 # For wiping SSL hooks..
1016 #ifdef CONFIG_SSL
1017
1018 chosen_ssl_library=""
1019
1020 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1021 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1022             [case "$with_gnutls" in
1023                 "no")   : ;;
1024                 "yes")  chosen_ssl_library="GNUTLS" ;;
1025                 *)      chosen_ssl_library="GNUTLS"
1026                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1027 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1028              esac])
1029
1030 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1031 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1032             [case "$with_openssl" in
1033                 "no")   : ;;
1034                 *)      chosen_ssl_library="OpenSSL" ;;
1035              esac])
1036
1037 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
1038                           NSS compatibility SSL libraries/include files]],
1039             [case "$with_nss_compat_ossl" in
1040                 "no")   : ;;
1041                 *)      chosen_ssl_library="nss_compat_ossl" ;;
1042              esac])
1043
1044 # ---- nss_compat_ossl
1045
1046 if test "$with_nss_compat_ossl" = no; then
1047         # explicitly disabled
1048         :
1049 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "nss_compat_ossl"; then
1050         # not used, because $chosen_ssl_library was chosen
1051         :
1052 elif test -z "${with_nss_compat_ossl+set}"; then
1053         # SSL_library_init() in nss_compat_ossl 0.9.2 calls exit(1)
1054         # with no error message if there is no certificate database.
1055         # https://bugzilla.redhat.com/show_bug.cgi?id=463437
1056         # So ELinks uses nss_compat_ossl only if explicitly requested.
1057         :
1058 else
1059         EL_SAVE_FLAGS
1060         if test "$with_nss_compat_ossl" = yes; then
1061                 if pkg-config nss; then
1062                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
1063                         LIBS="$LIBS_X `pkg-config --libs nss`"
1064                 else
1065                         with_nss_compat_ossl=no
1066                 fi
1067         else
1068                 # Without pkg-config, we'll kludge in some defaults
1069                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
1070                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
1071         fi
1072         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
1073         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
1074
1075         if test "$with_nss_compat_ossl" = "no"; then
1076                 EL_RESTORE_FLAGS
1077         else
1078                 LIBS="$LIBS -lnss_compat_ossl"
1079                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
1080                 chosen_ssl_library="nss_compat_ossl"
1081         fi
1082 fi
1083
1084 # ---- OpenSSL
1085
1086 AC_MSG_CHECKING([for OpenSSL])
1087
1088 EL_SAVE_FLAGS
1089
1090 if test "$with_openssl" = no; then
1091         cf_result="explicitly disabled"
1092
1093 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1094         cf_result="not used, because $chosen_ssl_library was chosen"
1095
1096 else
1097         cf_result=no
1098         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1099                          /usr/lib/openssl /usr/local/ssl \
1100                          /usr/local/www /usr/lib/ssl /usr/local \
1101                          /usr/pkg /opt /opt/openssl; do
1102                 if test "$cf_result" = no; then
1103                         if test -d "$ssldir"; then
1104                                 OPENSSL_CFLAGS="-I$ssldir/include"
1105                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1106                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1107                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1108 #                               # FIXME: This created serious portability problems. --pasky
1109 #                               if test "$CC" == "gcc"; then
1110 #                                       # I'm not sure about compatibility here. --pasky
1111 #                                       LIBS="$LIBS -R$ssldir/lib"
1112 #                               fi
1113                         else
1114                                 LIBS="-lssl -lcrypto $LIBS_X"
1115                         fi
1116                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1117                         if test "$cf_result" != yes; then
1118                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1119                         fi
1120                 fi
1121         done
1122
1123         if test "$cf_result" != yes; then
1124                 if test "${with_openssl-no}" != "no"; then
1125                         AC_MSG_ERROR([OpenSSL not found])
1126                 fi
1127                 EL_RESTORE_FLAGS
1128         else
1129                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1130                 chosen_ssl_library="OpenSSL"
1131
1132                 CFLAGS="$CFLAGS_X"
1133                 AC_SUBST(OPENSSL_CFLAGS)
1134         fi
1135 fi
1136
1137 AC_MSG_RESULT($cf_result)
1138
1139 # ---- GNU TLS
1140
1141 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1142 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1143 # ELinks will use its internal MD5 code instead.
1144 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1145
1146 if test "$with_gnutls" = no; then
1147         AC_MSG_CHECKING([[for GNUTLS]])
1148         AC_MSG_RESULT([[explicitly disabled]])
1149
1150 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1151         AC_MSG_CHECKING([[for GNUTLS]])
1152         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1153
1154 else
1155         cf_result=no
1156         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1157         if pkg-config --atleast-version=1.2 gnutls; then
1158                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1159                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1160                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1161
1162                 EL_SAVE_FLAGS
1163                 LIBS="$GNUTLS_LIBS $LIBS"
1164                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1165                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1166
1167                 # Verify if it's really usable.  gnutls_session was
1168                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1169                 # (on 2004-06-13); ELinks now requires this.
1170                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1171                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1172                                                 [[gnutls_session_t dummy;
1173                                                   gnutls_check_version(NULL)]])],
1174                                [cf_result=yes],
1175                                [cf_result=no])
1176                 AC_MSG_RESULT([[$cf_result]])
1177
1178                 if test "$cf_result" = yes; then
1179                         # According to gnutls/NEWS, the function was originally
1180                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1181                         # (released 2007-10-27) and then renamed to
1182                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1183                         # 2007-11-29).
1184                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1185                 fi
1186
1187                 EL_RESTORE_FLAGS
1188         else
1189                 AC_MSG_RESULT([[$cf_result]])
1190         fi
1191
1192         if test "$cf_result" = yes; then
1193                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1194                 chosen_ssl_library="GNUTLS"
1195
1196                 # gcry_create_nounce is part of libgcrypt
1197                 LIBGCRYPT_CFLAGS=`libgcrypt-config --cflags`
1198                 LIBGCRYPT_LIBS=`libgcrypt-config --libs`
1199
1200                 LIBS="$LIBGCRYPT_LIBS $GNUTLS_LIBS $LIBS"
1201                 AC_SUBST(LIBGCRYPT_CFLAGS)
1202                 AC_SUBST(GNUTLS_CFLAGS)
1203
1204         elif test "${with_gnutls-no}" != "no"; then
1205                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1206         fi
1207 fi
1208
1209 # Final SSL setup
1210
1211 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1212 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1213 AC_SUBST(CONFIG_OPENSSL)
1214 AC_SUBST(CONFIG_GNUTLS)
1215 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1216
1217 #endif
1218
1219 AC_MSG_CHECKING([whether to be or not to be])
1220 AC_MSG_RESULT([needs to be determined experimentally])
1221
1222 # ===================================================================
1223 # Check for IPv6 support and related functions.
1224 # ===================================================================
1225
1226 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1227 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1228 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1229
1230 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1231 if test "$HAVE_GETADDRINFO" != yes; then
1232         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1233         if test "$HAVE_GETADDRINFO" = yes; then
1234                 LIBS="$LIBS -linet6"
1235         fi
1236 fi
1237
1238
1239 # ===================================================================
1240 # Checking for X11 (window title restoring).
1241 # ===================================================================
1242
1243 AC_PATH_X
1244 if test x"$no_x" != xyes; then
1245         EL_SAVE_FLAGS
1246         if test -n "$x_includes"; then
1247                 X_CFLAGS="-I$x_includes"
1248                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1249                 CFLAGS="$CFLAGS $X_CFLAGS"
1250         fi
1251         if test -n "$x_libraries"; then
1252                 LDFLAGS="$LDFLAGS -L$x_libraries"
1253         fi
1254         LIBS="-lX11 $LIBS"
1255         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1256         EL_RESTORE_FLAGS
1257         if test "$cf_result" = yes; then
1258                 if test -n "$x_libraries"; then
1259                         LDFLAGS="$LDFLAGS -L$x_libraries"
1260                 fi
1261                 LIBS="-lX11 $LIBS"
1262                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1263                 AC_SUBST(X_CFLAGS)
1264         fi
1265 fi
1266
1267
1268 # ===================================================================
1269 # Backtraces displaying support.
1270 # ===================================================================
1271
1272 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1273 # possible checks for other system-specific means go here
1274
1275
1276 # ===================================================================
1277 # Gettext grey zone. Beware.
1278 # ===================================================================
1279
1280 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1281
1282 AM_GNU_GETTEXT
1283
1284 # iconv is always used
1285 LIBS="$LIBS $LIBICONV"
1286
1287 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1288 dnl # f33r d4 l33t... I hope it's portable. :)
1289 dnl cf_result=$((48#z - 48#a + 1));
1290 dnl AC_MSG_RESULT($cf_result)
1291
1292
1293 # ===================================================================
1294 # Compile-time features control
1295 # ===================================================================
1296
1297 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1298               [  --disable-cookies       disable cookie support])
1299
1300 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1301               [  --disable-formhist      disable form history support])
1302
1303 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1304               [  --disable-globhist      disable global history support])
1305
1306
1307 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1308               [  --disable-mailcap       disable mailcap support])
1309
1310 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1311               [  --disable-mimetypes     disable mimetypes files support])
1312
1313
1314 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1315               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1316               [IPv6],
1317               [  --disable-ipv6          disable IPv6 support])
1318
1319 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1320               [  --enable-bittorrent     enable BitTorrent protocol support])
1321
1322 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1323               [  --disable-data          disable data protocol support])
1324
1325 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1326               [  --disable-uri-rewrite   disable URI rewrite support])
1327
1328 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1329               [  --enable-cgi            enable local CGI support])
1330
1331 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1332               [  --enable-finger         enable finger protocol support])
1333
1334 # ===================================================================
1335 # FSP protocol
1336 # ===================================================================
1337 EL_SAVE_FLAGS
1338
1339 if test "x${enable_fsp}" != xno; then
1340         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1341
1342         if test "$HAVE_FSPLIB" = yes; then
1343                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1344                 if test "$HAVE_FSPLIB" = yes; then
1345                         LIBS="$LIBS -lfsplib"
1346                 else
1347                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1348                         if test "$HAVE_FSPLIB" = yes; then
1349                                 LIBS="$LIBS -lfsp"
1350                         fi
1351                 fi
1352         fi
1353 fi
1354
1355 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1356               [  --enable-fsp            enable FSP protocol support])
1357
1358 if test "x$CONFIG_FSP" = xno; then
1359         EL_RESTORE_FLAGS
1360 fi
1361
1362 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1363               [  --disable-ftp           disable ftp protocol support])
1364
1365 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1366               [  --enable-gopher         enable gopher protocol support])
1367
1368 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1369               [  --enable-nntp           enable nntp protocol support])
1370
1371 # ===================================================================
1372 # SMB protocol support.
1373 # ===================================================================
1374 EL_SAVE_FLAGS
1375
1376 if test "x${enable_smb}" != xno; then
1377         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1378
1379         if test "$HAVE_SMBCLIENT" = yes; then
1380                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1381                 if test "$HAVE_SMBCLIENT" = yes; then
1382                         LIBS="$LIBS -lsmbclient"
1383                 fi
1384         fi
1385 fi
1386
1387 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1388               [  --enable-smb            enable Samba protocol support])
1389
1390 if test "x$CONFIG_SMB" = xno; then
1391         EL_RESTORE_FLAGS
1392 fi
1393
1394
1395 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1396               [  --disable-mouse         disable mouse support])
1397
1398 # GPM mouse is Linux specific, so ...
1399 CONFIG_SYSMOUSE=yes
1400 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1401               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1402               [BSD sysmouse],
1403               [  --disable-sysmouse      disable BSD sysmouse support])
1404
1405 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1406               [  --enable-88-colors      enable 88 color support])
1407
1408 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1409               [  --enable-256-colors     enable 256 color support])
1410
1411 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1412               [  --enable-true-color     enable true color support])
1413
1414 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1415               [  --enable-exmode         enable exmode (CLI) interface])
1416
1417 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1418               [  --disable-leds          disable LEDs support])
1419
1420 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1421               [  --disable-marks         disable document marks support])
1422
1423
1424 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1425               [  --disable-css           disable Cascading Style Sheet support])
1426
1427 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1428               [  --enable-html-highlight HTML highlighting using DOM engine])
1429
1430 # Everything in the tree already uses CONFIG_DOM
1431 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1432 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1433
1434 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1435               [  --disable-backtrace     disable backtrace support])
1436
1437 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1438               [  --enable-no-root        enable prevention of usage by root])
1439
1440
1441 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1442               [  --enable-debug          enable leak debug and internal error checking])
1443
1444 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1445               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1446
1447 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1448               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1449
1450 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1451               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1452
1453 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1454               [  --disable-utf-8         disable UTF-8 support])
1455
1456 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1457               [  --enable-combining      support Unicode combining characters (experimental)])
1458
1459
1460 AC_ARG_ENABLE(weehoofooboomookerchoo,
1461               [
1462     Also check out the features.conf file for more information about features!
1463               ],
1464               [AC_MSG_ERROR(Are you strange, or what?)])
1465
1466
1467 # ===================================================================
1468 # Decide whether to use TRE
1469 # ===================================================================
1470 #
1471 # This must be done after the CONFIG_UTF8 check above.
1472 # The first part of the TRE check is separate, to get
1473 # the configure --help output in a sensible order.
1474 #
1475 # After this section, nothing else must be added to the
1476 # beginning of $LIBS.
1477
1478 if test "$tre_log" = "available"; then
1479         if test "$CONFIG_UTF8" = "yes"; then
1480                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1481                 # src/viewer/text/search.c makes a string of
1482                 # unicode_val_T and gives it to regwexec(), which
1483                 # expects a string of wchar_t.  If the unicode_val_T
1484                 # and wchar_t types are too different, this won't
1485                 # work, so try to detect that and disable regexp
1486                 # operations entirely in that case.
1487                 #
1488                 # Currently, this code only compares the sizes of the
1489                 # types.  src/intl/charsets.h defines unicode_val_T as
1490                 # uint32_t, so we check whether wchar_t has exactly 32
1491                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1492                 # there doesn't seem to be a documented way to get the
1493                 # result of that for use in the configure script.
1494                 #
1495                 # C99 says the implementation can define
1496                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1497                 # (or Unicode) numbers in all locales.  Do not check
1498                 # that macro here, because it is too restrictive: it
1499                 # should be enough for ELinks if the values match in
1500                 # the locales where ELinks is actually run.
1501                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1502                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1503 #include <limits.h>
1504 #include <stddef.h>
1505 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1506                         [AC_MSG_RESULT([[yes]])
1507                          tre_log="TRE"],
1508                         [AC_MSG_RESULT([[no]])
1509                          tre_log="no (unsuitable wchar_t)"])
1510         else
1511                 # If UTF-8 is not used, then wchar_t doesn't matter.
1512                 tre_log="TRE"
1513         fi
1514 fi
1515
1516 if test "$tre_log" = "TRE"; then
1517         AC_DEFINE([CONFIG_TRE], [1],
1518                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1519         # TRE_CFLAGS will be used only where needed.
1520         #
1521         # Bug 1081: If both TRE and libc define the regfree function,
1522         # ELinks needs to use the version defined by TRE because
1523         # that's the one compatible with regex_t initialized by the
1524         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1525         # very beginning of $LIBS so that the linker hopefully finds
1526         # regfree there before it examines libc.  In particular,
1527         # $PERL_LIBS appears to often include "-lc".
1528         #
1529         # This scheme still risks a crash if ELinks is linked with
1530         # some static library that uses GNU <regex.h> extensions that
1531         # TRE does not implement.  For example, the library might call
1532         # re_compile_pattern, which is found in GNU libc, and then
1533         # regfree, which is found in TRE and probably crashes with the
1534         # GNU-initialized regex_t.  Ways to avoid such crashes:
1535         #
1536         # - Change TRE so it defines only tre_... functions and does
1537         #   not attempt to override the POSIX names by default.
1538         #
1539         # - Change ELinks to access TRE only via dlopen and dlsym.
1540         #   The problem then is how to find the correct file name.
1541         #   There might be libtre.so.4 and libtre.so.5 with different
1542         #   ABI.  How can this configure script detect which of them
1543         #   matches the <tre/regex.h> in the include path?
1544         #
1545         # - Replace the static library with a shared library.  At
1546         #   least on GNU/Linux, when the shared library is built, the
1547         #   linker should note that e.g. regfree is defined in libc
1548         #   and has the GLIBC_2.0 version there, and write that
1549         #   version string to the shared library as well; because TRE
1550         #   does not provide regfree with that version, any regfree
1551         #   calls at run time should then get resolved to libc.
1552         LIBS="$TRE_LIBS $LIBS"
1553 else
1554         TRE_LIBS=
1555         TRE_CFLAGS=
1556 fi
1557 AC_SUBST(TRE_CFLAGS)
1558 AC_SUBST(TRE_LIBS)
1559 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1560
1561
1562 # ===================================================================
1563 # Further LDFLAGS tweaks
1564 # ===================================================================
1565
1566 # == EMX hack
1567
1568 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1569 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1570
1571
1572 # Check for -rdynamic
1573 #
1574 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1575 # the executable to its dynamic symbol table.  ELinks uses this for
1576 # two purposes:
1577 #
1578 # 1. If ELinks detects a bug, it can try to display a backtrace by
1579 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1580 #    manual states users of GNU ld must pass -rdynamic to make the
1581 #    symbols available to the program.
1582 #
1583 # 2. It would eventually be nice to dynamically load shared
1584 #    libraries as plugins (bug 73).  The plugins must be able to
1585 #    call ELinks functions.  This can be implemented either by
1586 #    registering all callable functions in ELinks-specific data
1587 #    structures, or by letting the dynamic linker handle them.
1588 #    The latter way requires something equivalent to -rdynamic.
1589 #
1590 # Because backtraces are not needed for correct operation, and bug
1591 # 73 is not yet being fixed, the configure script and makefiles
1592 # should not complain to the user if they find that -rdynamic does
1593 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1594 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1595 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1596 # -rdynamic but does something equivalent automatically.  (This was
1597 # tested with "nm -D elinks | grep redraw_from_window".)
1598 #
1599 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1600 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1601 # linker from finding the libraries listed in -l operands.  So this
1602 # -rdynamic check needs to happen after the libraries have already
1603 # been added to $LDFLAGS.
1604 AC_MSG_CHECKING([for -rdynamic])
1605 LDFLAGS_X="$LDFLAGS"
1606 LDFLAGS="-rdynamic $LDFLAGS"
1607 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1608 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1609 AC_MSG_RESULT($have_rdynamic)
1610
1611 # ===================================================================
1612 # Export directory paths
1613 # ===================================================================
1614
1615 # Set up the ``entry points'' if they were not supplied by builder
1616 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1617 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1618
1619 # Create CONFDIR #define for config.h
1620
1621 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1622 # it's autoconf fault to force us to do such hacks ;p.
1623 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1624   # sysconfdir is set to its default value... fine, let's append /elinks/
1625   # XXX: We can't modify listing of the default in ./configure --help :-(
1626   sysconfdir_n=`eval echo "$sysconfdir"`
1627   sysconfdir=$sysconfdir_n
1628   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1629         sysconfdir="$sysconfdir/elinks"
1630 fi
1631
1632 CONFDIR=$sysconfdir
1633 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1634 AC_SUBST(CONFDIR)
1635
1636 # Create LOCALEDIR #define for config.h
1637 LOCALEDIR=`eval echo "$datadir/locale"`
1638 while echo "$LOCALEDIR" | grep "\\$"
1639 do
1640         LOCALEDIR=`eval echo "$LOCALEDIR"`
1641 done > /dev/null 2> /dev/null
1642 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1643 AC_SUBST(LOCALEDIR)
1644
1645 # Create LIBDIR #define for config.h
1646 LIBDIR=`eval echo "$libdir"`
1647 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1648 AC_SUBST(LIBDIR)
1649
1650 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1651 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1652
1653
1654 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1655 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1656         #error not tcc
1657         #endif ]])],[cf_result=yes],[cf_result=no])
1658
1659 if test "$cf_result" = "yes"; then
1660         AC_DEFINE([HAVE_ALLOCA])
1661         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1662                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1663                 override the alloca macro defined in <stddef.h> of TCC.
1664                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1665                 it has already been included, and does not redefine alloca.
1666                 This might not work in future glibc versions though, because
1667                 the names of the #include guard macros are not documented.
1668                 The incompatibility has been reported to the tinycc-devel
1669                 mailing list on 2008-07-14.  If a future version of TCC provides
1670                 an <alloca.h> of its own, this hack won't be needed.])
1671 fi
1672 # ===================================================================
1673 # A little fine tuning of gcc specific options (continued)
1674 # ===================================================================
1675
1676 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1677   if test "$CONFIG_DEBUG" = "yes"; then
1678     # We want to see all warnings and live with none (in debug mode).
1679     CFLAGS="$CFLAGS -Werror"
1680   fi
1681
1682   case "`$CC -dumpversion`" in
1683     3.0|3.1|3.2)
1684       # These should be ok using -Werror
1685       ;;
1686     3.*)
1687       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1688       # "dereferencing type-punned pointer will break strict-aliasing rules"
1689       # warnings. Disable them by not doing any strict-aliasing. The
1690       # alternative is just too ugly. Thanks gcc guys!! ;)
1691       CFLAGS="$CFLAGS -fno-strict-aliasing"
1692       ;;
1693     4.5*)
1694       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign -Wno-enum-compare"
1695       ;;
1696     4.*)
1697       # Do not show warnings related to (char * | unsigned char *) type
1698       # difference.
1699       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1700       ;;
1701     *)
1702       # These should be ok using -Werror
1703       ;;
1704   esac
1705
1706   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1707   # warning: the address of `builtin_modules' will always evaluate as `true'
1708   # This hits the object_lock and foreach_module macros in particular.
1709   # It would be okay to put something in the macros to avoid the warning,
1710   # but currently this seems to require defining parallel macros that skip
1711   # the NULL check, and that's too ugly.  So we instead disable the warning.
1712   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1713   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1714   for warning_flag in -Wno-address -Wno-always-true; do
1715     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1716     EL_SAVE_FLAGS
1717     CFLAGS="$CFLAGS $warning_flag"
1718     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1719       [AC_MSG_RESULT([yes])
1720        break],
1721       [AC_MSG_RESULT([no])])
1722     EL_RESTORE_FLAGS
1723   done
1724
1725   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1726   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1727   # "warning: assuming signed overflow does not occur when assuming
1728   # that (X + c) > X is always true", which may be an incorrect
1729   # optimization (although allowed by the standard), and breaks the
1730   # build with -Werror.
1731   #
1732   # All of the following tests included -S -Wall -Wextra:
1733   #
1734   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1735   # * gcc-4.0 -O0: OK, compares the values
1736   # * gcc-4.0 -O2: assumes no overflow, does not warn
1737   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1738   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1739   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1740   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1741   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1742   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1743   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1744   #
1745   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1746   # * gcc-4.1 -O0: assumes no overflow, does not warn
1747   # * gcc-4.1 -O2: assumes no overflow, does not warn
1748   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1749   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1750   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1751   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1752   # * gcc-4.1 -O2 -ftrapv: compares the values
1753   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1754   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1755   #
1756   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1757   # * gcc-4.2 -O0: OK, compares the values
1758   # * gcc-4.2 -O2: assumes no overflow, warns about it
1759   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1760   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1761   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1762   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1763   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1764   # * gcc-4.2 -O2 -ftrapv: compares the values
1765   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1766   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1767   #
1768   # Apparently, -ftrapv does not work reliably at all.
1769   for overflow_flag in -fno-strict-overflow -fwrapv; do
1770     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1771     EL_SAVE_FLAGS
1772     CFLAGS="$CFLAGS $overflow_flag"
1773     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1774       [AC_MSG_RESULT([yes])
1775        break],
1776       [AC_MSG_RESULT([no])])
1777     EL_RESTORE_FLAGS
1778   done
1779 fi
1780
1781 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1782 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1783 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1784 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1785
1786 # ===================================================================
1787 # Colored make output
1788 # ===================================================================
1789
1790 if test $(`which tput` colors) -ge 4; then
1791         MAKE_COLOR=1
1792         AC_SUBST(MAKE_COLOR)
1793 fi
1794
1795 # ===================================================================
1796 # Generated files
1797 # ===================================================================
1798
1799 AC_CONFIG_FILES([ \
1800  Makefile.config \
1801  contrib/elinks.spec \
1802  contrib/lua/hooks.lua \
1803  contrib/conv/w3m2links.awk \
1804  doc/Doxyfile \
1805  doc/man/man1/elinks.1 \
1806  src/intl/gettext/ref-add.sed \
1807  src/intl/gettext/ref-del.sed
1808 ])
1809 AC_OUTPUT
1810
1811 abs_srcdir="$(cd "$srcdir" && pwd)"
1812 # builddir is always absolute!
1813 if test "$abs_srcdir" != "$builddir"; then
1814         # Bootstrap the Makefile creation
1815         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1816         "$MAKE" "SRC=$abs_srcdir" init
1817
1818         # Make cg-status ignore this build directory
1819         echo "*" > "$builddir/.gitignore"
1820 fi
1821
1822 # ===================================================================
1823 # Configuration summary
1824 # ===================================================================
1825
1826 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1827 cat features.log