extra/webapps/wee-url/wee-url.factor

   1 ! Copyright (C) 2007 Doug Coleman.
   2 ! Copyright (C) 2008 Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: math.ranges sequences random accessors
   5 kernel namespaces fry db.types db.tuples urls validators
   6 html.components html.forms http http.server.dispatchers furnace
   7 furnace.actions furnace.boilerplate furnace.redirection
   8 furnace.utilities continuations ;
   9 IN: webapps.wee-url
  10
  11 TUPLE: wee-url < dispatcher ;
  12
  13 TUPLE: short-url short url ;
  14
  15 short-url "SHORT_URLS" {
  16     { "short" "SHORT" TEXT +user-assigned-id+ }
  17     { "url" "URL" TEXT +not-null+ }
  18 } define-persistent
  19
  20 : letter-bank ( -- seq )
  21     CHAR: a CHAR: z [a,b]
  22     CHAR: A CHAR: Z [a,b]
  23     CHAR: 1 CHAR: 0 [a,b]
  24     3append ; foldable
  25
  26 : random-url ( -- string )
  27     1 6 [a,b] random [ letter-bank random ] "" replicate-as ;
  28
  29 : insert-short-url ( short-url -- short-url )
  30     '[ _ dup random-url >>short insert-tuple ] 10 retry ;
  31
  32 : shorten ( url -- short )
  33     short-url new swap >>url dup select-tuple
  34     [ ] [ insert-short-url ] ?if short>> ;
  35
  36 : short>url ( short -- url )
  37     "$wee-url/go/" prepend >url adjust-url ;
  38
  39 : expand-url ( string -- url )
  40     short-url new swap >>short select-tuple url>> ;
  41
  42 : <shorten-action> ( -- action )
  43     <page-action>
  44         { wee-url "shorten" } >>template
  45         [ { { "url" [ v-url ] } } validate-params ] >>validate
  46         [
  47             "$wee-url/show/" "url" value shorten append >url <redirect>
  48         ] >>submit ;
  49
  50 : <show-action> ( -- action )
  51     <page-action>
  52         "short" >>rest
  53         [
  54             { { "short" [ v-one-word ] } } validate-params
  55             "short" value expand-url "url" set-value
  56             "short" value short>url "short" set-value
  57         ] >>init
  58         { wee-url "show" } >>template ;
  59
  60 : <go-action> ( -- action )
  61     <action>
  62         "short" >>rest
  63         [ { { "short" [ v-one-word ] } } validate-params ] >>init
  64         [ "short" value expand-url <redirect> ] >>display ;
  65
  66 : <wee-url> ( -- wee-url )
  67     wee-url new-dispatcher
  68         <shorten-action> "" add-responder
  69         <show-action> "show" add-responder
  70         <go-action> "go" add-responder
  71     <boilerplate>
  72         { wee-url "wee-url" } >>template ;