basis/ui/tools/walker/walker.factor

   1 ! Copyright (C) 2006, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel concurrency.messaging inspector
   4 ui.tools.listener ui.tools.traceback ui.gadgets.buttons
   5 ui.gadgets.status-bar ui.gadgets.tracks ui.commands ui.gadgets
   6 models models.filter ui.tools.workspace ui.gestures
   7 ui.gadgets.labels ui threads namespaces make tools.walker assocs
   8 combinators fry ;
   9 IN: ui.tools.walker
  10
  11 TUPLE: walker-gadget < track
  12 status continuation thread
  13 traceback
  14 closing? ;
  15
  16 : walker-command ( walker msg -- )
  17     swap
  18     dup thread>> thread-registered?
  19     [ thread>> send-synchronous drop ]
  20     [ 2drop ]
  21     if ;
  22
  23 : com-step ( walker -- ) step walker-command ;
  24
  25 : com-into ( walker -- ) step-into walker-command ;
  26
  27 : com-out ( walker -- ) step-out walker-command ;
  28
  29 : com-back ( walker -- ) step-back walker-command ;
  30
  31 : com-continue ( walker -- ) step-all walker-command ;
  32
  33 : com-abandon ( walker -- ) abandon walker-command ;
  34
  35 M: walker-gadget ungraft*
  36     [ t >>closing? drop ] [ com-continue ] [ call-next-method ] tri ;
  37
  38 M: walker-gadget focusable-child*
  39     traceback>> ;
  40
  41 : walker-state-string ( status thread -- string )
  42     [
  43         "Thread: " %
  44         dup name>> %
  45         " (" %
  46         swap {
  47             { +stopped+ "Stopped" }
  48             { +suspended+ "Suspended" }
  49             { +running+ "Running" }
  50         } at %
  51         ")" %
  52         drop
  53     ] "" make ;
  54
  55 : <thread-status> ( model thread -- gadget )
  56     '[ _ walker-state-string ] <filter> <label-control> ;
  57
  58 : <walker-gadget> ( status continuation thread -- gadget )
  59     { 0 1 } walker-gadget new-track
  60         swap >>thread
  61         swap >>continuation
  62         swap >>status
  63         dup continuation>> <traceback-gadget> >>traceback
  64
  65         add-toolbar
  66         dup status>> self <thread-status> f track-add
  67         dup traceback>> 1 track-add ;
  68
  69 : walker-help ( -- ) "ui-walker" help-window ;
  70
  71 \ walker-help H{ { +nullary+ t } } define-command
  72
  73 walker-gadget "toolbar" f {
  74     { T{ key-down f f "s" } com-step }
  75     { T{ key-down f f "i" } com-into }
  76     { T{ key-down f f "o" } com-out }
  77     { T{ key-down f f "b" } com-back }
  78     { T{ key-down f f "c" } com-continue }
  79     { T{ key-down f f "a" } com-abandon }
  80     { T{ key-down f f "d" } close-window }
  81     { T{ key-down f f "F1" } walker-help }
  82 } define-command-map
  83
  84 : walker-for-thread? ( thread gadget -- ? )
  85     {
  86         { [ dup walker-gadget? not ] [ 2drop f ] }
  87         { [ dup closing?>> ] [ 2drop f ] }
  88         [ thread>> eq? ]
  89     } cond ;
  90
  91 : find-walker-window ( thread -- world/f )
  92     '[ _ swap walker-for-thread? ] find-window ;
  93
  94 : walker-window ( status continuation thread -- )
  95     [ <walker-gadget> ] [ name>> ] bi open-status-window ;
  96
  97 [
  98     dup find-walker-window dup
  99     [ raise-window 3drop ] [ drop [ walker-window ] with-ui ] if
 100 ] show-walker-hook set-global