core/strings/strings.factor

   1 ! Copyright (C) 2003, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math.private sequences kernel.private
   4 math sequences.private slots.private byte-arrays
   5 alien.accessors ;
   6 IN: strings
   7
   8 <PRIVATE
   9
  10 : string-hashcode ( str -- n ) 3 slot ; inline
  11
  12 : set-string-hashcode ( n str -- ) 3 set-slot ; inline
  13
  14 : reset-string-hashcode ( str -- )
  15     f swap set-string-hashcode ; inline
  16
  17 : rehash-string ( str -- )
  18     1 over sequence-hashcode swap set-string-hashcode ; inline
  19
  20 : set-string-nth ( ch n str -- )
  21     pick HEX: 7f fixnum<=
  22     [ set-string-nth-fast ] [ set-string-nth-slow ] if ; inline
  23
  24 PRIVATE>
  25
  26 M: string equal?
  27     over string? [
  28         over hashcode over hashcode eq?
  29         [ sequence= ] [ 2drop f ] if
  30     ] [
  31         2drop f
  32     ] if ;
  33
  34 M: string hashcode*
  35     nip
  36     dup string-hashcode
  37     [ ] [ dup rehash-string string-hashcode ] ?if ;
  38
  39 M: string length
  40     length>> ;
  41
  42 M: string nth-unsafe
  43     [ >fixnum ] dip string-nth ;
  44
  45 M: string set-nth-unsafe
  46     dup reset-string-hashcode
  47     [ >fixnum ] [ >fixnum ] [ ] tri* set-string-nth ;
  48
  49 M: string clone
  50     (clone) [ clone ] change-aux ;
  51
  52 M: string resize resize-string ;
  53
  54 : 1string ( ch -- str ) 1 swap <string> ;
  55
  56 : >string ( seq -- str ) "" clone-like ;
  57
  58 M: string new-sequence drop 0 <string> ;
  59
  60 INSTANCE: string sequence