core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2009 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences arrays math sequences.private vectors
   4 accessors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: value-at* ( value assoc -- key/f ? )
  11 GENERIC: set-at ( value key assoc -- )
  12 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  13 GENERIC: delete-at ( key assoc -- )
  14 GENERIC: clear-assoc ( assoc -- )
  15 GENERIC: assoc-size ( assoc -- n )
  16 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  17 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  18 GENERIC: >alist ( assoc -- newassoc )
  19
  20 M: assoc assoc-like drop ;
  21
  22 <PRIVATE
  23
  24 : (assoc-each) ( assoc quot -- seq quot' )
  25     [ >alist ] dip [ first2 ] prepose ; inline
  26
  27 : (assoc-stack) ( key i seq -- value )
  28     over 0 < [
  29         3drop f
  30     ] [
  31         3dup nth-unsafe at*
  32         [ [ 3drop ] dip ] [ drop [ 1- ] dip (assoc-stack) ] if
  33     ] if ; inline recursive
  34
  35 : search-alist ( key alist -- pair/f i/f )
  36     [ first = ] with find swap ; inline
  37
  38 : substituter ( assoc -- quot )
  39     [ dupd at* [ nip ] [ drop ] if ] curry ; inline
  40
  41 PRIVATE>
  42
  43 : assoc-find ( assoc quot -- key value ? )
  44     (assoc-each) find swap [ first2 t ] [ drop f f f ] if ; inline
  45
  46 : key? ( key assoc -- ? ) at* nip ; inline
  47
  48 : assoc-each ( assoc quot -- )
  49     (assoc-each) each ; inline
  50
  51 : assoc>map ( assoc quot exemplar -- seq )
  52     [ accumulator [ assoc-each ] dip ] dip like ; inline
  53
  54 : assoc-map-as ( assoc quot exemplar -- newassoc )
  55     [ [ 2array ] compose V{ } assoc>map ] dip assoc-like ; inline
  56
  57 : assoc-map ( assoc quot -- newassoc )
  58     over assoc-map-as ; inline
  59
  60 : assoc-filter-as ( assoc quot exemplar -- subassoc )
  61     [ (assoc-each) filter ] dip assoc-like ; inline
  62
  63 : assoc-filter ( assoc quot -- subassoc )
  64     over assoc-filter-as ; inline
  65
  66 : assoc-partition ( assoc quot -- true-assoc false-assoc )
  67     [ (assoc-each) partition ] [ drop ] 2bi
  68     tuck [ assoc-like ] 2bi@ ; inline
  69
  70 : assoc-contains? ( assoc quot -- ? )
  71     assoc-find 2nip ; inline
  72
  73 : assoc-all? ( assoc quot -- ? )
  74     [ not ] compose assoc-contains? not ; inline
  75
  76 : at ( key assoc -- value/f )
  77     at* drop ; inline
  78
  79 : at-default ( key assoc -- value/key )
  80     2dup at* [ 2nip ] [ 2drop ] if ; inline
  81
  82 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
  83     [ dup assoc-size ] dip new-assoc
  84     [ [ swapd set-at ] curry assoc-each ] keep ;
  85
  86 : keys ( assoc -- keys )
  87     [ drop ] { } assoc>map ;
  88
  89 : values ( assoc -- values )
  90     [ nip ] { } assoc>map ;
  91
  92 : delete-at* ( key assoc -- old ? )
  93     [ at* ] 2keep delete-at ;
  94
  95 : rename-at ( newkey key assoc -- )
  96     [ delete-at* ] keep [ swapd set-at ] curry [ 2drop ] if ;
  97
  98 : assoc-empty? ( assoc -- ? )
  99     assoc-size 0 = ;
 100
 101 : assoc-stack ( key seq -- value )
 102     [ length 1- ] keep (assoc-stack) ; flushable
 103
 104 : assoc-subset? ( assoc1 assoc2 -- ? )
 105     [ swapd at* [ = ] [ 2drop f ] if ] curry assoc-all? ;
 106
 107 : assoc= ( assoc1 assoc2 -- ? )
 108     [ assoc-subset? ] [ swap assoc-subset? ] 2bi and ;
 109
 110 : assoc-hashcode ( n assoc -- code )
 111     >alist hashcode* ;
 112
 113 : assoc-intersect ( assoc1 assoc2 -- intersection )
 114     swap [ nip key? ] curry assoc-filter ;
 115
 116 : update ( assoc1 assoc2 -- )
 117     swap [ swapd set-at ] curry assoc-each ;
 118
 119 : assoc-union ( assoc1 assoc2 -- union )
 120     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 121     [ dupd update ] bi@ ;
 122
 123 : assoc-combine ( seq -- union )
 124     H{ } clone [ dupd update ] reduce ;
 125
 126 : assoc-diff ( assoc1 assoc2 -- diff )
 127     [ nip key? not ] curry assoc-filter ;
 128
 129 : remove-all ( assoc seq -- subseq )
 130     swap [ key? not ] curry filter ;
 131
 132 : substitute-here ( seq assoc -- )
 133     substituter change-each ;
 134
 135 : substitute ( seq assoc -- newseq )
 136     substituter map ;
 137
 138 : cache ( key assoc quot -- value )
 139     [ [ at* ] 2keep ] dip
 140     [ [ nip call dup ] [ drop ] 3bi set-at ] 3curry
 141     [ drop ] prepose
 142     unless ; inline
 143
 144 : 2cache ( key1 key2 assoc quot -- value )
 145     [ 2array ] 2dip [ first2 ] prepose cache ; inline
 146
 147 : change-at ( key assoc quot -- )
 148     [ [ at ] dip call ] [ drop ] 3bi set-at ; inline
 149
 150 : at+ ( n key assoc -- ) [ 0 or + ] change-at ; inline
 151
 152 : inc-at ( key assoc -- ) [ 1 ] 2dip at+ ; inline
 153
 154 : map>assoc ( seq quot exemplar -- assoc )
 155     [ [ 2array ] compose { } map-as ] dip assoc-like ; inline
 156
 157 : extract-keys ( seq assoc -- subassoc )
 158     [ [ dupd at ] curry ] keep map>assoc ;
 159
 160 M: assoc value-at* swap [ = nip ] curry assoc-find nip ;
 161
 162 : value-at ( value assoc -- key/f ) value-at* drop ;
 163
 164 : value? ( value assoc -- ? ) value-at* nip ;
 165
 166 : push-at ( value key assoc -- )
 167     [ ?push ] change-at ;
 168
 169 : zip ( keys values -- alist )
 170     2array flip ; inline
 171
 172 : unzip ( assoc -- keys values )
 173     dup assoc-empty? [ drop { } { } ] [ >alist flip first2 ] if ;
 174
 175 M: sequence at*
 176     search-alist [ second t ] [ f ] if ;
 177
 178 M: sequence set-at
 179     2dup search-alist
 180     [ 2nip set-second ]
 181     [ drop [ swap 2array ] dip push ] if ;
 182
 183 M: sequence new-assoc drop <vector> ;
 184
 185 M: sequence clear-assoc delete-all ;
 186
 187 M: sequence delete-at
 188     [ nip ] [ search-alist nip ] 2bi
 189     [ swap delete-nth ] [ drop ] if* ;
 190
 191 M: sequence assoc-size length ;
 192
 193 M: sequence assoc-clone-like
 194     [ >alist ] dip clone-like ;
 195
 196 M: sequence assoc-like
 197     [ >alist ] dip like ;
 198
 199 M: sequence >alist ;
 200
 201 ! Override sequence => assoc instance for f
 202 M: f clear-assoc drop ;
 203
 204 M: f assoc-like drop dup assoc-empty? [ drop f ] when ;
 205
 206 INSTANCE: sequence assoc
 207
 208 TUPLE: enum seq ;
 209
 210 C: <enum> enum
 211
 212 M: enum at*
 213     seq>> 2dup bounds-check?
 214     [ nth t ] [ 2drop f f ] if ;
 215
 216 M: enum set-at seq>> set-nth ;
 217
 218 M: enum delete-at seq>> delete-nth ;
 219
 220 M: enum >alist ( enum -- alist )
 221     seq>> [ length ] keep zip ;
 222
 223 M: enum assoc-size seq>> length ;
 224
 225 M: enum clear-assoc seq>> delete-all ;
 226
 227 INSTANCE: enum assoc