core/classes/classes.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays definitions assocs kernel kernel.private
   4 slots.private namespaces make sequences strings words words.symbol
   5 vectors math quotations combinators sorting effects graphs
   6 vocabs sets ;
   7 IN: classes
   8
   9 SYMBOL: class<=-cache
  10 SYMBOL: class-not-cache
  11 SYMBOL: classes-intersect-cache
  12 SYMBOL: class-and-cache
  13 SYMBOL: class-or-cache
  14 SYMBOL: next-method-quot-cache
  15
  16 : init-caches ( -- )
  17     H{ } clone class<=-cache set
  18     H{ } clone class-not-cache set
  19     H{ } clone classes-intersect-cache set
  20     H{ } clone class-and-cache set
  21     H{ } clone class-or-cache set
  22     H{ } clone next-method-quot-cache set ;
  23
  24 : reset-caches ( -- )
  25     class<=-cache get clear-assoc
  26     class-not-cache get clear-assoc
  27     classes-intersect-cache get clear-assoc
  28     class-and-cache get clear-assoc
  29     class-or-cache get clear-assoc
  30     next-method-quot-cache get clear-assoc ;
  31
  32 SYMBOL: update-map
  33
  34 SYMBOL: implementors-map
  35
  36 PREDICATE: class < word "class" word-prop ;
  37
  38 : classes ( -- seq ) implementors-map get keys ;
  39
  40 : predicate-word ( word -- predicate )
  41     [ name>> "?" append ] [ vocabulary>> ] bi create ;
  42
  43 PREDICATE: predicate < word "predicating" word-prop >boolean ;
  44
  45 M: predicate reset-word
  46     [ call-next-method ] [ { "predicating" } reset-props ] bi ;
  47
  48 : define-predicate ( class quot -- )
  49     [ "predicate" word-prop first ] dip
  50     (( object -- ? )) define-declared ;
  51
  52 : superclass ( class -- super )
  53     #! Output f for non-classes to work with algebra code
  54     dup class? [ "superclass" word-prop ] [ drop f ] if ;
  55
  56 : superclasses ( class -- supers )
  57     [ superclass ] follow reverse ;
  58
  59 : members ( class -- seq )
  60     #! Output f for non-classes to work with algebra code
  61     dup class? [ "members" word-prop ] [ drop f ] if ;
  62
  63 : participants ( class -- seq )
  64     #! Output f for non-classes to work with algebra code
  65     dup class? [ "participants" word-prop ] [ drop f ] if ;
  66
  67 GENERIC: rank-class ( class -- n )
  68
  69 GENERIC: reset-class ( class -- )
  70
  71 M: class reset-class
  72     {
  73         "class"
  74         "metaclass"
  75         "superclass"
  76         "members"
  77         "participants"
  78         "predicate"
  79     } reset-props ;
  80
  81 M: word reset-class drop ;
  82
  83 GENERIC: implementors ( class/classes -- seq )
  84
  85 ! update-map
  86 : class-uses ( class -- seq )
  87     [
  88         [ members % ]
  89         [ participants % ]
  90         [ superclass [ , ] when* ]
  91         tri
  92     ] { } make ;
  93
  94 : class-usage ( class -- seq ) update-map get at ;
  95
  96 : class-usages ( class -- seq ) [ class-usage ] closure keys ;
  97
  98 <PRIVATE
  99
 100 : update-map+ ( class -- )
 101     dup class-uses update-map get add-vertex ;
 102
 103 : update-map- ( class -- )
 104     dup class-uses update-map get remove-vertex ;
 105
 106 M: class implementors implementors-map get at keys ;
 107
 108 M: sequence implementors [ implementors ] gather ;
 109
 110 : implementors-map+ ( class -- )
 111     H{ } clone swap implementors-map get set-at ;
 112
 113 : implementors-map- ( class -- )
 114     implementors-map get delete-at ;
 115
 116 : make-class-props ( superclass members participants metaclass -- assoc )
 117     [
 118         {
 119             [ dup [ bootstrap-word ] when "superclass" set ]
 120             [ [ bootstrap-word ] map "members" set ]
 121             [ [ bootstrap-word ] map "participants" set ]
 122             [ "metaclass" set ]
 123         } spread
 124     ] H{ } make-assoc ;
 125
 126 : (define-class) ( word props -- )
 127     [
 128         dup class? [ dup [ implementors-map+ ] [ new-class ] bi ] unless
 129         dup reset-class
 130         dup deferred? [ dup define-symbol ] when
 131         dup redefined
 132         dup props>>
 133     ] dip assoc-union >>props
 134     dup predicate-word
 135     [ 1quotation "predicate" set-word-prop ]
 136     [ swap "predicating" set-word-prop ]
 137     [ drop t "class" set-word-prop ]
 138     2tri ;
 139
 140 PRIVATE>
 141
 142 GENERIC: update-class ( class -- )
 143
 144 M: class update-class drop ;
 145
 146 GENERIC: update-methods ( class seq -- )
 147
 148 : update-classes ( class -- )
 149     dup class-usages
 150     [ nip [ update-class ] each ] [ update-methods ] 2bi ;
 151
 152 : define-class ( word superclass members participants metaclass -- )
 153     #! If it was already a class, update methods after.
 154     reset-caches
 155     make-class-props
 156     [ drop update-map- ]
 157     [ (define-class) ]
 158     [ drop update-map+ ]
 159     2tri ;
 160
 161 : forget-predicate ( class -- )
 162     dup "predicate" word-prop
 163     dup length 1 = [
 164         first
 165         tuck "predicating" word-prop =
 166         [ forget ] [ drop ] if
 167     ] [ 2drop ] if ;
 168
 169 : forget-methods ( class -- )
 170     [ implementors ] [ [ swap 2array ] curry ] bi map forget-all ;
 171
 172 GENERIC: class-forgotten ( use class -- )
 173
 174 : forget-class ( class -- )
 175     {
 176         [ dup class-usage keys [ class-forgotten ] with each ]
 177         [ forget-predicate ]
 178         [ forget-methods ]
 179         [ implementors-map- ]
 180         [ update-map- ]
 181         [ reset-class ]
 182     } cleave
 183     reset-caches ;
 184
 185 M: class class-forgotten
 186     nip forget-class ;
 187
 188 M: class forget* ( class -- )
 189     [ call-next-method ] [ forget-class ] bi ;
 190
 191 GENERIC: class ( object -- class )
 192
 193 GENERIC: instance? ( object class -- ? ) flushable