core/effects/effects.factor

   1 ! Copyright (C) 2006, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math math.parser namespaces make sequences strings
   4 words assocs combinators accessors arrays ;
   5 IN: effects
   6
   7 TUPLE: effect in out terminated? ;
   8
   9 : <effect> ( in out -- effect )
  10     dup { "*" } sequence= [ drop { } t ] [ f ] if
  11     effect boa ;
  12
  13 : effect-height ( effect -- n )
  14     [ out>> length ] [ in>> length ] bi - ;
  15
  16 : effect<= ( eff1 eff2 -- ? )
  17     {
  18         { [ over terminated?>> ] [ t ] }
  19         { [ dup terminated?>> ] [ f ] }
  20         { [ 2dup [ in>> length ] bi@ > ] [ f ] }
  21         { [ 2dup [ effect-height ] bi@ = not ] [ f ] }
  22         [ t ]
  23     } cond 2nip ;
  24
  25 GENERIC: effect>string ( obj -- str )
  26 M: string effect>string ;
  27 M: word effect>string name>> ;
  28 M: integer effect>string number>string ;
  29 M: pair effect>string first2 [ effect>string ] bi@ ": " glue ;
  30
  31 : stack-picture ( seq -- string )
  32     dup integer? [ "object" <repetition> ] when
  33     [ [ effect>string % CHAR: \s , ] each ] "" make ;
  34
  35 M: effect effect>string ( effect -- string )
  36     [
  37         "( " %
  38         [ in>> stack-picture % "-- " % ]
  39         [ out>> stack-picture % ]
  40         [ terminated?>> [ "* " % ] when ]
  41         tri
  42         ")" %
  43     ] "" make ;
  44
  45 GENERIC: stack-effect ( word -- effect/f )
  46
  47 M: word stack-effect
  48     { "declared-effect" "inferred-effect" }
  49     swap props>> [ at ] curry map [ ] find nip ;
  50
  51 M: effect clone
  52     [ in>> clone ] [ out>> clone ] bi <effect> ;
  53
  54 : stack-height ( word -- n )
  55     stack-effect effect-height ;
  56
  57 : split-shuffle ( stack shuffle -- stack1 stack2 )
  58     in>> length cut* ;
  59
  60 : load-shuffle ( stack shuffle -- )
  61     in>> [ set ] 2each ;
  62
  63 : shuffled-values ( shuffle -- values )
  64     out>> [ get ] map ;
  65
  66 : shuffle ( stack shuffle -- newstack )
  67     [ [ load-shuffle ] keep shuffled-values ] with-scope ;