src/LAPACK/zung2l.f

   1       SUBROUTINE ZUNG2L( M, N, K, A, LDA, TAU, WORK, INFO )
   2 *
   3 *  -- LAPACK routine (version 3.1) --
   4 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
   5 *     November 2006
   6 *
   7 *     .. Scalar Arguments ..
   8       INTEGER            INFO, K, LDA, M, N
   9 *     ..
  10 *     .. Array Arguments ..
  11       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
  12 *     ..
  13 *
  14 *  Purpose
  15 *  =======
  16 *
  17 *  ZUNG2L generates an m by n complex matrix Q with orthonormal columns,
  18 *  which is defined as the last n columns of a product of k elementary
  19 *  reflectors of order m
  20 *
  21 *        Q  =  H(k) . . . H(2) H(1)
  22 *
  23 *  as returned by ZGEQLF.
  24 *
  25 *  Arguments
  26 *  =========
  27 *
  28 *  M       (input) INTEGER
  29 *          The number of rows of the matrix Q. M >= 0.
  30 *
  31 *  N       (input) INTEGER
  32 *          The number of columns of the matrix Q. M >= N >= 0.
  33 *
  34 *  K       (input) INTEGER
  35 *          The number of elementary reflectors whose product defines the
  36 *          matrix Q. N >= K >= 0.
  37 *
  38 *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  39 *          On entry, the (n-k+i)-th column must contain the vector which
  40 *          defines the elementary reflector H(i), for i = 1,2,...,k, as
  41 *          returned by ZGEQLF in the last k columns of its array
  42 *          argument A.
  43 *          On exit, the m-by-n matrix Q.
  44 *
  45 *  LDA     (input) INTEGER
  46 *          The first dimension of the array A. LDA >= max(1,M).
  47 *
  48 *  TAU     (input) COMPLEX*16 array, dimension (K)
  49 *          TAU(i) must contain the scalar factor of the elementary
  50 *          reflector H(i), as returned by ZGEQLF.
  51 *
  52 *  WORK    (workspace) COMPLEX*16 array, dimension (N)
  53 *
  54 *  INFO    (output) INTEGER
  55 *          = 0: successful exit
  56 *          < 0: if INFO = -i, the i-th argument has an illegal value
  57 *
  58 *  =====================================================================
  59 *
  60 *     .. Parameters ..
  61       COMPLEX*16         ONE, ZERO
  62       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ),
  63      $                   ZERO = ( 0.0D+0, 0.0D+0 ) )
  64 *     ..
  65 *     .. Local Scalars ..
  66       INTEGER            I, II, J, L
  67 *     ..
  68 *     .. External Subroutines ..
  69       EXTERNAL           XERBLA, ZLARF, ZSCAL
  70 *     ..
  71 *     .. Intrinsic Functions ..
  72       INTRINSIC          MAX
  73 *     ..
  74 *     .. Executable Statements ..
  75 *
  76 *     Test the input arguments
  77 *
  78       INFO = 0
  79       IF( M.LT.0 ) THEN
  80          INFO = -1
  81       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
  82          INFO = -2
  83       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
  84          INFO = -3
  85       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  86          INFO = -5
  87       END IF
  88       IF( INFO.NE.0 ) THEN
  89          CALL XERBLA( 'ZUNG2L', -INFO )
  90          RETURN
  91       END IF
  92 *
  93 *     Quick return if possible
  94 *
  95       IF( N.LE.0 )
  96      $   RETURN
  97 *
  98 *     Initialise columns 1:n-k to columns of the unit matrix
  99 *
 100       DO 20 J = 1, N - K
 101          DO 10 L = 1, M
 102             A( L, J ) = ZERO
 103    10    CONTINUE
 104          A( M-N+J, J ) = ONE
 105    20 CONTINUE
 106 *
 107       DO 40 I = 1, K
 108          II = N - K + I
 109 *
 110 *        Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
 111 *
 112          A( M-N+II, II ) = ONE
 113          CALL ZLARF( 'Left', M-N+II, II-1, A( 1, II ), 1, TAU( I ), A,
 114      $               LDA, WORK )
 115          CALL ZSCAL( M-N+II-1, -TAU( I ), A( 1, II ), 1 )
 116          A( M-N+II, II ) = ONE - TAU( I )
 117 *
 118 *        Set A(m-k+i+1:m,n-k+i) to zero
 119 *
 120          DO 30 L = M - N + II + 1, M
 121             A( L, II ) = ZERO
 122    30    CONTINUE
 123    40 CONTINUE
 124       RETURN
 125 *
 126 *     End of ZUNG2L
 127 *
 128       END