libffado/tests/SConscript

   1 #
   2 # Copyright (C) 2007-2008 Arnold Krille
   3 # Copyright (C) 2007-2008 Pieter Palmers
   4 #
   5 # This file is part of FFADO
   6 # FFADO = Free Firewire (pro-)audio drivers for linux
   7 #
   8 # FFADO is based upon FreeBoB.
   9 #
  10 # This program is free software: you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation, either version 2 of the License, or
  13 # (at your option) version 3 of the License.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22 #
  23
  24 Import( 'env' )
  25
  26 env = env.Clone()
  27
  28 env.MergeFlags( "-I#/ -I#/src -L%ssrc -lffado" % env['build_base'] )
  29
  30 if not env.GetOption( "clean" ):
  31         env.MergeFlags( "-lpthread" )
  32         env.MergeFlags( env['LIBIEC61883_FLAGS'] )
  33         env.MergeFlags( env['LIBRAW1394_FLAGS'] )
  34         if not env['SERIALIZE_USE_EXPAT']:
  35                 env.MergeFlags( env['LIBXML26_FLAGS'] )
  36         else:
  37                 env.PrependUnique( LIBS=["expat"] )
  38
  39 static_env = env.Clone()
  40
  41 #
  42 # deactivate as they don't seem ported to the new api: test-extplugcmd,
  43 # test-mixer, test-volume
  44 #
  45 apps = {
  46         "ffado-test" : "test-ffado.cpp",
  47         "test-fw410" : "test-fw410.cpp",
  48         #"test-extplugcmd" : "test-extplugcmd.cpp",
  49         #"test-mixer" : "test-mixer.cpp",
  50         "test-timestampedbuffer" : "test-timestampedbuffer.cpp",
  51         "test-ieee1394service" : "test-ieee1394service.cpp",
  52         "test-streamdump" : "test-streamdump.cpp",
  53         "test-bufferops" : "test-bufferops.cpp",
  54         "test-watchdog" : "test-watchdog.cpp",
  55         "test-messagequeue" : "test-messagequeue.cpp",
  56         "test-shm" : "test-shm.cpp",
  57         "test-ipcringbuffer" : "test-ipcringbuffer.cpp",
  58         "test-devicestringparser" : "test-devicestringparser.cpp",
  59         "dumpiso_mod" : "dumpiso_mod.cpp",
  60         "scan-devreg" : "scan-devreg.cpp",
  61         "test-cycle-time" : "test-cycle-time.c"
  62 }
  63
  64 if env['ENABLE_BEBOB']:
  65         apps.update( { "test-focusrite" : "test-focusrite.cpp" } )
  66 if env['ENABLE_GENERICAVC']:
  67         if env.has_key("ALSA_FLAGS") and env["ALSA_FLAGS"]:
  68                 env.MergeFlags( env["ALSA_FLAGS"] )
  69                 apps.update( { "test-scs" : "test-scs.cpp" } )
  70         apps.update( { "test-volume" : "test-volume.cpp" } )
  71         apps.update( { "test-enhanced-mixer" : "test-enhanced-mixer.cpp" } )
  72         # MB: utility to unmute M-Audio Ozonic
  73         apps.update( { "unmute-ozonic" : "unmute-ozonic.cpp" } )
  74         apps.update( { "test-avccmd" : "test-avccmd.cpp" } )
  75 if env['ENABLE_FIREWORKS']:
  76         apps.update( { "test-echomixer" : "test-echomixer.cpp" } )
  77 if env['ENABLE_DICE']:
  78         apps.update( { "test-dice-eap" : "test-dice-eap.cpp" } )
  79         apps.update( { "set-default-router-config-dice-eap" : "set-default-router-config-dice-eap.cpp" } )
  80
  81 for app in apps.keys():
  82         env.Program( target=app, source = env.Split( apps[app] ) )
  83         env.Install( "$bindir", app )
  84
  85 env.SConscript( dirs=["streaming", "systemtests"], exports="env" )
  86
  87 # static versions
  88 if static_env['BUILD_STATIC_TOOLS']:
  89     static_env.Append(LIBS=File('#/src/libffado.a'))
  90     for app in apps.keys():
  91         static_app = app + "-static"
  92         static_env.Program( target=static_app, source = static_env.Split( apps[app] ) )