basis/base64/base64.factor

   1 ! Copyright (C) 2008 Doug Coleman, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators io io.binary io.encodings.binary
   4 io.streams.byte-array io.streams.string kernel math namespaces
   5 sequences strings io.crlf ;
   6 IN: base64
   7
   8 <PRIVATE
   9
  10 : read1-ignoring ( ignoring -- ch )
  11     read1 2dup swap member? [ drop read1-ignoring ] [ nip ] if ;
  12
  13 : read-ignoring ( ignoring n -- str )
  14     [ drop read1-ignoring ] with map harvest
  15     [ f ] [ >string ] if-empty ;
  16
  17 : ch>base64 ( ch -- ch )
  18     "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  19     nth ; inline
  20
  21 : base64>ch ( ch -- ch )
  22     {
  23         f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f f
  24         f f f f f f f f f f 62 f f f 63 52 53 54 55 56 57 58 59 60 61 f f
  25         f 0 f f f 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
  26         22 23 24 25 f f f f f f 26 27 28 29 30 31 32 33 34 35 36 37 38 39
  27         40 41 42 43 44 45 46 47 48 49 50 51
  28     } nth ; inline
  29
  30 SYMBOL: column
  31
  32 : write1-lines ( ch -- )
  33     write1
  34     column get [
  35         1+ [ 76 = [ crlf ] when ]
  36         [ 76 mod column set ] bi
  37     ] when* ;
  38
  39 : write-lines ( str -- )
  40     [ write1-lines ] each ;
  41
  42 : encode3 ( seq -- )
  43     be> 4 <reversed> [
  44         -6 * shift HEX: 3f bitand ch>base64 write1-lines
  45     ] with each ; inline
  46
  47 : encode-pad ( seq n -- )
  48     [ 3 0 pad-tail binary [ encode3 ] with-byte-writer ]
  49     [ 1+ ] bi* head-slice 4 CHAR: = pad-tail write-lines ; inline
  50
  51 ERROR: malformed-base64 ;
  52
  53 : decode4 ( seq -- )
  54     [ 0 [ base64>ch swap 6 shift bitor ] reduce 3 >be ]
  55     [ [ CHAR: = = ] count ] bi head-slice*
  56     [ write1 ] each ; inline
  57
  58 PRIVATE>
  59
  60 : encode-base64 ( -- )
  61     3 read dup length {
  62         { 0 [ drop ] }
  63         { 3 [ encode3 encode-base64 ] }
  64         [ encode-pad encode-base64 ]
  65     } case ;
  66
  67 : encode-base64-lines ( -- )
  68     0 column [ encode-base64 ] with-variable ;
  69
  70 : decode-base64 ( -- )
  71     "\n\r" 4 read-ignoring dup length {
  72         { 0 [ drop ] }
  73         { 4 [ decode4 decode-base64 ] }
  74         [ malformed-base64 ]
  75     } case ;
  76
  77 : >base64 ( seq -- base64 )
  78     binary [ [ encode-base64 ] with-string-reader ] with-byte-writer ;
  79
  80 : base64> ( base64 -- seq )
  81     [ binary [ decode-base64 ] with-byte-reader ] with-string-writer ;
  82
  83 : >base64-lines ( seq -- base64 )
  84     binary [ [ encode-base64-lines ] with-string-reader ] with-byte-writer ;