core/libs/libpng-1.2.18/configure.ac

   1 # configure.ac
   2
   3 dnl Process this file with autoconf to produce a configure script.
   4 dnl
   5 dnl Minor upgrades (compatible ABI): increment the package version
   6 dnl (third field in two places below) and set the PNGLIB_RELEASE
   7 dnl variable.
   8 dnl
   9 dnl Major upgrades (incompatible ABI): increment the package major
  10 dnl version (second field, or first if desired), set the minor
  11 dnl to 0, set PNGLIB_MAJOR below *and* follow the instructions in
  12 dnl Makefile.am to upgrade the package name.
  13
  14 dnl This is here to prevent earlier autoconf from being used, it
  15 dnl should not be necessary to regenerate configure if the time
  16 dnl stamps are correct
  17 AC_PREREQ(2.59)
  18
  19 dnl Version number stuff here:
  20
  21 AC_INIT([libpng], [1.2.18], [png-mng-implement@lists.sourceforge.net])
  22 AM_INIT_AUTOMAKE
  23 dnl stop configure from automagically running automake
  24 AM_MAINTAINER_MODE
  25
  26 PNGLIB_VERSION=1.2.18
  27 PNGLIB_MAJOR=1
  28 PNGLIB_MINOR=2
  29 PNGLIB_RELEASE=18
  30
  31 dnl End of version number stuff
  32
  33 AC_CONFIG_SRCDIR([pngget.c])
  34 AM_CONFIG_HEADER(config.h)
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_LD
  39 AC_PROG_CPP
  40 AC_CHECK_TOOL(SED, sed, :)
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43 AC_PROG_MAKE_SET
  44 AC_PROG_LIBTOOL
  45
  46 # Checks for header files.
  47 AC_HEADER_STDC
  48 AC_CHECK_HEADERS([malloc.h stdlib.h string.h strings.h])
  49
  50 # Checks for typedefs, structures, and compiler characteristics.
  51 AC_C_CONST
  52 AC_TYPE_SIZE_T
  53 AC_STRUCT_TM
  54
  55 # Checks for library functions.
  56 AC_FUNC_STRTOD
  57 AC_CHECK_FUNCS([memset], , AC_ERROR([memset not found in libc]))
  58 AC_CHECK_FUNCS([pow], , AC_CHECK_LIB(m, pow, , AC_ERROR([cannot find pow])) )
  59 AC_CHECK_LIB(z, zlibVersion, , AC_ERROR([zlib not installed]))
  60
  61 LIBPNG_DEFINES=-DPNG_CONFIGURE_LIBPNG
  62 AC_MSG_CHECKING(
  63   [if assembler code in pnggccrd.c can be compiled without PNG_NO_MMX_CODE])
  64 AC_TRY_COMPILE(
  65   [#include "pnggccrd.c"],
  66   [return 0;],
  67   AC_MSG_RESULT(yes)
  68   LIBPNG_NO_MMX="",
  69   AC_MSG_RESULT(no)
  70   LIBPNG_NO_MMX=-DPNG_NO_MMX_CODE)
  71 LIBPNG_DEFINES=$LIBPNG_DEFINES\ $LIBPNG_NO_MMX
  72 AC_SUBST(LIBPNG_DEFINES)
  73 AC_SUBST(LIBPNG_NO_MMX)
  74
  75 AC_MSG_CHECKING([if libraries can be versioned])
  76 GLD=`$LD --help < /dev/null 2>/dev/null | grep version-script`
  77 if test "$GLD"; then
  78     have_ld_version_script=yes
  79     AC_MSG_RESULT(yes)
  80 else
  81     have_ld_version_script=no
  82     AC_MSG_RESULT(no)
  83     AC_MSG_WARN(*** You have not enabled versioned symbols.)
  84 fi
  85 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
  86
  87 # Substitutions for .in files
  88 AC_SUBST(PNGLIB_VERSION)
  89 AC_SUBST(PNGLIB_MAJOR)
  90 AC_SUBST(PNGLIB_MINOR)
  91 AC_SUBST(PNGLIB_RELEASE)
  92
  93 # Additional arguments (and substitutions)
  94 # Allow the pkg-config directory to be set
  95 AC_ARG_WITH(pkgconfigdir,
  96         AC_HELP_STRING([--with-pkgconfigdir],
  97         [Use the specified pkgconfig dir (default is libdir/pkgconfig)]),
  98         [pkgconfigdir=${withval}],
  99         [pkgconfigdir='${libdir}/pkgconfig'])
 100
 101 AC_SUBST([pkgconfigdir])
 102 AC_MSG_NOTICE([pkgconfig directory is ${pkgconfigdir}])
 103
 104 # Make the *-config binary config scripts optional
 105 AC_ARG_WITH(binconfigs,
 106         AC_HELP_STRING([--with-binconfigs],
 107                 [Generate shell libpng-config scripts as well as pkg-config data]
 108                 [@<:@default=yes@:>@]),
 109         [if test "${withval}" = no; then
 110                 binconfigs=
 111                 AC_MSG_NOTICE([libpng-config scripts will not be built])
 112         else
 113                 binconfigs='${binconfigs}'
 114         fi],
 115         [binconfigs='${binconfigs}'])
 116 AC_SUBST([binconfigs])
 117
 118 # Allow the old version number library, libpng.so, to be removed from
 119 # the build
 120 AC_ARG_WITH(libpng-compat,
 121         AC_HELP_STRING([--with-libpng-compat],
 122                 [Generate the obsolete libpng.so library @<:@default=yes@:>@]),
 123         [if test "${withval}" = no; then
 124                 compatlib=
 125                 AC_MSG_NOTICE([libpng.so will not be built])
 126         else
 127                 compatlib=libpng.la
 128         fi],
 129         [compatlib=libpng.la])
 130 AC_SUBST([compatlib])
 131
 132 # Config files, substituting as above
 133 AC_CONFIG_FILES([Makefile libpng.pc:scripts/libpng.pc-configure.in])
 134 AC_CONFIG_FILES([libpng-config:scripts/libpng-config.in],
 135                 [chmod +x libpng-config])
 136
 137 AC_OUTPUT