configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.13.GIT
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 test -f "$srcdir/$features" && . "$srcdir/$features"
  52 test -f "$builddir/$features" && . "$builddir/$features"
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_CHECK_TOOL([LD], [ld])
  61 AC_PROG_AWK
  62 AC_PATH_PROGS(AWK, "$AWK")
  63 AC_PROG_RANLIB
  64 AC_PROG_INSTALL
  65
  66 AC_PATH_PROGS(GIT, "git")
  67 AC_PATH_PROGS(SPARSE, "sparse")
  68
  69 CONFIG_ASCIIDOC="no"
  70 CONFIG_POD2HTML="no"
  71 CONFIG_XMLTO="no"
  72 CONFIG_JW="no"
  73
  74 if test "x$CONFIG_DOC" != xno; then
  75         AC_PATH_PROGS(PYTHON, "python")
  76         if test "x$PYTHON" != "x"; then
  77                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  78                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  79                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  80         fi
  81
  82         AC_PATH_PROGS(XMLTO, "xmlto")
  83         if test "x$XMLTO" != "x"; then
  84                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  85                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  86                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  87         fi
  88
  89         AC_PATH_PROGS(JW, "jw")
  90         if test "x$JW" != "x"; then
  91                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  92                 EL_CONFIG(MANUAL_JW, [PDF])
  93         fi
  94
  95         AC_PATH_PROGS(POD2HTML, "pod2html")
  96         if test "x$POD2HTML" != "x"; then
  97                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  98         fi
  99
 100         AC_PATH_PROGS(DOXYGEN, "doxygen")
 101         if test "x$DOXYGEN" != "x"; then
 102                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 103                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 104                 AC_SUBST(api_srcdir)
 105         fi
 106 fi
 107
 108 AC_SUBST(CONFIG_ASCIIDOC)
 109 AC_SUBST(CONFIG_DOXYGEN)
 110 AC_SUBST(CONFIG_POD2HTML)
 111 AC_SUBST(CONFIG_XMLTO)
 112 AC_SUBST(CONFIG_JW)
 113
 114 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 115 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 117 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 118
 119 # gcc specific options (to be continued at the bottom of configure)
 120 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 121   # We want to see all warnings and live with none.
 122   # We can't set up -Werror here as there may be some warnings in test
 123   # suite of configure, and we don't want to fail them.
 124   CFLAGS="$CFLAGS -Wall"
 125 fi
 126
 127 # ===================================================================
 128 # Checks for special OSes.
 129 # ===================================================================
 130
 131 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 132 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 133 [
 134         AC_MSG_CHECKING([for $2])
 135
 136         for flag in $3; do
 137                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 138 kill me!
 139 #endif ]])],[$1=yes],[$1=no])
 140                 if test "[$]$1" = yes; then
 141                         EL_CONFIG([$1], [$2])
 142                         break
 143                 fi
 144         done
 145
 146         AC_MSG_RESULT([$]$1)
 147 ])
 148
 149 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 150 AC_SUBST(CONFIG_OS_BEOS)
 151
 152 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 153 AC_SUBST(CONFIG_OS_RISCOS)
 154
 155 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 156 AC_SUBST(CONFIG_OS_WIN32)
 157
 158 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 159 AC_SUBST(CONFIG_OS_OS2)
 160 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 161
 162 AC_MSG_CHECKING([for UNIX])
 163 dnl FIXME: some depend kind of mechanism
 164 if test "$CONFIG_OS_BEOS" = no && \
 165    test "$CONFIG_OS_RISCOS" = no && \
 166    test "$CONFIG_OS_WIN32" = no && \
 167    test "$CONFIG_OS_OS2" = no; then
 168         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 169 else
 170         CONFIG_OS_UNIX=no
 171 fi
 172 AC_MSG_RESULT($CONFIG_OS_UNIX)
 173 AC_SUBST(CONFIG_OS_UNIX)
 174
 175 # ===================================================================
 176 # Checks for header files.
 177 # ===================================================================
 178
 179 AC_HEADER_DIRENT
 180 AC_HEADER_STDC
 181 AC_HEADER_SYS_WAIT
 182 AC_HEADER_TIME
 183
 184 AC_CHECK_HEADERS(wchar.h wctype.h)
 185 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 186 AC_CHECK_HEADERS(sigaction.h)
 187 AC_CHECK_HEADERS(arpa/inet.h)
 188 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 189 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 190 AC_CHECK_HEADERS(ifaddrs.h)
 191 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 192 AC_CHECK_HEADERS(sys/fmutex.h)
 193 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 194 AC_CHECK_HEADERS(sys/resource.h)
 195 AC_CHECK_HEADERS(sys/select.h)
 196 AC_CHECK_HEADERS(sys/signal.h)
 197 AC_CHECK_HEADERS(sys/socket.h)
 198 AC_CHECK_HEADERS(sys/time.h)
 199 AC_CHECK_HEADERS(sys/utsname.h)
 200 AC_CHECK_HEADERS([net/if.h], [], [],
 201 [[#ifdef HAVE_SYS_SOCKET_H
 202 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 203 #endif
 204 ]])
 205 AC_CHECK_HEADERS(stdint.h inttypes.h)
 206 AC_CHECK_HEADERS(locale.h pwd.h)
 207 AC_CHECK_HEADERS(termios.h)
 208
 209
 210 AC_CHECK_HEADERS(sys/un.h,
 211         [CONFIG_INTERLINK=yes
 212          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 213         [CONFIG_INTERLINK=no])
 214 AC_SUBST(CONFIG_INTERLINK)
 215
 216 # ===================================================================
 217 # Checks for typedefs, structures, and compiler characteristics.
 218 # ===================================================================
 219
 220 AC_STRUCT_TM
 221 AC_C_CONST
 222 AC_C_INLINE
 223 AC_MSG_CHECKING([[for C99-conforming inline]])
 224 AC_COMPILE_IFELSE([[
 225         int add(int change);
 226
 227         static int sum;
 228
 229         inline int
 230         add(int change)
 231         {
 232                 sum += change;
 233                 return sum;
 234         }
 235
 236         int
 237         sub(int change)
 238         {
 239                 return add(-change);
 240         }]],
 241         [AC_MSG_RESULT([[yes]])
 242          AC_DEFINE([NONSTATIC_INLINE], [inline],
 243                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 244         [AC_MSG_RESULT([[no]])
 245          AC_DEFINE([NONSTATIC_INLINE], [])])
 246 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 247
 248 AC_SYS_LARGEFILE
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_OFF_T
 251 EL_CHECK_TYPE(ssize_t, int)
 252 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 253 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 254 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 255 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 256 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 257
 258 AC_CHECK_SIZEOF(char, 1)
 259 AC_CHECK_SIZEOF(short, 2)
 260 AC_CHECK_SIZEOF(int, 4)
 261 AC_CHECK_SIZEOF(long, 4)
 262 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 263 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 264
 265 # Check for variadic macros
 266 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 267                 [#include <stdio.h>
 268                  #define a(b,c...) printf(b,##c)],
 269                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 270
 271 # ===================================================================
 272 # Checks for library functions.
 273 # ===================================================================
 274
 275 AC_PROG_GCC_TRADITIONAL
 276 AC_FUNC_MEMCMP
 277 AC_FUNC_MMAP
 278 AC_FUNC_STRFTIME
 279 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 280 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 281 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 282 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 283 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 284 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 285 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 286 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 287 AC_CHECK_FUNCS(setitimer, HAVE_SETITIMER=yes)
 288
 289 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(unsetenv)
 293 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 294 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 295
 296 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 297
 298 # These aren't probably needed now, as they are commented in links.h.
 299 # I've no idea about their historical background, but I keep them here
 300 # just in the case they will help later. --pasky
 301 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 302 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 303 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 304 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 305
 306 AC_CHECK_FUNCS(fpathconf, HAVE_FPATHCONF=yes)
 307
 308 if test x"$HAVE_RAISE" = x; then
 309         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 310                 AC_MSG_ERROR([Unable to emulate raise()])
 311         fi
 312 fi
 313
 314 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 315 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 316 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 317 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 318         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 319 fi
 320
 321 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 322 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 323 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 324 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 325         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 326 fi
 327
 328 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 330 #include <stdio.h>
 331 #include <stdarg.h>
 332 #include <stdlib.h>
 333 #include <string.h>
 334
 335 char buf[8];
 336
 337 int bar(char *buf, const char *format, va_list ap)
 338 {
 339        return vsnprintf(buf, 0, format, ap);
 340 }
 341
 342 void foo(const char *format, ...) {
 343        va_list ap;
 344        int len;
 345
 346        va_start(ap, format);
 347        len = bar(buf, format, ap);
 348        va_end(ap);
 349        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 350
 351        va_start(ap, format);
 352        len = bar(buf, format, ap);
 353        va_end(ap);
 354        if ((len != 6) && (len != 7)) exit(1);
 355
 356        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 357
 358        exit(0);
 359 }
 360 main() { foo("hello\n"); }
 361 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 362 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 363         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 364 fi
 365
 366 # OpenSSL and Lua frequently need dlopen
 367 AC_CHECK_LIB(dl, dlopen)
 368
 369 # ===================================================================
 370 # Checks for libraries.
 371 # ===================================================================
 372
 373 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 374 if test "$cf_result" = no; then
 375         AC_CHECK_LIB(socket, socket)
 376 fi
 377
 378 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 379 if test "$cf_result" = no; then
 380         AC_CHECK_LIB(socket, setsockopt)
 381 fi
 382
 383 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 384 if test "$cf_result" = no; then
 385         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 386         if test "$cf_result" = no; then
 387                 AC_CHECK_LIB(nsl, gethostbyname)
 388         else
 389                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 390         fi
 391 fi
 392
 393 # ===================================================================
 394 # Checks for packaging specific options.
 395 # ===================================================================
 396
 397 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 398             [ if test "$withval" != no && test "$withval" != yes; then
 399                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 400               fi ])
 401
 402 # ===================================================================
 403 # Checks for a libraries, optional even if installed.
 404 # ===================================================================
 405
 406 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 407 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 408 [
 409         AC_MSG_CHECKING([for $2 support])
 410
 411         if test "[$]$1" != no; then
 412                 AC_MSG_RESULT(yes)
 413                 EL_SAVE_FLAGS
 414                 if test -n "$withval" && test -d "$withval"; then
 415                         # Be a little more careful when setting
 416                         # include and lib directories. This way
 417                         # $withval will work when includes are
 418                         # there but the library is in the common
 419                         # /usr/lib ... Does the right thing when
 420                         # looking for gc on Debian.
 421                         if test -d "$withval/include"; then
 422                                 CFLAGS="$CFLAGS -I$withval/include"
 423                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 424                         else
 425                                 CFLAGS="$CFLAGS -I$withval"
 426                                 CPPFLAGS="$CPPFLAGS -I$withval"
 427                         fi
 428                         if test -d "$withval/lib"; then
 429                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 430                         fi
 431                 fi
 432
 433                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 434                 if test "[$]$1" = yes; then
 435                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 436                 fi
 437
 438                 if test "[$]$1" = yes; then
 439                         EL_CONFIG([$1], [$2])
 440                         LIBS="$LIBS -l$4"
 441                 else
 442                         if test -n "[$]WITHVAL_$1" &&
 443                            test "x[$]WITHVAL_$1" != xno; then
 444                                 AC_MSG_ERROR([$2 not found])
 445                         fi
 446                         EL_RESTORE_FLAGS
 447                 fi
 448         else
 449                 AC_MSG_RESULT(disabled)
 450         fi
 451 ])
 452
 453 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 454 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 455 [
 456         if test "x[$]$1" != xno; then $1=yes; fi
 457         WITHVAL_$1=
 458
 459         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 460         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 461         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 462
 463         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 464
 465         EL_LOG_CONFIG([$1], [$2], [])
 466 ])
 467
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 469         [  --without-gpm           disable gpm (mouse) support])
 470
 471 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 472 # enable automatic decoding of both zlib and gzip headers.  This
 473 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 474 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 475 # that, even though ELinks does not actually call gzclearerr.
 476 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 477         [  --without-zlib          disable zlib support])
 478
 479 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 480         [  --without-bzlib         disable bzlib support])
 481
 482 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 483         [  --without-idn           disable international domain names support])
 484
 485 if test "x${with_gc}" != xno; then
 486         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 487                 [  --with-gc               enable Boehm's garbage collector])
 488 fi
 489
 490 # LZMA disabled by default, because of little usability and compilation problems
 491 # with new xz
 492 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 493         [  --with-lzma             enable lzma encoding support])
 494
 495 # ===================================================================
 496 # Check for GSSAPI, optional even if installed.
 497 # ===================================================================
 498
 499 enable_gssapi="no";
 500
 501 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 502             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 503
 504 AC_MSG_CHECKING([for GSSAPI])
 505
 506 if test "$enable_gssapi" = "yes"; then
 507         AC_MSG_RESULT(yes)
 508         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 509         GSSAPI_LIBS=`krb5-config --libs gssapi`
 510         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 511         LIBS="$GSSAPI_LIBS $LIBS"
 512         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 513 else
 514         AC_MSG_RESULT(no)
 515 fi
 516
 517 AC_SUBST(CONFIG_GSSAPI)
 518
 519 # ===================================================================
 520 # Bookmark and XBEL support
 521 # ===================================================================
 522
 523 EL_SAVE_FLAGS
 524
 525 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 526               [  --disable-bookmarks     disable bookmark support])
 527
 528 # Check whether --enable-xbel or --disable-xbel was given.
 529 if test "x${enable_xbel}" != xno; then
 530         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 531
 532         if test "$HAVE_LIBEXPAT" = yes; then
 533                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 534                 if test "$HAVE_LIBEXPAT" = yes; then
 535                         LIBS="$LIBS -lexpat"
 536                 fi
 537         fi
 538 fi
 539
 540
 541 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 542               [XBEL bookmarks],
 543               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 544
 545 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 546         EL_RESTORE_FLAGS
 547 fi
 548
 549 # ===================================================================
 550 # Checks for BSD sysmouse
 551 # ===================================================================
 552
 553 HAVE_SYSMOUSE_HEADER="no"
 554
 555 # Either of these header files provides the (same) sysmouse interface
 556 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 557
 558 # ===================================================================
 559 # Checks for OS/2
 560 # ===================================================================
 561
 562 if test "$CONFIG_OS_OS2" = yes; then
 563         EL_CONFIG_OS_OS2
 564 fi
 565
 566 # ===================================================================
 567 # Checks for Win32
 568 # ===================================================================
 569
 570 if test "$CONFIG_OS_WIN32" = yes; then
 571         EL_CONFIG_OS_WIN32
 572 fi
 573
 574 # ===================================================================
 575 # Check for SEE (Simple Ecmascript Engine)
 576 # ===================================================================
 577 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 578             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 579
 580 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 581 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 582 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 583 # for Guile in $PATH etc. --pasky
 584
 585 CONFIG_ECMASCRIPT_SEE=no
 586
 587 if test "$enable_see" = "yes"; then
 588         if test -d "$withval"; then
 589                 SEE_PATH="$withval:$PATH"
 590         else
 591                 SEE_PATH="$PATH"
 592         fi
 593
 594         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 595         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 596         if test "$SEE_CONFIG" != no; then
 597                 EL_SAVE_FLAGS
 598                 SEE_LIBS="`$SEE_CONFIG --libs`"
 599                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 600                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 601                 LIBS="$SEE_LIBS $LIBS_X"
 602                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 603                         #error SEE too old
 604                         #endif
 605                 ]])],[cf_result=yes],[cf_result=no])
 606                 EL_RESTORE_FLAGS
 607                 if test "$cf_result" = yes; then
 608                         LIBS="$SEE_LIBS $LIBS"
 609                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 610                         AC_SUBST(SEE_CFLAGS)
 611                 fi
 612                 AC_MSG_RESULT($cf_result)
 613         else
 614                 if test -n "$withval" && test "x$withval" != xno; then
 615                         AC_MSG_ERROR([SEE not found])
 616                 else
 617                         AC_MSG_WARN([SEE support disabled])
 618                 fi
 619         fi
 620 fi
 621
 622 # ===================================================================
 623 # Check for SpiderMonkey, optional even if installed.
 624 # ===================================================================
 625
 626 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 627             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 628
 629 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 630
 631 EL_SAVE_FLAGS
 632 cf_result=no
 633
 634 if test -z "$disable_spidermonkey"; then
 635         if test ! -d "$withval"; then
 636                 withval="";
 637         fi
 638         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 639                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 640                         for spidermonkeylib in js smjs mozjs; do
 641                                 if test "$cf_result" = no; then
 642                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 643                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 644
 645                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 646                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 647                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 648
 649                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 650                                                 #define XP_UNIX
 651                                                 #include <jsapi.h>]], [[
 652                                                 #ifndef JS_VERSION
 653                                                 #error JS_VERSION
 654                                                 #endif
 655                                                 #if JS_VERSION < 185
 656                                                 #error too old
 657                                                 #endif]])],
 658                                                 [cf_result=yes],[cf_result=no])
 659                                 fi
 660                         done
 661                 done
 662         done
 663 fi
 664
 665 AC_MSG_RESULT($cf_result)
 666 CONFIG_SPIDERMONKEY="$cf_result"
 667 if test "$cf_result" = "yes"; then
 668         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 669         AC_CHECK_FUNCS(JS_SetBranchCallback)
 670         AC_CHECK_FUNCS(JS_TriggerOperationCallback, HAVE_JS_TRIGGEROPERATIONCALLBACK=yes)
 671 fi
 672 EL_RESTORE_FLAGS
 673
 674 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 675    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 676         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 677 else
 678         CONFIG_ECMASCRIPT_SMJS=no
 679 fi
 680
 681 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 682 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 683 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 684
 685 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes &&
 686    test "x$HAVE_JS_TRIGGEROPERATIONCALLBACK" = xyes &&
 687    test "x$HAVE_SETITIMER" = xyes; then
 688         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT, [ECMAScript heartbeat support])
 689 else
 690         CONFIG_ECMASCRIPT_SMJS_HEARTBEAT=no
 691 fi
 692 AC_SUBST(CONFIG_ECMASCRIPT_SMJS_HEARTBEAT)
 693
 694
 695 # ===================================================================
 696 # Optional Spidermonkey-based ECMAScript browser scripting
 697 # ===================================================================
 698
 699 AC_ARG_ENABLE(sm-scripting,
 700               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 701               [if test "$enableval" != no; then enableval="yes"; fi
 702                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 703
 704 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 705    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 706         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 707 else
 708         CONFIG_SCRIPTING_SPIDERMONKEY=no
 709 fi
 710
 711 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 712    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 713         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 714         AC_SUBST(SPIDERMONKEY_LIBS)
 715         AC_SUBST(SPIDERMONKEY_CFLAGS)
 716         AC_SUBST(CONFIG_SPIDERMONKEY)
 717 fi
 718
 719 # ===================================================================
 720 # Check for Guile, optional even if installed.
 721 # ===================================================================
 722
 723 enable_guile="no";
 724
 725 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 726             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 727
 728 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 729 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 730 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 731 # for Guile in $PATH etc. --pasky
 732
 733 AC_MSG_CHECKING([for Guile])
 734
 735 if test "$enable_guile" = "yes"; then
 736         AC_MSG_RESULT(yes);
 737         ## Based on the GUILE_FLAGS macro.
 738
 739         if test -d "$withval"; then
 740                 GUILE_PATH="$withval:$PATH"
 741         else
 742                 GUILE_PATH="$PATH"
 743         fi
 744
 745         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 746
 747         ## First, let's just see if we can find Guile at all.
 748         if test "$GUILE_CONFIG" != no; then
 749                 cf_result="yes";
 750
 751                 GUILE_LIBS="`guile-config link`"
 752                 GUILE_CFLAGS="`guile-config compile`"
 753                 LIBS="$GUILE_LIBS $LIBS"
 754                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 755                 AC_SUBST(GUILE_CFLAGS)
 756                 cat <<EOF
 757 ***********************************************************************
 758 The Guile support is incomplete and not so well integrated to ELinks
 759 yet. That means, e.g., that you have no Guile console and there might
 760 not be all the necessary hooks. Also, the Guile interface is not too
 761 well tested (success stories heartily welcomed!).  See
 762 src/scripting/guile/README for further details and hints.
 763 ***********************************************************************
 764 EOF
 765         else
 766                 if test -n "$withval" && test "x$withval" != xno; then
 767                         AC_MSG_ERROR([Guile not found])
 768                 else
 769                         AC_MSG_WARN([Guile support disabled])
 770                 fi
 771         fi
 772 else
 773         AC_MSG_RESULT(no);
 774 fi
 775
 776 # ===================================================================
 777 # Check for Perl
 778 # ===================================================================
 779 enable_perl="no";
 780
 781 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 782             [
 783 if test "$withval" = yes; then
 784         # FIXME: If withval is a valid directory append it to PATH
 785         # so that you can specify one of several perl installations.
 786         withval="";
 787         enable_perl=yes;
 788 fi
 789             ])
 790
 791 AC_MSG_CHECKING([for Perl])
 792
 793 cf_result=no
 794
 795 EL_SAVE_FLAGS
 796
 797 if test "$enable_perl" = "yes"; then
 798         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 799         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 800         LIBS="$PERL_LIBS $LIBS"
 801         CFLAGS="$PERL_CFLAGS $CFLAGS"
 802         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 803         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 804 #include <EXTERN.h>
 805 #include <perl.h>
 806 #include <perlapi.h>
 807 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 808 fi
 809
 810 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 811
 812 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 813 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 814 #include <EXTERN.h>
 815 #include <perl.h>
 816 extern PerlInterpreter *my_perl;
 817 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 818 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 819                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 820 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 821
 822 if test "$cf_result" != "yes"; then
 823         EL_RESTORE_FLAGS
 824 else
 825         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 826
 827         CFLAGS="$CFLAGS_X"
 828         CPPFLAGS="$CPPFLAGS_X"
 829         AC_SUBST(PERL_LIBS)
 830         AC_SUBST(PERL_CFLAGS)
 831 fi
 832
 833 # ===================================================================
 834 # Check for Python
 835 # ===================================================================
 836 enable_python="no";
 837
 838 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 839             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 840
 841 EL_SAVE_FLAGS
 842 cf_result=no
 843
 844 AC_MSG_CHECKING([for Python])
 845
 846 if test "$enable_python" = "yes"; then
 847         AC_MSG_RESULT(yes);
 848
 849         if test -d "$withval"; then
 850                 PYTHON_PATH="$withval:$PATH"
 851         else
 852                 PYTHON_PATH="$PATH"
 853         fi
 854
 855         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 856
 857         if test "$PYTHON" != no; then
 858                 cf_result="yes";
 859
 860                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 861                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 862                 LIBS="$PYTHON_LIBS $LIBS"
 863                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 864                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 865
 866                 if test "$cf_result" != "yes"; then
 867                         EL_RESTORE_FLAGS
 868                 else
 869                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 870                         AC_SUBST(PYTHON_LIBS)
 871                         AC_SUBST(PYTHON_CFLAGS)
 872                         CPPFLAGS="$CPPFLAGS_X"
 873                         cat <<EOF
 874 ***********************************************************************
 875 The Python support is incomplete and not so well integrated to ELinks
 876 yet. That means, e.g., that you have no Python console and there might
 877 not be all the necessary hooks. Also, the Python interface is not too
 878 well tested (success stories heartily welcomed!).
 879 ***********************************************************************
 880 EOF
 881                 fi
 882         else
 883                 if test -n "$withval" && test "x$withval" != xno; then
 884                         AC_MSG_ERROR([Python not found])
 885                 else
 886                         AC_MSG_WARN([Python support disabled])
 887                 fi
 888         fi
 889 else
 890         AC_MSG_RESULT(no);
 891 fi
 892
 893
 894 # ===================================================================
 895 # Check for Lua, optional even if installed.
 896 # ===================================================================
 897
 898 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 899 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 900
 901 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 902             [if test "$withval" = no; then disable_lua=yes; fi])
 903 AC_MSG_CHECKING([for Lua])
 904
 905 EL_SAVE_FLAGS
 906 cf_result=no
 907
 908 if test -z "$disable_lua"; then
 909         if test ! -d "$withval"; then
 910                 withval="";
 911         fi
 912         for luadir in "$withval" "" /usr /usr/local; do
 913                 for suffix in "" 5.1 51; do
 914                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 915                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 916                                 LUA_LIBS="-L$luadir/lib -llua$suffix -lm"
 917                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 918
 919                                 LIBS="$LUA_LIBS $LIBS_X"
 920                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 921                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 922
 923                                 # Check that it is a compatible Lua version
 924                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lauxlib.h>]
 925                                                 #include <lua.h>
 926                                                 #include <lualib.h>
 927                                                 ], [[   lua_State *L = luaL_newstate();
 928                                                 luaL_openlibs(L);
 929                                                 lua_pushboolean(L, 1);
 930                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 931                         fi
 932                 done
 933         done
 934 fi
 935
 936 AC_MSG_RESULT($cf_result)
 937
 938 if test "$cf_result" != yes; then
 939         EL_RESTORE_FLAGS
 940 else
 941         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 942         AC_CHECK_HEADERS(lauxlib.h)
 943
 944         CFLAGS="$CFLAGS_X"
 945         CPPFLAGS="$CPPFLAGS_X"
 946         AC_SUBST(LUA_LIBS)
 947         AC_SUBST(LUA_CFLAGS)
 948 fi
 949
 950 # ===================================================================
 951 # Check for TRE library
 952 # ===================================================================
 953 #
 954 # This section only checks that --without-tre is not given and the
 955 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 956 # tre_log.  It does not define CONFIG_TRE, and always resets
 957 # LIBS and CFLAGS back to their original values.
 958 #
 959 # After any --enable-utf-8 and --disable-utf-8 options have been
 960 # handled, a separate section decides whether to actually use TRE.
 961 #
 962 # tre version 0.8.0 or higher is required which have the "tre_" prefix
 963 # for functions.
 964
 965 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 966 if test "$with_tre" = no; then
 967         AC_MSG_CHECKING([[for TRE]])
 968         AC_MSG_RESULT([[disabled]])
 969         tre_log="no (explicitly disabled)"
 970 else
 971         AC_MSG_CHECKING([[for TRE in pkg-config]])
 972         if pkg-config tre; then
 973                 TRE_CFLAGS=`pkg-config --cflags tre`
 974                 TRE_LIBS=`pkg-config --libs tre`
 975                 AC_MSG_RESULT([[yes]])
 976         else
 977                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 978                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 979                 # so we look for the library even if pkg-config doesn't know about it.
 980                 TRE_CFLAGS=
 981                 TRE_LIBS=-ltre
 982                 AC_MSG_RESULT([[no, but let's try defaults]])
 983         fi
 984
 985         AC_MSG_CHECKING([[for TRE header and library]])
 986         EL_SAVE_FLAGS
 987         CFLAGS="$TRE_CFLAGS $CFLAGS"
 988         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
 989         AC_TRY_LINK([#include <tre/tre.h>],
 990                     [regex_t re;
 991                      regmatch_t match[1];
 992                      tre_regwcomp(&re, L"zap", REG_ICASE);
 993                      tre_regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 994                     [AC_MSG_RESULT([[yes]])
 995                      tre_log="available"],
 996                     [AC_MSG_RESULT([[no]])
 997                      tre_log="no (TRE not found)"])
 998         EL_RESTORE_FLAGS
 999 fi
1000
1001 # ===================================================================
1002 # Check for Ruby, optional even if installed.
1003 # ===================================================================
1004
1005 EL_CONFIG_SCRIPTING_RUBY
1006
1007 # ===================================================================
1008 # Setup global scripting
1009 # ===================================================================
1010
1011 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
1012 AC_SUBST(CONFIG_SCRIPTING_GUILE)
1013 AC_SUBST(CONFIG_SCRIPTING_LUA)
1014 AC_SUBST(CONFIG_SCRIPTING_PERL)
1015 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
1016 AC_SUBST(CONFIG_SCRIPTING_RUBY)
1017 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
1018 AC_SUBST(CONFIG_SCRIPTING)
1019
1020
1021 # ===================================================================
1022 # Check for SSL support.
1023 # ===================================================================
1024
1025 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
1026 # is enabled, we won't try to use OpenSSL anymore.
1027
1028 # For wiping SSL hooks..
1029 #ifdef CONFIG_SSL
1030
1031 chosen_ssl_library=""
1032
1033 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1034 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1035             [case "$with_gnutls" in
1036                 "no")   : ;;
1037                 "yes")  chosen_ssl_library="GNUTLS" ;;
1038                 *)      chosen_ssl_library="GNUTLS"
1039                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1040 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1041              esac])
1042
1043 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1044 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1045             [case "$with_openssl" in
1046                 "no")   : ;;
1047                 *)      chosen_ssl_library="OpenSSL" ;;
1048              esac])
1049
1050 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
1051                           NSS compatibility SSL libraries/include files]],
1052             [case "$with_nss_compat_ossl" in
1053                 "no")   : ;;
1054                 *)      chosen_ssl_library="nss_compat_ossl" ;;
1055              esac])
1056
1057 # ---- nss_compat_ossl
1058
1059 if test "$with_nss_compat_ossl" = no; then
1060         # explicitly disabled
1061         :
1062 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "nss_compat_ossl"; then
1063         # not used, because $chosen_ssl_library was chosen
1064         :
1065 elif test -z "${with_nss_compat_ossl+set}"; then
1066         # SSL_library_init() in nss_compat_ossl 0.9.2 calls exit(1)
1067         # with no error message if there is no certificate database.
1068         # https://bugzilla.redhat.com/show_bug.cgi?id=463437
1069         # So ELinks uses nss_compat_ossl only if explicitly requested.
1070         :
1071 else
1072         EL_SAVE_FLAGS
1073         if test "$with_nss_compat_ossl" = yes; then
1074                 if pkg-config nss; then
1075                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
1076                         LIBS="$LIBS_X `pkg-config --libs nss`"
1077                 else
1078                         with_nss_compat_ossl=no
1079                 fi
1080         else
1081                 # Without pkg-config, we'll kludge in some defaults
1082                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
1083                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
1084         fi
1085         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
1086         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
1087
1088         if test "$with_nss_compat_ossl" = "no"; then
1089                 EL_RESTORE_FLAGS
1090         else
1091                 LIBS="$LIBS -lnss_compat_ossl"
1092                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
1093                 chosen_ssl_library="nss_compat_ossl"
1094         fi
1095 fi
1096
1097 # ---- OpenSSL
1098
1099 AC_MSG_CHECKING([for OpenSSL])
1100
1101 EL_SAVE_FLAGS
1102
1103 if test "$with_openssl" = no; then
1104         cf_result="explicitly disabled"
1105
1106 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1107         cf_result="not used, because $chosen_ssl_library was chosen"
1108
1109 else
1110         cf_result=no
1111         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1112                          /usr/lib/openssl /usr/local/ssl \
1113                          /usr/local/www /usr/lib/ssl /usr/local \
1114                          /usr/pkg /opt /opt/openssl; do
1115                 if test "$cf_result" = no; then
1116                         if test -d "$ssldir"; then
1117                                 OPENSSL_CFLAGS="-I$ssldir/include"
1118                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1119                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1120                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1121 #                               # FIXME: This created serious portability problems. --pasky
1122 #                               if test "$CC" == "gcc"; then
1123 #                                       # I'm not sure about compatibility here. --pasky
1124 #                                       LIBS="$LIBS -R$ssldir/lib"
1125 #                               fi
1126                         else
1127                                 LIBS="-lssl -lcrypto $LIBS_X"
1128                         fi
1129                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1130                         if test "$cf_result" != yes; then
1131                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1132                         fi
1133                 fi
1134         done
1135
1136         if test "$cf_result" != yes; then
1137                 if test "${with_openssl-no}" != "no"; then
1138                         AC_MSG_ERROR([OpenSSL not found])
1139                 fi
1140                 EL_RESTORE_FLAGS
1141         else
1142                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1143                 chosen_ssl_library="OpenSSL"
1144
1145                 CFLAGS="$CFLAGS_X"
1146                 AC_SUBST(OPENSSL_CFLAGS)
1147         fi
1148 fi
1149
1150 AC_MSG_RESULT($cf_result)
1151
1152 # ---- GNU TLS
1153
1154 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1155 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1156 # ELinks will use its internal MD5 code instead.
1157 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1158
1159 if test "$with_gnutls" = no; then
1160         AC_MSG_CHECKING([[for GNUTLS]])
1161         AC_MSG_RESULT([[explicitly disabled]])
1162
1163 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1164         AC_MSG_CHECKING([[for GNUTLS]])
1165         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1166
1167 else
1168         cf_result=no
1169         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1170         if pkg-config --atleast-version=1.2 gnutls; then
1171                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1172                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1173                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1174
1175                 EL_SAVE_FLAGS
1176                 LIBS="$GNUTLS_LIBS $LIBS"
1177                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1178                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1179
1180                 # Verify if it's really usable.  gnutls_session was
1181                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1182                 # (on 2004-06-13); ELinks now requires this.
1183                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1184                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1185                                                 [[gnutls_session_t dummy;
1186                                                   gnutls_check_version(NULL)]])],
1187                                [cf_result=yes],
1188                                [cf_result=no])
1189                 AC_MSG_RESULT([[$cf_result]])
1190
1191                 if test "$cf_result" = yes; then
1192                         # According to gnutls/NEWS, the function was originally
1193                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1194                         # (released 2007-10-27) and then renamed to
1195                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1196                         # 2007-11-29).
1197                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1198                 fi
1199
1200                 EL_RESTORE_FLAGS
1201         else
1202                 AC_MSG_RESULT([[$cf_result]])
1203         fi
1204
1205         if test "$cf_result" = yes; then
1206                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1207                 chosen_ssl_library="GNUTLS"
1208
1209                 # gcry_create_nounce is part of libgcrypt
1210                 LIBGCRYPT_CFLAGS=`libgcrypt-config --cflags`
1211                 LIBGCRYPT_LIBS=`libgcrypt-config --libs`
1212
1213                 LIBS="$LIBGCRYPT_LIBS $GNUTLS_LIBS $LIBS"
1214                 AC_SUBST(LIBGCRYPT_CFLAGS)
1215                 AC_SUBST(GNUTLS_CFLAGS)
1216
1217         elif test "${with_gnutls-no}" != "no"; then
1218                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1219         fi
1220 fi
1221
1222 # Final SSL setup
1223
1224 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1225 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1226 AC_SUBST(CONFIG_OPENSSL)
1227 AC_SUBST(CONFIG_GNUTLS)
1228 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1229
1230 #endif
1231
1232 AC_MSG_CHECKING([whether to be or not to be])
1233 AC_MSG_RESULT([needs to be determined experimentally])
1234
1235 # ===================================================================
1236 # Check for IPv6 support and related functions.
1237 # ===================================================================
1238
1239 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1240 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1241 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1242
1243 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1244 if test "$HAVE_GETADDRINFO" != yes; then
1245         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1246         if test "$HAVE_GETADDRINFO" = yes; then
1247                 LIBS="$LIBS -linet6"
1248         fi
1249 fi
1250
1251
1252 # ===================================================================
1253 # Checking for X11 (window title restoring).
1254 # ===================================================================
1255
1256 AC_PATH_X
1257 if test x"$no_x" != xyes; then
1258         EL_SAVE_FLAGS
1259         if test -n "$x_includes"; then
1260                 X_CFLAGS="-I$x_includes"
1261                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1262                 CFLAGS="$CFLAGS $X_CFLAGS"
1263         fi
1264         if test -n "$x_libraries"; then
1265                 LDFLAGS="$LDFLAGS -L$x_libraries"
1266         fi
1267         LIBS="-lX11 $LIBS"
1268         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1269         EL_RESTORE_FLAGS
1270         if test "$cf_result" = yes; then
1271                 if test -n "$x_libraries"; then
1272                         LDFLAGS="$LDFLAGS -L$x_libraries"
1273                 fi
1274                 LIBS="-lX11 $LIBS"
1275                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1276                 AC_SUBST(X_CFLAGS)
1277         fi
1278 fi
1279
1280
1281 # ===================================================================
1282 # Backtraces displaying support.
1283 # ===================================================================
1284
1285 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1286 # possible checks for other system-specific means go here
1287
1288
1289 # ===================================================================
1290 # Gettext grey zone. Beware.
1291 # ===================================================================
1292
1293 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1294
1295 AM_GNU_GETTEXT
1296
1297 # iconv is always used
1298 LIBS="$LIBS $LIBICONV"
1299
1300 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1301 dnl # f33r d4 l33t... I hope it's portable. :)
1302 dnl cf_result=$((48#z - 48#a + 1));
1303 dnl AC_MSG_RESULT($cf_result)
1304
1305
1306 # ===================================================================
1307 # Compile-time features control
1308 # ===================================================================
1309
1310 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1311               [  --disable-cookies       disable cookie support])
1312
1313 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1314               [  --disable-formhist      disable form history support])
1315
1316 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1317               [  --disable-globhist      disable global history support])
1318
1319
1320 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1321               [  --disable-mailcap       disable mailcap support])
1322
1323 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1324               [  --disable-mimetypes     disable mimetypes files support])
1325
1326
1327 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1328               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1329               [IPv6],
1330               [  --disable-ipv6          disable IPv6 support])
1331
1332 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1333               [  --enable-bittorrent     enable BitTorrent protocol support])
1334
1335 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1336               [  --disable-data          disable data protocol support])
1337
1338 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1339               [  --disable-uri-rewrite   disable URI rewrite support])
1340
1341 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1342               [  --enable-cgi            enable local CGI support])
1343
1344 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1345               [  --enable-finger         enable finger protocol support])
1346
1347 # ===================================================================
1348 # FSP protocol
1349 # ===================================================================
1350 EL_SAVE_FLAGS
1351
1352 if test "x${enable_fsp}" != xno; then
1353         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1354
1355         if test "$HAVE_FSPLIB" = yes; then
1356                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1357                 if test "$HAVE_FSPLIB" = yes; then
1358                         LIBS="$LIBS -lfsplib"
1359                 else
1360                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1361                         if test "$HAVE_FSPLIB" = yes; then
1362                                 LIBS="$LIBS -lfsp"
1363                         fi
1364                 fi
1365         fi
1366 fi
1367
1368 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1369               [  --enable-fsp            enable FSP protocol support])
1370
1371 if test "x$CONFIG_FSP" = xno; then
1372         EL_RESTORE_FLAGS
1373 fi
1374
1375 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1376               [  --disable-ftp           disable ftp protocol support])
1377
1378 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1379               [  --enable-gopher         enable gopher protocol support])
1380
1381 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1382               [  --enable-nntp           enable nntp protocol support])
1383
1384 # ===================================================================
1385 # SMB protocol support.
1386 # ===================================================================
1387 EL_SAVE_FLAGS
1388
1389 if test "x${enable_smb}" != xno; then
1390         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1391
1392         if test "$HAVE_SMBCLIENT" = yes; then
1393                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1394                 if test "$HAVE_SMBCLIENT" = yes; then
1395                         LIBS="$LIBS -lsmbclient"
1396                 fi
1397         fi
1398 fi
1399
1400 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1401               [  --enable-smb            enable Samba protocol support])
1402
1403 if test "x$CONFIG_SMB" = xno; then
1404         EL_RESTORE_FLAGS
1405 fi
1406
1407
1408 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1409               [  --disable-mouse         disable mouse support])
1410
1411 # GPM mouse is Linux specific, so ...
1412 CONFIG_SYSMOUSE=yes
1413 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1414               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1415               [BSD sysmouse],
1416               [  --disable-sysmouse      disable BSD sysmouse support])
1417
1418 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1419               [  --enable-88-colors      enable 88 color support])
1420
1421 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1422               [  --enable-256-colors     enable 256 color support])
1423
1424 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1425               [  --enable-true-color     enable true color support])
1426
1427 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1428               [  --enable-exmode         enable exmode (CLI) interface])
1429
1430 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1431               [  --disable-leds          disable LEDs support])
1432
1433 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1434               [  --disable-marks         disable document marks support])
1435
1436
1437 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1438               [  --disable-css           disable Cascading Style Sheet support])
1439
1440 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1441               [  --enable-html-highlight HTML highlighting using DOM engine])
1442
1443 # Everything in the tree already uses CONFIG_DOM
1444 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1445 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1446
1447 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1448               [  --disable-backtrace     disable backtrace support])
1449
1450 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1451               [  --enable-no-root        enable prevention of usage by root])
1452
1453
1454 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1455               [  --enable-debug          enable leak debug and internal error checking])
1456
1457 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1458               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1459
1460 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1461               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1462
1463 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1464               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1465
1466 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1467               [  --disable-utf-8         disable UTF-8 support])
1468
1469 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1470               [  --enable-combining      support Unicode combining characters (experimental)])
1471
1472
1473 AC_ARG_ENABLE(weehoofooboomookerchoo,
1474               [
1475     Also check out the features.conf file for more information about features!
1476               ],
1477               [AC_MSG_ERROR(Are you strange, or what?)])
1478
1479
1480 # ===================================================================
1481 # Decide whether to use TRE
1482 # ===================================================================
1483 #
1484 # This must be done after the CONFIG_UTF8 check above.
1485 # The first part of the TRE check is separate, to get
1486 # the configure --help output in a sensible order.
1487 #
1488 # After this section, nothing else must be added to the
1489 # beginning of $LIBS.
1490
1491 if test "$tre_log" = "available"; then
1492         if test "$CONFIG_UTF8" = "yes"; then
1493                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1494                 # src/viewer/text/search.c makes a string of
1495                 # unicode_val_T and gives it to regwexec(), which
1496                 # expects a string of wchar_t.  If the unicode_val_T
1497                 # and wchar_t types are too different, this won't
1498                 # work, so try to detect that and disable regexp
1499                 # operations entirely in that case.
1500                 #
1501                 # Currently, this code only compares the sizes of the
1502                 # types.  src/intl/charsets.h defines unicode_val_T as
1503                 # uint32_t, so we check whether wchar_t has exactly 32
1504                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1505                 # there doesn't seem to be a documented way to get the
1506                 # result of that for use in the configure script.
1507                 #
1508                 # C99 says the implementation can define
1509                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1510                 # (or Unicode) numbers in all locales.  Do not check
1511                 # that macro here, because it is too restrictive: it
1512                 # should be enough for ELinks if the values match in
1513                 # the locales where ELinks is actually run.
1514                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1515                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1516 #include <limits.h>
1517 #include <stddef.h>
1518 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1519                         [AC_MSG_RESULT([[yes]])
1520                          tre_log="TRE"],
1521                         [AC_MSG_RESULT([[no]])
1522                          tre_log="no (unsuitable wchar_t)"])
1523         else
1524                 # If UTF-8 is not used, then wchar_t doesn't matter.
1525                 tre_log="TRE"
1526         fi
1527 fi
1528
1529 if test "$tre_log" = "TRE"; then
1530         AC_DEFINE([CONFIG_TRE], [1],
1531                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1532         # TRE_CFLAGS will be used only where needed.
1533         #
1534         # Bug 1081: If both TRE and libc define the regfree function,
1535         # ELinks needs to use the version defined by TRE because
1536         # that's the one compatible with regex_t initialized by the
1537         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1538         # very beginning of $LIBS so that the linker hopefully finds
1539         # regfree there before it examines libc.  In particular,
1540         # $PERL_LIBS appears to often include "-lc".
1541         #
1542         # This scheme still risks a crash if ELinks is linked with
1543         # some static library that uses GNU <regex.h> extensions that
1544         # TRE does not implement.  For example, the library might call
1545         # re_compile_pattern, which is found in GNU libc, and then
1546         # regfree, which is found in TRE and probably crashes with the
1547         # GNU-initialized regex_t.  Ways to avoid such crashes:
1548         #
1549         # - Change TRE so it defines only tre_... functions and does
1550         #   not attempt to override the POSIX names by default.
1551         #
1552         # - Change ELinks to access TRE only via dlopen and dlsym.
1553         #   The problem then is how to find the correct file name.
1554         #   There might be libtre.so.4 and libtre.so.5 with different
1555         #   ABI.  How can this configure script detect which of them
1556         #   matches the <tre/regex.h> in the include path?
1557         #
1558         # - Replace the static library with a shared library.  At
1559         #   least on GNU/Linux, when the shared library is built, the
1560         #   linker should note that e.g. regfree is defined in libc
1561         #   and has the GLIBC_2.0 version there, and write that
1562         #   version string to the shared library as well; because TRE
1563         #   does not provide regfree with that version, any regfree
1564         #   calls at run time should then get resolved to libc.
1565         LIBS="$TRE_LIBS $LIBS"
1566 else
1567         TRE_LIBS=
1568         TRE_CFLAGS=
1569 fi
1570 AC_SUBST(TRE_CFLAGS)
1571 AC_SUBST(TRE_LIBS)
1572 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1573
1574
1575 # ===================================================================
1576 # Further LDFLAGS tweaks
1577 # ===================================================================
1578
1579 # == EMX hack
1580
1581 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1582 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1583
1584
1585 # Check for -rdynamic
1586 #
1587 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1588 # the executable to its dynamic symbol table.  ELinks uses this for
1589 # two purposes:
1590 #
1591 # 1. If ELinks detects a bug, it can try to display a backtrace by
1592 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1593 #    manual states users of GNU ld must pass -rdynamic to make the
1594 #    symbols available to the program.
1595 #
1596 # 2. It would eventually be nice to dynamically load shared
1597 #    libraries as plugins (bug 73).  The plugins must be able to
1598 #    call ELinks functions.  This can be implemented either by
1599 #    registering all callable functions in ELinks-specific data
1600 #    structures, or by letting the dynamic linker handle them.
1601 #    The latter way requires something equivalent to -rdynamic.
1602 #
1603 # Because backtraces are not needed for correct operation, and bug
1604 # 73 is not yet being fixed, the configure script and makefiles
1605 # should not complain to the user if they find that -rdynamic does
1606 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1607 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1608 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1609 # -rdynamic but does something equivalent automatically.  (This was
1610 # tested with "nm -D elinks | grep redraw_from_window".)
1611 #
1612 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1613 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1614 # linker from finding the libraries listed in -l operands.  So this
1615 # -rdynamic check needs to happen after the libraries have already
1616 # been added to $LDFLAGS.
1617 AC_MSG_CHECKING([for -rdynamic])
1618 LDFLAGS_X="$LDFLAGS"
1619 LDFLAGS="-rdynamic $LDFLAGS"
1620 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1621 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1622 AC_MSG_RESULT($have_rdynamic)
1623
1624 # ===================================================================
1625 # Export directory paths
1626 # ===================================================================
1627
1628 # Set up the ``entry points'' if they were not supplied by builder
1629 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1630 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1631
1632 # Create CONFDIR #define for config.h
1633
1634 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1635 # it's autoconf fault to force us to do such hacks ;p.
1636 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1637   # sysconfdir is set to its default value... fine, let's append /elinks/
1638   # XXX: We can't modify listing of the default in ./configure --help :-(
1639   sysconfdir_n=`eval echo "$sysconfdir"`
1640   sysconfdir=$sysconfdir_n
1641   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1642         sysconfdir="$sysconfdir/elinks"
1643 fi
1644
1645 CONFDIR=$sysconfdir
1646 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1647 AC_SUBST(CONFDIR)
1648
1649 # Create LOCALEDIR #define for config.h
1650 LOCALEDIR=`eval echo "$datadir/locale"`
1651 while echo "$LOCALEDIR" | grep "\\$"
1652 do
1653         LOCALEDIR=`eval echo "$LOCALEDIR"`
1654 done > /dev/null 2> /dev/null
1655 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1656 AC_SUBST(LOCALEDIR)
1657
1658 # Create LIBDIR #define for config.h
1659 LIBDIR=`eval echo "$libdir"`
1660 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1661 AC_SUBST(LIBDIR)
1662
1663 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1664 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1665
1666
1667 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1668 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1669         #error not tcc
1670         #endif ]])],[cf_result=yes],[cf_result=no])
1671
1672 if test "$cf_result" = "yes"; then
1673         AC_DEFINE([HAVE_ALLOCA])
1674         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1675                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1676                 override the alloca macro defined in <stddef.h> of TCC.
1677                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1678                 it has already been included, and does not redefine alloca.
1679                 This might not work in future glibc versions though, because
1680                 the names of the #include guard macros are not documented.
1681                 The incompatibility has been reported to the tinycc-devel
1682                 mailing list on 2008-07-14.  If a future version of TCC provides
1683                 an <alloca.h> of its own, this hack won't be needed.])
1684 fi
1685 # ===================================================================
1686 # A little fine tuning of gcc specific options (continued)
1687 # ===================================================================
1688
1689 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1690   if test "$CONFIG_DEBUG" = "yes"; then
1691     # We want to see all warnings and live with none (in debug mode).
1692     CFLAGS="$CFLAGS -Werror"
1693   fi
1694
1695   case "`$CC -dumpversion`" in
1696     3.0|3.1|3.2)
1697       # These should be ok using -Werror
1698       ;;
1699     3.*)
1700       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1701       # "dereferencing type-punned pointer will break strict-aliasing rules"
1702       # warnings. Disable them by not doing any strict-aliasing. The
1703       # alternative is just too ugly. Thanks gcc guys!! ;)
1704       CFLAGS="$CFLAGS -fno-strict-aliasing"
1705       ;;
1706     4.5*)
1707       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign -Wno-enum-compare"
1708       ;;
1709     4.*)
1710       # Do not show warnings related to (char * | unsigned char *) type
1711       # difference.
1712       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1713       ;;
1714     *)
1715       # These should be ok using -Werror
1716       ;;
1717   esac
1718
1719   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1720   # warning: the address of `builtin_modules' will always evaluate as `true'
1721   # This hits the object_lock and foreach_module macros in particular.
1722   # It would be okay to put something in the macros to avoid the warning,
1723   # but currently this seems to require defining parallel macros that skip
1724   # the NULL check, and that's too ugly.  So we instead disable the warning.
1725   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1726   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1727   for warning_flag in -Wno-address -Wno-always-true; do
1728     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1729     EL_SAVE_FLAGS
1730     CFLAGS="$CFLAGS $warning_flag"
1731     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1732       [AC_MSG_RESULT([yes])
1733        break],
1734       [AC_MSG_RESULT([no])])
1735     EL_RESTORE_FLAGS
1736   done
1737
1738   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1739   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1740   # "warning: assuming signed overflow does not occur when assuming
1741   # that (X + c) > X is always true", which may be an incorrect
1742   # optimization (although allowed by the standard), and breaks the
1743   # build with -Werror.
1744   #
1745   # All of the following tests included -S -Wall -Wextra:
1746   #
1747   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1748   # * gcc-4.0 -O0: OK, compares the values
1749   # * gcc-4.0 -O2: assumes no overflow, does not warn
1750   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1751   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1752   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1753   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1754   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1755   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1756   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1757   #
1758   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1759   # * gcc-4.1 -O0: assumes no overflow, does not warn
1760   # * gcc-4.1 -O2: assumes no overflow, does not warn
1761   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1762   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1763   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1764   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1765   # * gcc-4.1 -O2 -ftrapv: compares the values
1766   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1767   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1768   #
1769   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1770   # * gcc-4.2 -O0: OK, compares the values
1771   # * gcc-4.2 -O2: assumes no overflow, warns about it
1772   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1773   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1774   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1775   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1776   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1777   # * gcc-4.2 -O2 -ftrapv: compares the values
1778   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1779   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1780   #
1781   # Apparently, -ftrapv does not work reliably at all.
1782   for overflow_flag in -fno-strict-overflow -fwrapv; do
1783     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1784     EL_SAVE_FLAGS
1785     CFLAGS="$CFLAGS $overflow_flag"
1786     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1787       [AC_MSG_RESULT([yes])
1788        break],
1789       [AC_MSG_RESULT([no])])
1790     EL_RESTORE_FLAGS
1791   done
1792 fi
1793
1794 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1795 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1796 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1797 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1798
1799 # ===================================================================
1800 # Colored make output
1801 # ===================================================================
1802
1803 if test $(`which tput` colors) -ge 4; then
1804         MAKE_COLOR=1
1805         AC_SUBST(MAKE_COLOR)
1806 fi
1807
1808 # ===================================================================
1809 # Generated files
1810 # ===================================================================
1811
1812 AC_CONFIG_FILES([ \
1813  Makefile.config \
1814  contrib/elinks.spec \
1815  contrib/lua/hooks.lua \
1816  contrib/conv/w3m2links.awk \
1817  doc/Doxyfile \
1818  doc/man/man1/elinks.1 \
1819  src/intl/gettext/ref-add.sed \
1820  src/intl/gettext/ref-del.sed
1821 ])
1822 AC_OUTPUT
1823
1824 abs_srcdir="$(cd "$srcdir" && pwd)"
1825 # builddir is always absolute!
1826 if test "$abs_srcdir" != "$builddir"; then
1827         # Bootstrap the Makefile creation
1828         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1829         "$MAKE" "SRC=$abs_srcdir" init
1830
1831         # Make cg-status ignore this build directory
1832         echo "*" > "$builddir/.gitignore"
1833 fi
1834
1835 # ===================================================================
1836 # Configuration summary
1837 # ===================================================================
1838
1839 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1840 cat features.log