basis/furnace/syndication/syndication.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel sequences fry combinators syndication
   4 http.server.responses http.server.redirection furnace.actions
   5 furnace.utilities ;
   6 IN: furnace.syndication
   7
   8 GENERIC: feed-entry-title ( object -- string )
   9
  10 GENERIC: feed-entry-date ( object -- timestamp )
  11
  12 GENERIC: feed-entry-url ( object -- url )
  13
  14 GENERIC: feed-entry-description ( object -- description )
  15
  16 M: object feed-entry-description drop f ;
  17
  18 GENERIC: >entry ( object -- entry )
  19
  20 M: entry >entry ;
  21
  22 M: object >entry
  23     <entry>
  24         swap {
  25             [ feed-entry-title >>title ]
  26             [ feed-entry-date >>date ]
  27             [ feed-entry-url >>url ]
  28             [ feed-entry-description >>description ]
  29         } cleave ;
  30
  31 : process-entries ( seq -- seq' )
  32     20 short head-slice [
  33         >entry clone
  34         [ adjust-url ] change-url
  35     ] map ;
  36
  37 : <feed-content> ( body -- response )
  38     feed>xml "application/atom+xml" <content> ;
  39
  40 TUPLE: feed-action < action title url entries ;
  41
  42 : <feed-action> ( -- action )
  43     feed-action new-action
  44         dup '[
  45             feed new
  46                 _
  47                 [ title>> call >>title ]
  48                 [ url>> call adjust-url >>url ]
  49                 [ entries>> call process-entries >>entries ]
  50                 tri
  51             <feed-content>
  52         ] >>display ;