configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.61 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.  (Also, some files
  11 dnl in Autoconf 2.62 and 2.63 sources are not GPLv2 compatible.)
  12 AC_PREREQ(2.61)
  13 AC_INIT
  14 AC_CONFIG_SRCDIR([src/main/main.c])
  15 AC_CONFIG_AUX_DIR(config)
  16
  17 PACKAGE=elinks
  18 VERSION=0.12pre5
  19 AC_SUBST(PACKAGE)
  20 AC_SUBST(VERSION)
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  23 AC_CONFIG_HEADERS(config.h)
  24
  25 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  26 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  27 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  28
  29 MAKE=
  30
  31 for make in gnumake gmake make false; do
  32         if test "x$MAKE" = x; then
  33                 AC_PATH_PROGS(MAKE, "$make")
  34         fi
  35 done
  36
  37 builddir="`pwd`"
  38
  39 # Cleanup if we are configuring with a previous build in the tree
  40 if test -e Makefile.config; then
  41         AC_MSG_CHECKING([for previous build to clean])
  42         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  43         AC_MSG_RESULT(done)
  44 fi
  45
  46 # ===================================================================
  47 # Load feature configuration file and start logging features.
  48 # ===================================================================
  49
  50 features="features.conf"
  51 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  52 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  53 echo "Feature summary:" > features.log
  54
  55 # ===================================================================
  56 # Checks for programs.
  57 # ===================================================================
  58
  59 AC_PROG_CC
  60 AC_PROG_AWK
  61 AC_PATH_PROGS(AWK, "$AWK")
  62 AC_PROG_RANLIB
  63 AC_PROG_INSTALL
  64
  65 AC_PATH_PROGS(GIT, "git")
  66 AC_PATH_PROGS(SPARSE, "sparse")
  67
  68 CONFIG_ASCIIDOC="no"
  69 CONFIG_POD2HTML="no"
  70 CONFIG_XMLTO="no"
  71 CONFIG_JW="no"
  72
  73 if test "x$CONFIG_DOC" != xno; then
  74         AC_PATH_PROGS(PYTHON, "python")
  75         if test "x$PYTHON" != "x"; then
  76                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  77                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  78                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  79         fi
  80
  81         AC_PATH_PROGS(XMLTO, "xmlto")
  82         if test "x$XMLTO" != "x"; then
  83                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  84                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  85                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  86         fi
  87
  88         AC_PATH_PROGS(JW, "jw")
  89         if test "x$JW" != "x"; then
  90                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  91                 EL_CONFIG(MANUAL_JW, [PDF])
  92         fi
  93
  94         AC_PATH_PROGS(POD2HTML, "pod2html")
  95         if test "x$POD2HTML" != "x"; then
  96                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  97         fi
  98
  99         AC_PATH_PROGS(DOXYGEN, "doxygen")
 100         if test "x$DOXYGEN" != "x"; then
 101                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 102                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 103                 AC_SUBST(api_srcdir)
 104         fi
 105 fi
 106
 107 AC_SUBST(CONFIG_ASCIIDOC)
 108 AC_SUBST(CONFIG_DOXYGEN)
 109 AC_SUBST(CONFIG_POD2HTML)
 110 AC_SUBST(CONFIG_XMLTO)
 111 AC_SUBST(CONFIG_JW)
 112
 113 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 114 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 115 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 116 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 117
 118 # gcc specific options (to be continued at the bottom of configure)
 119 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 120   # We want to see all warnings and live with none.
 121   # We can't set up -Werror here as there may be some warnings in test
 122   # suite of configure, and we don't want to fail them.
 123   CFLAGS="$CFLAGS -Wall"
 124 fi
 125
 126 # ===================================================================
 127 # Checks for special OSes.
 128 # ===================================================================
 129
 130 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 131 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 132 [
 133         AC_MSG_CHECKING([for $2])
 134
 135         for flag in $3; do
 136                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 137 kill me!
 138 #endif ]])],[$1=yes],[$1=no])
 139                 if test "[$]$1" = yes; then
 140                         EL_CONFIG([$1], [$2])
 141                         break
 142                 fi
 143         done
 144
 145         AC_MSG_RESULT([$]$1)
 146 ])
 147
 148 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 149 AC_SUBST(CONFIG_OS_BEOS)
 150
 151 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 152 AC_SUBST(CONFIG_OS_RISCOS)
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 155 AC_SUBST(CONFIG_OS_WIN32)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 158 AC_SUBST(CONFIG_OS_OS2)
 159 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 160
 161 AC_MSG_CHECKING([for UNIX])
 162 dnl FIXME: some depend kind of mechanism
 163 if test "$CONFIG_OS_BEOS" = no && \
 164    test "$CONFIG_OS_RISCOS" = no && \
 165    test "$CONFIG_OS_WIN32" = no && \
 166    test "$CONFIG_OS_OS2" = no; then
 167         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 168 else
 169         CONFIG_OS_UNIX=no
 170 fi
 171 AC_MSG_RESULT($CONFIG_OS_UNIX)
 172 AC_SUBST(CONFIG_OS_UNIX)
 173
 174 # ===================================================================
 175 # Checks for header files.
 176 # ===================================================================
 177
 178 AC_HEADER_DIRENT
 179 AC_HEADER_STDC
 180 AC_HEADER_SYS_WAIT
 181 AC_HEADER_TIME
 182
 183 AC_CHECK_HEADERS(wctype.h)
 184 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 185 AC_CHECK_HEADERS(sigaction.h)
 186 AC_CHECK_HEADERS(arpa/inet.h)
 187 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 188 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 189 AC_CHECK_HEADERS(ifaddrs.h)
 190 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 191 AC_CHECK_HEADERS(sys/fmutex.h)
 192 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 193 AC_CHECK_HEADERS(sys/resource.h)
 194 AC_CHECK_HEADERS(sys/select.h)
 195 AC_CHECK_HEADERS(sys/signal.h)
 196 AC_CHECK_HEADERS(sys/socket.h)
 197 AC_CHECK_HEADERS(sys/time.h)
 198 AC_CHECK_HEADERS(sys/utsname.h)
 199 AC_CHECK_HEADERS([net/if.h], [], [],
 200 [[#ifdef HAVE_SYS_SOCKET_H
 201 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 202 #endif
 203 ]])
 204 AC_CHECK_HEADERS(stdint.h inttypes.h)
 205 AC_CHECK_HEADERS(locale.h pwd.h)
 206 AC_CHECK_HEADERS(termios.h)
 207
 208
 209 AC_CHECK_HEADERS(sys/un.h,
 210         [CONFIG_INTERLINK=yes
 211          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 212         [CONFIG_INTERLINK=no])
 213 AC_SUBST(CONFIG_INTERLINK)
 214
 215 # ===================================================================
 216 # Checks for typedefs, structures, and compiler characteristics.
 217 # ===================================================================
 218
 219 AC_STRUCT_TM
 220 AC_C_CONST
 221 AC_C_INLINE
 222 AC_MSG_CHECKING([[for C99-conforming inline]])
 223 AC_COMPILE_IFELSE([[
 224         int add(int change);
 225
 226         static int sum;
 227
 228         inline int
 229         add(int change)
 230         {
 231                 sum += change;
 232                 return sum;
 233         }
 234
 235         int
 236         sub(int change)
 237         {
 238                 return add(-change);
 239         }]],
 240         [AC_MSG_RESULT([[yes]])
 241          AC_DEFINE([NONSTATIC_INLINE], [inline],
 242                 [Define as inline if the compiler lets you declare a function without inline, then define it with inline, and have that definition refer to identifiers with internal linkage.  This is allowed by C99 6.7.4p6 and 6.7.4p3 together.  Otherwise define as nothing.])],
 243         [AC_MSG_RESULT([[no]])
 244          AC_DEFINE([NONSTATIC_INLINE], [])])
 245 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 246
 247 AC_SYS_LARGEFILE
 248 AC_TYPE_SIZE_T
 249 AC_TYPE_OFF_T
 250 EL_CHECK_TYPE(ssize_t, int)
 251 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 252 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 253 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 254 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 255 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 256
 257 AC_CHECK_SIZEOF(char, 1)
 258 AC_CHECK_SIZEOF(short, 2)
 259 AC_CHECK_SIZEOF(int, 4)
 260 AC_CHECK_SIZEOF(long, 4)
 261 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 262 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 263
 264 # Check for variadic macros
 265 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 266                 [#include <stdio.h>
 267                  #define a(b,c...) printf(b,##c)],
 268                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 269
 270 # ===================================================================
 271 # Checks for library functions.
 272 # ===================================================================
 273
 274 AC_PROG_GCC_TRADITIONAL
 275 AC_FUNC_MEMCMP
 276 AC_FUNC_MMAP
 277 AC_FUNC_STRFTIME
 278 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 279 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 280 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 281 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 282 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 283 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 284 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 285 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 286
 287 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 288
 289 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 290 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 291 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 292
 293 # These aren't probably needed now, as they are commented in links.h.
 294 # I've no idea about their historical background, but I keep them here
 295 # just in the case they will help later. --pasky
 296 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 297 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 298 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 299 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 300
 301 if test x"$HAVE_RAISE" = x; then
 302         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 303                 AC_MSG_ERROR([Unable to emulate raise()])
 304         fi
 305 fi
 306
 307 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 308 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 309 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 310 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 311         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 312 fi
 313
 314 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 315 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 316 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 317 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 318         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 319 fi
 320
 321 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 322 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 323 #include <stdio.h>
 324 #include <stdarg.h>
 325 #include <stdlib.h>
 326 #include <string.h>
 327
 328 char buf[8];
 329
 330 int bar(char *buf, const char *format, va_list ap)
 331 {
 332        return vsnprintf(buf, 0, format, ap);
 333 }
 334
 335 void foo(const char *format, ...) {
 336        va_list ap;
 337        int len;
 338
 339        va_start(ap, format);
 340        len = bar(buf, format, ap);
 341        va_end(ap);
 342        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 343
 344        va_start(ap, format);
 345        len = bar(buf, format, ap);
 346        va_end(ap);
 347        if ((len != 6) && (len != 7)) exit(1);
 348
 349        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 350
 351        exit(0);
 352 }
 353 main() { foo("hello\n"); }
 354 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 355 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 356         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 357 fi
 358
 359 # OpenSSL and Lua frequently need dlopen
 360 AC_CHECK_LIB(dl, dlopen)
 361
 362 # ===================================================================
 363 # Checks for libraries.
 364 # ===================================================================
 365
 366 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 367 if test "$cf_result" = no; then
 368         AC_CHECK_LIB(socket, socket)
 369 fi
 370
 371 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 372 if test "$cf_result" = no; then
 373         AC_CHECK_LIB(socket, setsockopt)
 374 fi
 375
 376 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 377 if test "$cf_result" = no; then
 378         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 379         if test "$cf_result" = no; then
 380                 AC_CHECK_LIB(nsl, gethostbyname)
 381         else
 382                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 383         fi
 384 fi
 385
 386 # ===================================================================
 387 # Checks for packaging specific options.
 388 # ===================================================================
 389
 390 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 391             [ if test "$withval" != no && test "$withval" != yes; then
 392                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 393               fi ])
 394
 395 # ===================================================================
 396 # Checks for a libraries, optional even if installed.
 397 # ===================================================================
 398
 399 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 400 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 401 [
 402         AC_MSG_CHECKING([for $2 support])
 403
 404         if test "[$]$1" != no; then
 405                 AC_MSG_RESULT(yes)
 406                 EL_SAVE_FLAGS
 407                 if test -n "$withval" && test -d "$withval"; then
 408                         # Be a little more careful when setting
 409                         # include and lib directories. This way
 410                         # $withval will work when includes are
 411                         # there but the library is in the common
 412                         # /usr/lib ... Does the right thing when
 413                         # looking for gc on Debian.
 414                         if test -d "$withval/include"; then
 415                                 CFLAGS="$CFLAGS -I$withval/include"
 416                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 417                         else
 418                                 CFLAGS="$CFLAGS -I$withval"
 419                                 CPPFLAGS="$CPPFLAGS -I$withval"
 420                         fi
 421                         if test -d "$withval/lib"; then
 422                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 423                         fi
 424                 fi
 425
 426                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 427                 if test "[$]$1" = yes; then
 428                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 429                 fi
 430
 431                 if test "[$]$1" = yes; then
 432                         EL_CONFIG([$1], [$2])
 433                         LIBS="$LIBS -l$4"
 434                 else
 435                         if test -n "[$]WITHVAL_$1" &&
 436                            test "[$]WITHVAL_$1" != xno; then
 437                                 AC_MSG_ERROR([$2 not found])
 438                         fi
 439                         EL_RESTORE_FLAGS
 440                 fi
 441         else
 442                 AC_MSG_RESULT(disabled)
 443         fi
 444 ])
 445
 446 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 447 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 448 [
 449         if test "x[$]$1" != xno; then $1=yes; fi
 450         WITHVAL_$1=
 451
 452         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 453         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 454         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 455
 456         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 457
 458         EL_LOG_CONFIG([$1], [$2], [])
 459 ])
 460
 461 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 462         [  --without-gpm           disable gpm (mouse) support])
 463
 464 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 465 # enable automatic decoding of both zlib and gzip headers.  This
 466 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 467 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 468 # that, even though ELinks does not actually call gzclearerr.
 469 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 470         [  --without-zlib          disable zlib support])
 471
 472 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 473         [  --without-bzlib         disable bzlib support])
 474
 475 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 476         [  --without-idn           disable international domain names support])
 477
 478 if test "x${with_gc}" != xno; then
 479         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 480                 [  --with-gc               enable Boehm's garbage collector])
 481 fi
 482
 483 # LZMA disabled by default, because of little usability and compilation problems
 484 # with new xz
 485 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 486         [  --with-lzma             enable lzma encoding support])
 487
 488 # ===================================================================
 489 # Check for GSSAPI, optional even if installed.
 490 # ===================================================================
 491
 492 enable_gssapi="no";
 493
 494 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 495             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 496
 497 AC_MSG_CHECKING([for GSSAPI])
 498
 499 if test "$enable_gssapi" = "yes"; then
 500         AC_MSG_RESULT(yes)
 501         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 502         GSSAPI_LIBS=`krb5-config --libs gssapi`
 503         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 504         LIBS="$GSSAPI_LIBS $LIBS"
 505         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 506 else
 507         AC_MSG_RESULT(no)
 508 fi
 509
 510 AC_SUBST(CONFIG_GSSAPI)
 511
 512 # ===================================================================
 513 # Bookmark and XBEL support
 514 # ===================================================================
 515
 516 EL_SAVE_FLAGS
 517
 518 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 519               [  --disable-bookmarks     disable bookmark support])
 520
 521 # Check whether --enable-xbel or --disable-xbel was given.
 522 if test "x${enable_xbel}" != xno; then
 523         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 524
 525         if test "$HAVE_LIBEXPAT" = yes; then
 526                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 527                 if test "$HAVE_LIBEXPAT" = yes; then
 528                         LIBS="$LIBS -lexpat"
 529                 fi
 530         fi
 531 fi
 532
 533
 534 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 535               [XBEL bookmarks],
 536               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 537
 538 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 539         EL_RESTORE_FLAGS
 540 fi
 541
 542 # ===================================================================
 543 # Checks for BSD sysmouse
 544 # ===================================================================
 545
 546 HAVE_SYSMOUSE_HEADER="no"
 547
 548 # Either of these header files provides the (same) sysmouse interface
 549 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 550
 551 # ===================================================================
 552 # Checks for OS/2
 553 # ===================================================================
 554
 555 if test "$CONFIG_OS_OS2" = yes; then
 556         EL_CONFIG_OS_OS2
 557 fi
 558
 559 # ===================================================================
 560 # Checks for Win32
 561 # ===================================================================
 562
 563 if test "$CONFIG_OS_WIN32" = yes; then
 564         EL_CONFIG_OS_WIN32
 565 fi
 566
 567 # ===================================================================
 568 # Check for SEE (Simple Ecmascript Engine)
 569 # ===================================================================
 570 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 571             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 572
 573 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 574 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 575 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 576 # for Guile in $PATH etc. --pasky
 577
 578 CONFIG_ECMASCRIPT_SEE=no
 579
 580 if test "$enable_see" = "yes"; then
 581         if test -d "$withval"; then
 582                 SEE_PATH="$withval:$PATH"
 583         else
 584                 SEE_PATH="$PATH"
 585         fi
 586
 587         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 588         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 589         if test "$SEE_CONFIG" != no; then
 590                 EL_SAVE_FLAGS
 591                 SEE_LIBS="`$SEE_CONFIG --libs`"
 592                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 593                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 594                 LIBS="$SEE_LIBS $LIBS_X"
 595                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 596                         #error SEE too old
 597                         #endif
 598                 ]])],[cf_result=yes],[cf_result=no])
 599                 EL_RESTORE_FLAGS
 600                 if test "$cf_result" = yes; then
 601                         LIBS="$SEE_LIBS $LIBS"
 602                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 603                         AC_SUBST(SEE_CFLAGS)
 604                 fi
 605                 AC_MSG_RESULT($cf_result)
 606         else
 607                 if test -n "$withval" && test "x$withval" != xno; then
 608                         AC_MSG_ERROR([SEE not found])
 609                 else
 610                         AC_MSG_WARN([SEE support disabled])
 611                 fi
 612         fi
 613 fi
 614
 615 # ===================================================================
 616 # Check for SpiderMonkey, optional even if installed.
 617 # ===================================================================
 618
 619 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 620             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 621 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 622
 623 EL_SAVE_FLAGS
 624 cf_result=no
 625
 626 if test -z "$disable_spidermonkey"; then
 627         if test ! -d "$withval"; then
 628                 withval="";
 629         fi
 630         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 631                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 632                         for spidermonkeylib in js smjs mozjs; do
 633                                 if test "$cf_result" = no &&
 634                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 635                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 636                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 637
 638                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 639                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 640                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 641
 642                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 643                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 644                                 fi
 645                         done
 646                 done
 647         done
 648 fi
 649
 650 AC_MSG_RESULT($cf_result)
 651 CONFIG_SPIDERMONKEY="$cf_result"
 652 if test "$cf_result" = "yes"; then
 653         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 654 fi
 655 EL_RESTORE_FLAGS
 656
 657 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 658    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 659         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 660 else
 661         CONFIG_ECMASCRIPT_SMJS=no
 662 fi
 663
 664 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 665 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 666 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 667
 668
 669 # ===================================================================
 670 # Optional Spidermonkey-based ECMAScript browser scripting
 671 # ===================================================================
 672
 673 AC_ARG_ENABLE(sm-scripting,
 674               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 675               [if test "$enableval" != no; then enableval="yes"; fi
 676                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 677
 678 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 679    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 680         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 681 else
 682         CONFIG_SCRIPTING_SPIDERMONKEY=no
 683 fi
 684
 685 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 686    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 687         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 688         AC_SUBST(SPIDERMONKEY_LIBS)
 689         AC_SUBST(SPIDERMONKEY_CFLAGS)
 690         AC_SUBST(CONFIG_SPIDERMONKEY)
 691 fi
 692
 693 # ===================================================================
 694 # Check for Guile, optional even if installed.
 695 # ===================================================================
 696
 697 enable_guile="no";
 698
 699 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 700             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 701
 702 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 703 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 704 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 705 # for Guile in $PATH etc. --pasky
 706
 707 AC_MSG_CHECKING([for Guile])
 708
 709 if test "$enable_guile" = "yes"; then
 710         AC_MSG_RESULT(yes);
 711         ## Based on the GUILE_FLAGS macro.
 712
 713         if test -d "$withval"; then
 714                 GUILE_PATH="$withval:$PATH"
 715         else
 716                 GUILE_PATH="$PATH"
 717         fi
 718
 719         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 720
 721         ## First, let's just see if we can find Guile at all.
 722         if test "$GUILE_CONFIG" != no; then
 723                 cf_result="yes";
 724
 725                 GUILE_LIBS="`guile-config link`"
 726                 GUILE_CFLAGS="`guile-config compile`"
 727                 LIBS="$GUILE_LIBS $LIBS"
 728                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 729                 AC_SUBST(GUILE_CFLAGS)
 730                 cat <<EOF
 731 ***********************************************************************
 732 The Guile support is incomplete and not so well integrated to ELinks
 733 yet. That means, e.g., that you have no Guile console and there might
 734 not be all the necessary hooks. Also, the Guile interface is not too
 735 well tested (success stories heartily welcomed!).  See
 736 src/scripting/guile/README for further details and hints.
 737 ***********************************************************************
 738 EOF
 739         else
 740                 if test -n "$withval" && test "x$withval" != xno; then
 741                         AC_MSG_ERROR([Guile not found])
 742                 else
 743                         AC_MSG_WARN([Guile support disabled])
 744                 fi
 745         fi
 746 else
 747         AC_MSG_RESULT(no);
 748 fi
 749
 750 # ===================================================================
 751 # Check for Perl
 752 # ===================================================================
 753 enable_perl="no";
 754
 755 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 756             [
 757 if test "$withval" = yes; then
 758         # FIXME: If withval is a valid directory append it to PATH
 759         # so that you can specify one of several perl installations.
 760         withval="";
 761         enable_perl=yes;
 762 fi
 763             ])
 764
 765 AC_MSG_CHECKING([for Perl])
 766
 767 cf_result=no
 768
 769 EL_SAVE_FLAGS
 770
 771 if test "$enable_perl" = "yes"; then
 772         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 773         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 774         LIBS="$PERL_LIBS $LIBS"
 775         CFLAGS="$PERL_CFLAGS $CFLAGS"
 776         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 777         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 778 #include <EXTERN.h>
 779 #include <perl.h>
 780 #include <perlapi.h>
 781 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 782 fi
 783
 784 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 785
 786 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 787 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 788 #include <EXTERN.h>
 789 #include <perl.h>
 790 extern PerlInterpreter *my_perl;
 791 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 792 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 793                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 794 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 795
 796 if test "$cf_result" != "yes"; then
 797         EL_RESTORE_FLAGS
 798 else
 799         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 800
 801         CFLAGS="$CFLAGS_X"
 802         CPPFLAGS="$CPPFLAGS_X"
 803         AC_SUBST(PERL_LIBS)
 804         AC_SUBST(PERL_CFLAGS)
 805 fi
 806
 807 # ===================================================================
 808 # Check for Python
 809 # ===================================================================
 810 enable_python="no";
 811
 812 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 813             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 814
 815 EL_SAVE_FLAGS
 816 cf_result=no
 817
 818 AC_MSG_CHECKING([for Python])
 819
 820 if test "$enable_python" = "yes"; then
 821         AC_MSG_RESULT(yes);
 822
 823         if test -d "$withval"; then
 824                 PYTHON_PATH="$withval:$PATH"
 825         else
 826                 PYTHON_PATH="$PATH"
 827         fi
 828
 829         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 830
 831         if test "$PYTHON" != no; then
 832                 cf_result="yes";
 833
 834                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 835                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 836                 LIBS="$PYTHON_LIBS $LIBS"
 837                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 838                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 839
 840                 if test "$cf_result" != "yes"; then
 841                         EL_RESTORE_FLAGS
 842                 else
 843                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 844                         AC_SUBST(PYTHON_LIBS)
 845                         AC_SUBST(PYTHON_CFLAGS)
 846                         CPPFLAGS="$CPPFLAGS_X"
 847                         cat <<EOF
 848 ***********************************************************************
 849 The Python support is incomplete and not so well integrated to ELinks
 850 yet. That means, e.g., that you have no Python console and there might
 851 not be all the necessary hooks. Also, the Python interface is not too
 852 well tested (success stories heartily welcomed!).
 853 ***********************************************************************
 854 EOF
 855                 fi
 856         else
 857                 if test -n "$withval" && test "x$withval" != xno; then
 858                         AC_MSG_ERROR([Python not found])
 859                 else
 860                         AC_MSG_WARN([Python support disabled])
 861                 fi
 862         fi
 863 else
 864         AC_MSG_RESULT(no);
 865 fi
 866
 867
 868 # ===================================================================
 869 # Check for Lua, optional even if installed.
 870 # ===================================================================
 871
 872 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 873 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 874
 875 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 876             [if test "$withval" = no; then disable_lua=yes; fi])
 877 AC_MSG_CHECKING([for Lua])
 878
 879 EL_SAVE_FLAGS
 880 cf_result=no
 881
 882 if test -z "$disable_lua"; then
 883         if test ! -d "$withval"; then
 884                 withval="";
 885         fi
 886         for luadir in "$withval" "" /usr /usr/local; do
 887                 for suffix in "" 50; do
 888                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 889                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 890                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 891                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 892
 893                                 LIBS="$LUA_LIBS $LIBS_X"
 894                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 895                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 896
 897                                 # Check that it is a compatible Lua version
 898                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 899                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 900                                                 luaopen_base(L);
 901                                                 luaopen_table(L);
 902                                                 luaopen_io(L);
 903                                                 luaopen_string(L);
 904                                                 luaopen_math(L);
 905                                                 lua_pushboolean(L, 1);
 906                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 907                         fi
 908                 done
 909         done
 910 fi
 911
 912 AC_MSG_RESULT($cf_result)
 913
 914 if test "$cf_result" != yes; then
 915         EL_RESTORE_FLAGS
 916 else
 917         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 918         AC_CHECK_HEADERS(lauxlib.h)
 919
 920         CFLAGS="$CFLAGS_X"
 921         CPPFLAGS="$CPPFLAGS_X"
 922         AC_SUBST(LUA_LIBS)
 923         AC_SUBST(LUA_CFLAGS)
 924 fi
 925
 926 # ===================================================================
 927 # Check for TRE library
 928 # ===================================================================
 929 #
 930 # This section only checks that --without-tre is not given and the
 931 # library seems to work, and sets TRE_CFLAGS, TRE_LIBS, and
 932 # tre_log.  It does not define CONFIG_TRE, and always resets
 933 # LIBS and CFLAGS back to their original values.
 934 #
 935 # After any --enable-utf-8 and --disable-utf-8 options have been
 936 # handled, a separate section decides whether to actually use TRE.
 937
 938 AC_ARG_WITH([[tre]], [[  --without-tre           disable TRE regex search support]])
 939 if test "$with_tre" = no; then
 940         AC_MSG_CHECKING([[for TRE]])
 941         AC_MSG_RESULT([[disabled]])
 942         tre_log="no (explicitly disabled)"
 943 else
 944         AC_MSG_CHECKING([[for TRE in pkg-config]])
 945         if pkg-config tre; then
 946                 TRE_CFLAGS=`pkg-config --cflags tre`
 947                 TRE_LIBS=`pkg-config --libs tre`
 948                 AC_MSG_RESULT([[yes]])
 949         else
 950                 # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 951                 # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 952                 # so we look for the library even if pkg-config doesn't know about it.
 953                 TRE_CFLAGS=
 954                 TRE_LIBS=-ltre
 955                 AC_MSG_RESULT([[no, but let's try defaults]])
 956         fi
 957
 958         AC_MSG_CHECKING([[for TRE header and library]])
 959         EL_SAVE_FLAGS
 960         CFLAGS="$TRE_CFLAGS $CFLAGS"
 961         LIBS="$TRE_LIBS $LIBS" # must be first, because of regfree conflict
 962         AC_TRY_LINK([#include <tre/regex.h>],
 963                     [regex_t re;
 964                      regmatch_t match[1];
 965                      regwcomp(&re, L"zap", REG_ICASE);
 966                      regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 967                     [AC_MSG_RESULT([[yes]])
 968                      tre_log="available"],
 969                     [AC_MSG_RESULT([[no]])
 970                      tre_log="no (TRE not found)"])
 971         EL_RESTORE_FLAGS
 972 fi
 973
 974 # ===================================================================
 975 # Check for Ruby, optional even if installed.
 976 # ===================================================================
 977
 978 EL_CONFIG_SCRIPTING_RUBY
 979
 980 # ===================================================================
 981 # Setup global scripting
 982 # ===================================================================
 983
 984 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 985 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 986 AC_SUBST(CONFIG_SCRIPTING_LUA)
 987 AC_SUBST(CONFIG_SCRIPTING_PERL)
 988 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 989 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 990 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 991 AC_SUBST(CONFIG_SCRIPTING)
 992
 993
 994 # ===================================================================
 995 # Check for SSL support.
 996 # ===================================================================
 997
 998 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 999 # is enabled, we won't try to use OpenSSL anymore.
1000
1001 # For wiping SSL hooks..
1002 #ifdef CONFIG_SSL
1003
1004 chosen_ssl_library=""
1005
1006 AC_ARG_WITH(gnutls, [[  --without-gnutls        disable GNUTLS SSL support]])
1007 AC_ARG_WITH(gnutls, [[  --with-gnutls           enable GNUTLS SSL support]],
1008             [case "$with_gnutls" in
1009                 "no")   : ;;
1010                 "yes")  chosen_ssl_library="GNUTLS" ;;
1011                 *)      chosen_ssl_library="GNUTLS"
1012                         AC_MSG_WARN([[Support for --with-gnutls=DIR has been removed.
1013 You may have to set the PKG_CONFIG_PATH environment variable instead.]]) ;;
1014              esac])
1015
1016 AC_ARG_WITH(openssl, [[  --without-openssl       disable OpenSSL support]])
1017 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]],
1018             [case "$with_openssl" in
1019                 "no")   : ;;
1020                 *)      chosen_ssl_library="OpenSSL" ;;
1021              esac])
1022
1023 # ---- OpenSSL
1024
1025 AC_MSG_CHECKING([for OpenSSL])
1026
1027 EL_SAVE_FLAGS
1028
1029 if test "$with_openssl" = no; then
1030         cf_result="explicitly disabled"
1031
1032 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "OpenSSL"; then
1033         cf_result="not used, because $chosen_ssl_library was chosen"
1034
1035 else
1036         cf_result=no
1037         for ssldir in "$with_openssl" "" /usr /usr/local/openssl \
1038                          /usr/lib/openssl /usr/local/ssl \
1039                          /usr/local/www /usr/lib/ssl /usr/local \
1040                          /usr/pkg /opt /opt/openssl; do
1041                 if test "$cf_result" = no; then
1042                         if test -d "$ssldir"; then
1043                                 OPENSSL_CFLAGS="-I$ssldir/include"
1044                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1045                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1046                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1047 #                               # FIXME: This created serious portability problems. --pasky
1048 #                               if test "$CC" == "gcc"; then
1049 #                                       # I'm not sure about compatibility here. --pasky
1050 #                                       LIBS="$LIBS -R$ssldir/lib"
1051 #                               fi
1052                         else
1053                                 LIBS="-lssl -lcrypto $LIBS_X"
1054                         fi
1055                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1056                         if test "$cf_result" != yes; then
1057                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1058                         fi
1059                 fi
1060         done
1061
1062         if test "$cf_result" != yes; then
1063                 if test "${with_openssl-no}" != "no"; then
1064                         AC_MSG_ERROR([OpenSSL not found])
1065                 fi
1066                 EL_RESTORE_FLAGS
1067         else
1068                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1069                 chosen_ssl_library="OpenSSL"
1070
1071                 CFLAGS="$CFLAGS_X"
1072                 AC_SUBST(OPENSSL_CFLAGS)
1073         fi
1074 fi
1075
1076 AC_MSG_RESULT($cf_result)
1077
1078 # ---- GNU TLS
1079
1080 # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1081 # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1082 # ELinks will use its internal MD5 code instead.
1083 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1084
1085 if test "$with_gnutls" = no; then
1086         AC_MSG_CHECKING([[for GNUTLS]])
1087         AC_MSG_RESULT([[explicitly disabled]])
1088
1089 elif test -n "$chosen_ssl_library" && test "$chosen_ssl_library" != "GNUTLS"; then
1090         AC_MSG_CHECKING([[for GNUTLS]])
1091         AC_MSG_RESULT([[not used, because $chosen_ssl_library was chosen]])
1092
1093 else
1094         cf_result=no
1095         AC_MSG_CHECKING([[for GNUTLS (1.2 or later) in pkg-config]])
1096         if pkg-config --atleast-version=1.2 gnutls; then
1097                 GNUTLS_CFLAGS=`pkg-config --cflags gnutls`
1098                 GNUTLS_LIBS=`pkg-config --libs gnutls`
1099                 AC_MSG_RESULT([[yes: $GNUTLS_CFLAGS $GNUTLS_LIBS]])
1100
1101                 EL_SAVE_FLAGS
1102                 LIBS="$GNUTLS_LIBS $LIBS"
1103                 CFLAGS="$CFLAGS $GNUTLS_CFLAGS"
1104                 CPPFLAGS="$CPPFLAGS $GNUTLS_CFLAGS"
1105
1106                 # Verify if it's really usable.  gnutls_session was
1107                 # renamed to gnutls_session_t before GNU TLS 1.2.0
1108                 # (on 2004-06-13); ELinks now requires this.
1109                 AC_MSG_CHECKING([[whether GNUTLS can be linked with]])
1110                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]],
1111                                                 [[gnutls_session_t dummy;
1112                                                   gnutls_check_version(NULL)]])],
1113                                [cf_result=yes],
1114                                [cf_result=no])
1115                 AC_MSG_RESULT([[$cf_result]])
1116
1117                 if test "$cf_result" = yes; then
1118                         # According to gnutls/NEWS, the function was originally
1119                         # added as gnutls_set_default_priority2 in GNUTLS 2.1.4
1120                         # (released 2007-10-27) and then renamed to
1121                         # gnutls_priority_set_direct in GNUTLS 2.1.7 (released
1122                         # 2007-11-29).
1123                         AC_CHECK_FUNCS([gnutls_priority_set_direct])
1124                 fi
1125
1126                 EL_RESTORE_FLAGS
1127         else
1128                 AC_MSG_RESULT([[$cf_result]])
1129         fi
1130
1131         if test "$cf_result" = yes; then
1132                 EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1133                 chosen_ssl_library="GNUTLS"
1134
1135                 LIBS="$GNUTLS_LIBS $LIBS"
1136                 AC_SUBST(GNUTLS_CFLAGS)
1137
1138         elif test "${with_gnutls-no}" != "no"; then
1139                 AC_MSG_ERROR([[GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.]])
1140         fi
1141 fi
1142
1143 # Final SSL setup
1144
1145 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1146 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1147 AC_SUBST(CONFIG_OPENSSL)
1148 AC_SUBST(CONFIG_GNUTLS)
1149
1150 #endif
1151
1152 AC_MSG_CHECKING([whether to be or not to be])
1153 AC_MSG_RESULT([needs to be determined experimentally])
1154
1155 # ===================================================================
1156 # Check for IPv6 support and related functions.
1157 # ===================================================================
1158
1159 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1160 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1161 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1162
1163 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1164 if test "$HAVE_GETADDRINFO" != yes; then
1165         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1166         if test "$HAVE_GETADDRINFO" = yes; then
1167                 LIBS="$LIBS -linet6"
1168         fi
1169 fi
1170
1171
1172 # ===================================================================
1173 # Checking for X11 (window title restoring).
1174 # ===================================================================
1175
1176 AC_PATH_X
1177 if test x"$no_x" != xyes; then
1178         EL_SAVE_FLAGS
1179         if test -n "$x_includes"; then
1180                 X_CFLAGS="-I$x_includes"
1181                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1182                 CFLAGS="$CFLAGS $X_CFLAGS"
1183         fi
1184         if test -n "$x_libraries"; then
1185                 LDFLAGS="$LDFLAGS -L$x_libraries"
1186         fi
1187         LIBS="-lX11 $LIBS"
1188         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1189         EL_RESTORE_FLAGS
1190         if test "$cf_result" = yes; then
1191                 if test -n "$x_libraries"; then
1192                         LDFLAGS="$LDFLAGS -L$x_libraries"
1193                 fi
1194                 LIBS="-lX11 $LIBS"
1195                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1196                 AC_SUBST(X_CFLAGS)
1197         fi
1198 fi
1199
1200
1201 # ===================================================================
1202 # Backtraces displaying support.
1203 # ===================================================================
1204
1205 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1206 # possible checks for other system-specific means go here
1207
1208
1209 # ===================================================================
1210 # Gettext grey zone. Beware.
1211 # ===================================================================
1212
1213 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1214
1215 AM_GNU_GETTEXT
1216
1217 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1218 dnl # f33r d4 l33t... I hope it's portable. :)
1219 dnl cf_result=$((48#z - 48#a + 1));
1220 dnl AC_MSG_RESULT($cf_result)
1221
1222
1223 # ===================================================================
1224 # Compile-time features control
1225 # ===================================================================
1226
1227 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1228               [  --disable-cookies       disable cookie support])
1229
1230 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1231               [  --disable-formhist      disable form history support])
1232
1233 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1234               [  --disable-globhist      disable global history support])
1235
1236
1237 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1238               [  --disable-mailcap       disable mailcap support])
1239
1240 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1241               [  --disable-mimetypes     disable mimetypes files support])
1242
1243
1244 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1245               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1246               [IPv6],
1247               [  --disable-ipv6          disable IPv6 support])
1248
1249 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1250               [  --enable-bittorrent     enable BitTorrent protocol support])
1251
1252 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1253               [  --disable-data          disable data protocol support])
1254
1255 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1256               [  --disable-uri-rewrite   disable URI rewrite support])
1257
1258 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1259               [  --enable-cgi            enable local CGI support])
1260
1261 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1262               [  --enable-finger         enable finger protocol support])
1263
1264 # ===================================================================
1265 # FSP protocol
1266 # ===================================================================
1267 EL_SAVE_FLAGS
1268
1269 if test "x${enable_fsp}" != xno; then
1270         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1271
1272         if test "$HAVE_FSPLIB" = yes; then
1273                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1274                 if test "$HAVE_FSPLIB" = yes; then
1275                         LIBS="$LIBS -lfsplib"
1276                 else
1277                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1278                         if test "$HAVE_FSPLIB" = yes; then
1279                                 LIBS="$LIBS -lfsp"
1280                         fi
1281                 fi
1282         fi
1283 fi
1284
1285 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1286               [  --enable-fsp            enable FSP protocol support])
1287
1288 if test "x$CONFIG_FSP" = xno; then
1289         EL_RESTORE_FLAGS
1290 fi
1291
1292 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1293               [  --disable-ftp           disable ftp protocol support])
1294
1295 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1296               [  --enable-gopher         enable gopher protocol support])
1297
1298 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1299               [  --enable-nntp           enable nntp protocol support])
1300
1301 # ===================================================================
1302 # SMB protocol support.
1303 # ===================================================================
1304 EL_SAVE_FLAGS
1305
1306 if test "x${enable_smb}" != xno; then
1307         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1308
1309         if test "$HAVE_SMBCLIENT" = yes; then
1310                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1311                 if test "$HAVE_SMBCLIENT" = yes; then
1312                         LIBS="$LIBS -lsmbclient"
1313                 fi
1314         fi
1315 fi
1316
1317 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1318               [  --enable-smb            enable Samba protocol support])
1319
1320 if test "x$CONFIG_SMB" = xno; then
1321         EL_RESTORE_FLAGS
1322 fi
1323
1324
1325 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1326               [  --disable-mouse         disable mouse support])
1327
1328 # GPM mouse is Linux specific, so ...
1329 CONFIG_SYSMOUSE=yes
1330 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1331               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1332               [BSD sysmouse],
1333               [  --disable-sysmouse      disable BSD sysmouse support])
1334
1335 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1336               [  --enable-88-colors      enable 88 color support])
1337
1338 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1339               [  --enable-256-colors     enable 256 color support])
1340
1341 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1342               [  --enable-true-color     enable true color support])
1343
1344 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1345               [  --enable-exmode         enable exmode (CLI) interface])
1346
1347 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1348               [  --disable-leds          disable LEDs support])
1349
1350 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1351               [  --disable-marks         disable document marks support])
1352
1353
1354 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1355               [  --disable-css           disable Cascading Style Sheet support])
1356
1357 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1358               [  --enable-html-highlight HTML highlighting using DOM engine])
1359
1360 # Everything in the tree already uses CONFIG_DOM
1361 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1362 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1363
1364 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1365               [  --disable-backtrace     disable backtrace support])
1366
1367 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1368               [  --enable-no-root        enable prevention of usage by root])
1369
1370
1371 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1372               [  --enable-debug          enable leak debug and internal error checking])
1373
1374 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1375               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1376
1377 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1378               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1379
1380 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1381               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1382
1383 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1384               [  --disable-utf-8         disable UTF-8 support])
1385
1386
1387 AC_ARG_ENABLE(weehoofooboomookerchoo,
1388               [
1389     Also check out the features.conf file for more information about features!
1390               ],
1391               [AC_MSG_ERROR(Are you strange, or what?)])
1392
1393
1394 # ===================================================================
1395 # Decide whether to use TRE
1396 # ===================================================================
1397 #
1398 # This must be done after the CONFIG_UTF8 check above.
1399 # The first part of the TRE check is separate, to get
1400 # the configure --help output in a sensible order.
1401 #
1402 # After this section, nothing else must be added to the
1403 # beginning of $LIBS.
1404
1405 if test "$tre_log" = "available"; then
1406         if test "$CONFIG_UTF8" = "yes"; then
1407                 # When CONFIG_UTF8 and CONFIG_TRE are both defined,
1408                 # src/viewer/text/search.c makes a string of
1409                 # unicode_val_T and gives it to regwexec(), which
1410                 # expects a string of wchar_t.  If the unicode_val_T
1411                 # and wchar_t types are too different, this won't
1412                 # work, so try to detect that and disable regexp
1413                 # operations entirely in that case.
1414                 #
1415                 # Currently, this code only compares the sizes of the
1416                 # types.  src/intl/charsets.h defines unicode_val_T as
1417                 # uint32_t, so we check whether wchar_t has exactly 32
1418                 # bits.  But don't use AC_CHECK_SIZEOF for this, because
1419                 # there doesn't seem to be a documented way to get the
1420                 # result of that for use in the configure script.
1421                 #
1422                 # C99 says the implementation can define
1423                 # __STDC_ISO_10646__ if wchar_t values match ISO 10646
1424                 # (or Unicode) numbers in all locales.  Do not check
1425                 # that macro here, because it is too restrictive: it
1426                 # should be enough for ELinks if the values match in
1427                 # the locales where ELinks is actually run.
1428                 AC_MSG_CHECKING([[whether wchar_t is exactly 32-bit]])
1429                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1430 #include <limits.h>
1431 #include <stddef.h>
1432 int dummy[(sizeof(wchar_t) * CHAR_BIT == 32) ? 1 : -1];]], [])],
1433                         [AC_MSG_RESULT([[yes]])
1434                          tre_log="TRE"],
1435                         [AC_MSG_RESULT([[no]])
1436                          tre_log="no (unsuitable wchar_t)"])
1437         else
1438                 # If UTF-8 is not used, then wchar_t doesn't matter.
1439                 tre_log="TRE"
1440         fi
1441 fi
1442
1443 if test "$tre_log" = "TRE"; then
1444         AC_DEFINE([CONFIG_TRE], [1],
1445                 [Define as 1 to use the TRE library for regular expression searching.  This requires the <tre/regex.h> header file.  If you define CONFIG_UTF8 too, then wchar_t must be exactly 32-bit so that it matches unicode_val_T.])
1446         # TRE_CFLAGS will be used only where needed.
1447         #
1448         # Bug 1081: If both TRE and libc define the regfree function,
1449         # ELinks needs to use the version defined by TRE because
1450         # that's the one compatible with regex_t initialized by the
1451         # regwcomp function of TRE.  Therefore put $TRE_LIBS at the
1452         # very beginning of $LIBS so that the linker hopefully finds
1453         # regfree there before it examines libc.  In particular,
1454         # $PERL_LIBS appears to often include "-lc".
1455         #
1456         # This scheme still risks a crash if ELinks is linked with
1457         # some static library that uses GNU <regex.h> extensions that
1458         # TRE does not implement.  For example, the library might call
1459         # re_compile_pattern, which is found in GNU libc, and then
1460         # regfree, which is found in TRE and probably crashes with the
1461         # GNU-initialized regex_t.  Ways to avoid such crashes:
1462         #
1463         # - Change TRE so it defines only tre_... functions and does
1464         #   not attempt to override the POSIX names by default.
1465         #
1466         # - Change ELinks to access TRE only via dlopen and dlsym.
1467         #   The problem then is how to find the correct file name.
1468         #   There might be libtre.so.4 and libtre.so.5 with different
1469         #   ABI.  How can this configure script detect which of them
1470         #   matches the <tre/regex.h> in the include path?
1471         #
1472         # - Replace the static library with a shared library.  At
1473         #   least on GNU/Linux, when the shared library is built, the
1474         #   linker should note that e.g. regfree is defined in libc
1475         #   and has the GLIBC_2.0 version there, and write that
1476         #   version string to the shared library as well; because TRE
1477         #   does not provide regfree with that version, any regfree
1478         #   calls at run time should then get resolved to libc.
1479         LIBS="$TRE_LIBS $LIBS"
1480 else
1481         TRE_LIBS=
1482         TRE_CFLAGS=
1483 fi
1484 AC_SUBST(TRE_CFLAGS)
1485 AC_SUBST(TRE_LIBS)
1486 EL_LOG_CONFIG([CONFIG_TRE], [[Regexp searching]], [[$tre_log]])
1487
1488
1489 # ===================================================================
1490 # Further LDFLAGS tweaks
1491 # ===================================================================
1492
1493 # == EMX hack
1494
1495 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1496 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1497
1498
1499 # Check for -rdynamic
1500 #
1501 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1502 # the executable to its dynamic symbol table.  ELinks uses this for
1503 # two purposes:
1504 #
1505 # 1. If ELinks detects a bug, it can try to display a backtrace by
1506 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1507 #    manual states users of GNU ld must pass -rdynamic to make the
1508 #    symbols available to the program.
1509 #
1510 # 2. It would eventually be nice to dynamically load shared
1511 #    libraries as plugins (bug 73).  The plugins must be able to
1512 #    call ELinks functions.  This can be implemented either by
1513 #    registering all callable functions in ELinks-specific data
1514 #    structures, or by letting the dynamic linker handle them.
1515 #    The latter way requires something equivalent to -rdynamic.
1516 #
1517 # Because backtraces are not needed for correct operation, and bug
1518 # 73 is not yet being fixed, the configure script and makefiles
1519 # should not complain to the user if they find that -rdynamic does
1520 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1521 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1522 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1523 # -rdynamic but does something equivalent automatically.  (This was
1524 # tested with "nm -D elinks | grep redraw_from_window".)
1525 #
1526 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1527 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1528 # linker from finding the libraries listed in -l operands.  So this
1529 # -rdynamic check needs to happen after the libraries have already
1530 # been added to $LDFLAGS.
1531 AC_MSG_CHECKING([for -rdynamic])
1532 LDFLAGS_X="$LDFLAGS"
1533 LDFLAGS="-rdynamic $LDFLAGS"
1534 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1535 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1536 AC_MSG_RESULT($have_rdynamic)
1537
1538 # ===================================================================
1539 # Export directory paths
1540 # ===================================================================
1541
1542 # Set up the ``entry points'' if they were not supplied by builder
1543 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1544 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1545
1546 # Create CONFDIR #define for config.h
1547
1548 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1549 # it's autoconf fault to force us to do such hacks ;p.
1550 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1551   # sysconfdir is set to its default value... fine, let's append /elinks/
1552   # XXX: We can't modify listing of the default in ./configure --help :-(
1553   sysconfdir_n=`eval echo "$sysconfdir"`
1554   sysconfdir=$sysconfdir_n
1555   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1556         sysconfdir="$sysconfdir/elinks"
1557 fi
1558
1559 CONFDIR=$sysconfdir
1560 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1561 AC_SUBST(CONFDIR)
1562
1563 # Create LOCALEDIR #define for config.h
1564 LOCALEDIR=`eval echo "$datadir/locale"`
1565 while echo "$LOCALEDIR" | grep "\\$"
1566 do
1567         LOCALEDIR=`eval echo "$LOCALEDIR"`
1568 done > /dev/null 2> /dev/null
1569 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1570 AC_SUBST(LOCALEDIR)
1571
1572 # Create LIBDIR #define for config.h
1573 LIBDIR=`eval echo "$libdir"`
1574 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1575 AC_SUBST(LIBDIR)
1576
1577 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1578 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1579
1580
1581 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1582 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1583         #error not tcc
1584         #endif ]])],[cf_result=yes],[cf_result=no])
1585
1586 if test "$cf_result" = "yes"; then
1587         AC_DEFINE([HAVE_ALLOCA])
1588         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1589                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1590                 override the alloca macro defined in <stddef.h> of TCC.
1591                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1592                 it has already been included, and does not redefine alloca.
1593                 This might not work in future glibc versions though, because
1594                 the names of the #include guard macros are not documented.
1595                 The incompatibility has been reported to the tinycc-devel
1596                 mailing list on 2008-07-14.  If a future version of TCC provides
1597                 an <alloca.h> of its own, this hack won't be needed.])
1598 fi
1599 # ===================================================================
1600 # A little fine tuning of gcc specific options (continued)
1601 # ===================================================================
1602
1603 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1604   if test "$CONFIG_DEBUG" = "yes"; then
1605     # We want to see all warnings and live with none (in debug mode).
1606     CFLAGS="$CFLAGS -Werror"
1607   fi
1608
1609   case "`$CC -dumpversion`" in
1610     3.0|3.1|3.2)
1611       # These should be ok using -Werror
1612       ;;
1613     3.*)
1614       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1615       # "dereferencing type-punned pointer will break strict-aliasing rules"
1616       # warnings. Disable them by not doing any strict-aliasing. The
1617       # alternative is just too ugly. Thanks gcc guys!! ;)
1618       CFLAGS="$CFLAGS -fno-strict-aliasing"
1619       ;;
1620     4.*)
1621       # Do not show warnings related to (char * | unsigned char *) type
1622       # difference.
1623       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1624       ;;
1625     *)
1626       # These should be ok using -Werror
1627       ;;
1628   esac
1629
1630   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1631   # warning: the address of `builtin_modules' will always evaluate as `true'
1632   # This hits the object_lock and foreach_module macros in particular.
1633   # It would be okay to put something in the macros to avoid the warning,
1634   # but currently this seems to require defining parallel macros that skip
1635   # the NULL check, and that's too ugly.  So we instead disable the warning.
1636   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1637   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1638   for warning_flag in -Wno-address -Wno-always-true; do
1639     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1640     EL_SAVE_FLAGS
1641     CFLAGS="$CFLAGS $warning_flag"
1642     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1643       [AC_MSG_RESULT([yes])
1644        break],
1645       [AC_MSG_RESULT([no])])
1646     EL_RESTORE_FLAGS
1647   done
1648
1649   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1650   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1651   # "warning: assuming signed overflow does not occur when assuming
1652   # that (X + c) > X is always true", which may be an incorrect
1653   # optimization (although allowed by the standard), and breaks the
1654   # build with -Werror.
1655   #
1656   # All of the following tests included -S -Wall -Wextra:
1657   #
1658   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1659   # * gcc-4.0 -O0: OK, compares the values
1660   # * gcc-4.0 -O2: assumes no overflow, does not warn
1661   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1662   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1663   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1664   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1665   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1666   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1667   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1668   #
1669   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1670   # * gcc-4.1 -O0: assumes no overflow, does not warn
1671   # * gcc-4.1 -O2: assumes no overflow, does not warn
1672   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1673   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1674   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1675   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1676   # * gcc-4.1 -O2 -ftrapv: compares the values
1677   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1678   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1679   #
1680   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1681   # * gcc-4.2 -O0: OK, compares the values
1682   # * gcc-4.2 -O2: assumes no overflow, warns about it
1683   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1684   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1685   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1686   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1687   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1688   # * gcc-4.2 -O2 -ftrapv: compares the values
1689   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1690   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1691   #
1692   # Apparently, -ftrapv does not work reliably at all.
1693   for overflow_flag in -fno-strict-overflow -fwrapv; do
1694     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1695     EL_SAVE_FLAGS
1696     CFLAGS="$CFLAGS $overflow_flag"
1697     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1698       [AC_MSG_RESULT([yes])
1699        break],
1700       [AC_MSG_RESULT([no])])
1701     EL_RESTORE_FLAGS
1702   done
1703 fi
1704
1705 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1706 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1707 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1708 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1709
1710 # ===================================================================
1711 # Colored make output
1712 # ===================================================================
1713
1714 if test $(`which tput` colors) -ge 4; then
1715         MAKE_COLOR=1
1716         AC_SUBST(MAKE_COLOR)
1717 fi
1718
1719 # ===================================================================
1720 # Generated files
1721 # ===================================================================
1722
1723 AC_CONFIG_FILES([ \
1724  Makefile.config \
1725  contrib/elinks.spec \
1726  contrib/lua/hooks.lua \
1727  contrib/conv/w3m2links.awk \
1728  doc/Doxyfile \
1729  doc/man/man1/elinks.1 \
1730  src/intl/gettext/ref-add.sed \
1731  src/intl/gettext/ref-del.sed
1732 ])
1733 AC_OUTPUT
1734
1735 abs_srcdir="$(cd "$srcdir" && pwd)"
1736 # builddir is always absolute!
1737 if test "$abs_srcdir" != "$builddir"; then
1738         # Bootstrap the Makefile creation
1739         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1740         "$MAKE" "SRC=$abs_srcdir" init
1741
1742         # Make cg-status ignore this build directory
1743         echo "*" > "$builddir/.gitignore"
1744 fi
1745
1746 # ===================================================================
1747 # Configuration summary
1748 # ===================================================================
1749
1750 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1751 cat features.log